mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-06-03 13:13:21 +01:00
grungussuss
58501dce77
## About The Pull Request <details> - renamed ai folder to announcer -- announcer -- - moved vox_fem to announcer - moved approachingTG to announcer - separated the ambience folder into ambience and instrumental -- ambience -- - created holy folder moved all related sounds there - created engineering folder and moved all related sounds there - created security folder and moved ambidet there - created general folder and moved ambigen there - created icemoon folder and moved all icebox-related ambience there - created medical folder and moved all medbay-related ambi there - created ruin folder and moves all ruins ambi there - created beach folder and moved seag and shore there - created lavaland folder and moved related ambi there - created aurora_caelus folder and placed its ambi there - created misc folder and moved the rest of the files that don't have a specific category into it -- instrumental -- - moved traitor folder here - created lobby_music folder and placed our songs there (title0 not used anywhere? - server-side modification?) -- items -- - moved secdeath to hailer - moved surgery to handling -- effects -- - moved chemistry into effects - moved hallucinations into effects - moved health into effects - moved magic into effects -- vehicles -- - moved mecha into vehicles created mobs folder -- mobs -- - moved creatures folder into mobs - moved voice into mobs renamed creatures to non-humanoids renamed voice to humanoids -- non-humanoids-- created cyborg folder created hiss folder moved harmalarm.ogg to cyborg -- humanoids -- -- misc -- moved ghostwhisper to misc moved insane_low_laugh to misc I give up trying to document this. </details> - [X] ambience - [x] announcer - [x] effects - [X] instrumental - [x] items - [x] machines - [x] misc - [X] mobs - [X] runtime - [X] vehicles - [ ] attributions ## Why It's Good For The Game This folder is so disorganized that it's vomit inducing, will make it easier to find and add new sounds, providng a minor structure to the sound folder. ## Changelog 🆑 grungussuss refactor: the sound folder in the source code has been reorganized, please report any oddities with sounds playing or not playing server: lobby music has been repathed to sound/music/lobby_music /🆑
144 lines
5.5 KiB
Plaintext
144 lines
5.5 KiB
Plaintext
/area/ruin/space/meateor
|
|
name = "\improper Organic Asteroid"
|
|
sound_environment = SOUND_AREA_SMALL_ENCLOSED
|
|
|
|
/obj/item/paper/fluff/ruins/meateor/letter
|
|
name = "letter"
|
|
default_raw_text = {"We offer our sincerest congratulations, to be chosen to take this journey is an honour and privilege afforded to few.
|
|
<br> While you are walking in the footsteps of the divine, don't forget about the rest of us back at the farm!
|
|
<br> <This letter has been signed by 15 people.>"}
|
|
|
|
/// Tiger cultist corpse but with an exit wound
|
|
/obj/effect/mob_spawn/corpse/human/tigercultist/perforated
|
|
|
|
/obj/effect/mob_spawn/corpse/human/tigercultist/perforated/special(mob/living/carbon/human/spawned_human)
|
|
. = ..()
|
|
|
|
var/obj/item/bodypart/chest/their_chest = spawned_human.get_bodypart(BODY_ZONE_CHEST)
|
|
if (!their_chest)
|
|
return
|
|
|
|
spawned_human.cause_wound_of_type_and_severity(WOUND_PIERCE, their_chest, WOUND_SEVERITY_CRITICAL)
|
|
|
|
/// A fun drink enjoyed by the tiger cooperative, might corrode your brain if you drink the whole bottle
|
|
/obj/item/reagent_containers/cup/glass/bottle/ritual_wine
|
|
name = "ritual wine"
|
|
desc = "A bottle filled with liquids of a dubious nature, often enjoyed by members of the Tiger Cooperative."
|
|
icon_state = "winebottle"
|
|
list_reagents = list(
|
|
/datum/reagent/drug/mushroomhallucinogen = 25,
|
|
/datum/reagent/consumable/ethanol/ritual_wine = 25,
|
|
/datum/reagent/medicine/changelinghaste = 20, // This metabolises very fast
|
|
/datum/reagent/drug/bath_salts = 5,
|
|
/datum/reagent/blood = 5,
|
|
/datum/reagent/toxin/leadacetate = 5,
|
|
/datum/reagent/medicine/omnizine = 5,
|
|
/datum/reagent/medicine/c2/penthrite = 5,
|
|
/datum/reagent/consumable/vinegar = 5,
|
|
)
|
|
drink_type = NONE
|
|
age_restricted = FALSE
|
|
|
|
/// Abstract holder object for shared behaviour
|
|
/obj/structure/meateor_fluff
|
|
icon = 'icons/mob/simple/meteor_heart.dmi'
|
|
anchored = TRUE
|
|
|
|
/obj/structure/meateor_fluff/Initialize(mapload)
|
|
. = ..()
|
|
AddComponent(/datum/component/bloody_spreader,\
|
|
blood_left = INFINITY,\
|
|
blood_dna = list("meaty DNA" = "MT-"),\
|
|
diseases = null,\
|
|
)
|
|
|
|
/obj/structure/meateor_fluff/play_attack_sound(damage_amount, damage_type, damage_flag)
|
|
switch(damage_type)
|
|
if(BRUTE)
|
|
if(damage_amount)
|
|
playsound(loc, 'sound/effects/blob/attackblob.ogg', vol = 50, vary = TRUE, pressure_affected = FALSE)
|
|
else
|
|
playsound(loc, 'sound/effects/meatslap.ogg', vol = 50, vary = TRUE, pressure_affected = FALSE)
|
|
if(BURN)
|
|
playsound(loc, 'sound/effects/wounds/sizzle1.ogg', vol = 100, vary = TRUE, pressure_affected = FALSE)
|
|
|
|
/// A sort of loot box for organs, cut it open and find a prize
|
|
/obj/structure/meateor_fluff/flesh_pod
|
|
name = "flesh pod"
|
|
desc = "A quivering pod of living meat. Something is pulsing inside."
|
|
icon_state = "flesh_pod"
|
|
max_integrity = 120
|
|
density = TRUE
|
|
/// Typepath of the organ to spawn when this is destroyed
|
|
var/stored_organ
|
|
/// Types of organ we can spawn
|
|
var/static/list/allowed_organs = list(
|
|
/obj/item/organ/internal/heart/gland/egg = 7,
|
|
/obj/item/organ/internal/heart/gland/plasma = 7,
|
|
/obj/item/organ/internal/alien/plasmavessel = 5,
|
|
/obj/item/organ/internal/heart/gland/chem = 5,
|
|
/obj/item/organ/internal/heart/gland/mindshock = 5,
|
|
/obj/item/organ/internal/heart/gland/spiderman = 5,
|
|
/obj/item/organ/internal/heart/gland/transform = 5,
|
|
/obj/item/organ/internal/heart/gland/slime = 4,
|
|
/obj/item/organ/internal/heart/gland/trauma = 4,
|
|
/obj/item/organ/internal/heart/carp = 3,
|
|
/obj/item/organ/internal/heart/rat = 3,
|
|
/obj/item/organ/internal/heart/gland/electric = 3,
|
|
/obj/item/organ/internal/monster_core/brimdust_sac = 3,
|
|
/obj/item/organ/internal/monster_core/regenerative_core = 3,
|
|
/obj/item/organ/internal/monster_core/rush_gland = 3,
|
|
/obj/item/organ/internal/tongue/carp = 3,
|
|
/obj/item/organ/internal/alien/acid = 2,
|
|
/obj/item/organ/internal/alien/resinspinner = 2,
|
|
/obj/item/organ/internal/eyes/night_vision/goliath = 2,
|
|
/obj/item/organ/internal/eyes/night_vision/rat = 2,
|
|
/obj/item/organ/internal/heart/gland/ventcrawling = 1,
|
|
)
|
|
|
|
/obj/structure/meateor_fluff/flesh_pod/Initialize(mapload)
|
|
. = ..()
|
|
stored_organ = pick_weight(allowed_organs)
|
|
|
|
/obj/structure/meateor_fluff/flesh_pod/attackby(obj/item/attacking_item, mob/user, params)
|
|
if (attacking_item.sharpness & SHARP_EDGED)
|
|
cut_open(user)
|
|
return
|
|
return ..()
|
|
|
|
/// Cut the pod open and destroy it
|
|
/obj/structure/meateor_fluff/flesh_pod/proc/cut_open(mob/user)
|
|
balloon_alert(user, "slicing...")
|
|
if (!do_after(user, 3 SECONDS, target = src))
|
|
return
|
|
take_damage(max_integrity)
|
|
|
|
/obj/structure/meateor_fluff/flesh_pod/atom_destruction(damage_flag)
|
|
new stored_organ(loc)
|
|
new /obj/effect/decal/cleanable/blood(loc)
|
|
new /obj/structure/meateor_fluff/flesh_pod_open(loc)
|
|
playsound(loc, 'sound/effects/wounds/blood3.ogg', vol = 50, vary = TRUE, pressure_affected = FALSE)
|
|
return ..()
|
|
|
|
/obj/structure/meateor_fluff/flesh_pod_open
|
|
name = "flesh pod"
|
|
desc = "A pod of living meat, this one has been hollowed out."
|
|
icon_state = "flesh_pod_open"
|
|
max_integrity = 60
|
|
|
|
/obj/structure/meateor_fluff/flesh_pod_open/atom_destruction(damage_flag)
|
|
new /obj/effect/gibspawner/human(loc)
|
|
return ..()
|
|
|
|
/// Decorative fluff egg object
|
|
/obj/structure/meateor_fluff/abandoned_headcrab_egg
|
|
name = "meaty eggs"
|
|
desc = "A mass of fleshy, egg-shaped nodes."
|
|
icon_state = "eggs"
|
|
max_integrity = 15
|
|
|
|
/obj/structure/meateor_fluff/abandoned_headcrab_egg/atom_destruction(damage_flag)
|
|
new /obj/effect/decal/cleanable/xenoblood(loc)
|
|
playsound(loc, 'sound/effects/footstep/gib_step.ogg', vol = 50, vary = TRUE, pressure_affected = FALSE)
|
|
return ..()
|