mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-04-18 02:04:33 +01:00
58501dce77
## About The Pull Request <details> - renamed ai folder to announcer -- announcer -- - moved vox_fem to announcer - moved approachingTG to announcer - separated the ambience folder into ambience and instrumental -- ambience -- - created holy folder moved all related sounds there - created engineering folder and moved all related sounds there - created security folder and moved ambidet there - created general folder and moved ambigen there - created icemoon folder and moved all icebox-related ambience there - created medical folder and moved all medbay-related ambi there - created ruin folder and moves all ruins ambi there - created beach folder and moved seag and shore there - created lavaland folder and moved related ambi there - created aurora_caelus folder and placed its ambi there - created misc folder and moved the rest of the files that don't have a specific category into it -- instrumental -- - moved traitor folder here - created lobby_music folder and placed our songs there (title0 not used anywhere? - server-side modification?) -- items -- - moved secdeath to hailer - moved surgery to handling -- effects -- - moved chemistry into effects - moved hallucinations into effects - moved health into effects - moved magic into effects -- vehicles -- - moved mecha into vehicles created mobs folder -- mobs -- - moved creatures folder into mobs - moved voice into mobs renamed creatures to non-humanoids renamed voice to humanoids -- non-humanoids-- created cyborg folder created hiss folder moved harmalarm.ogg to cyborg -- humanoids -- -- misc -- moved ghostwhisper to misc moved insane_low_laugh to misc I give up trying to document this. </details> - [X] ambience - [x] announcer - [x] effects - [X] instrumental - [x] items - [x] machines - [x] misc - [X] mobs - [X] runtime - [X] vehicles - [ ] attributions ## Why It's Good For The Game This folder is so disorganized that it's vomit inducing, will make it easier to find and add new sounds, providng a minor structure to the sound folder. ## Changelog 🆑 grungussuss refactor: the sound folder in the source code has been reorganized, please report any oddities with sounds playing or not playing server: lobby music has been repathed to sound/music/lobby_music /🆑
76 lines
2.8 KiB
Plaintext
76 lines
2.8 KiB
Plaintext
/datum/surgery/stomach_pump
|
|
name = "Stomach Pump"
|
|
possible_locs = list(BODY_ZONE_CHEST)
|
|
steps = list(
|
|
/datum/surgery_step/incise,
|
|
/datum/surgery_step/retract_skin,
|
|
/datum/surgery_step/incise,
|
|
/datum/surgery_step/clamp_bleeders,
|
|
/datum/surgery_step/stomach_pump,
|
|
/datum/surgery_step/close,
|
|
)
|
|
|
|
/datum/surgery/stomach_pump/mechanic
|
|
name = "Nutrient Processing Purge"
|
|
requires_bodypart_type = BODYTYPE_ROBOTIC
|
|
steps = list(
|
|
/datum/surgery_step/mechanic_open,
|
|
/datum/surgery_step/open_hatch,
|
|
/datum/surgery_step/mechanic_unwrench,
|
|
/datum/surgery_step/stomach_pump,
|
|
/datum/surgery_step/mechanic_wrench,
|
|
/datum/surgery_step/mechanic_close,
|
|
)
|
|
|
|
/datum/surgery/stomach_pump/can_start(mob/user, mob/living/carbon/target)
|
|
var/obj/item/organ/internal/stomach/target_stomach = target.get_organ_slot(ORGAN_SLOT_STOMACH)
|
|
if(HAS_TRAIT(target, TRAIT_HUSK))
|
|
return FALSE
|
|
if(!target_stomach)
|
|
return FALSE
|
|
return ..()
|
|
|
|
//Working the stomach by hand in such a way that you induce vomiting.
|
|
/datum/surgery_step/stomach_pump
|
|
name = "pump stomach (hand)"
|
|
accept_hand = TRUE
|
|
repeatable = TRUE
|
|
time = 20
|
|
success_sound = 'sound/items/handling/surgery/organ2.ogg'
|
|
|
|
/datum/surgery_step/stomach_pump/preop(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
display_results(
|
|
user,
|
|
target,
|
|
span_notice("You begin pumping [target]'s stomach..."),
|
|
span_notice("[user] begins to pump [target]'s stomach."),
|
|
span_notice("[user] begins to press on [target]'s chest."),
|
|
)
|
|
display_pain(target, "You feel a horrible sloshing feeling in your gut! You're going to be sick!")
|
|
|
|
/datum/surgery_step/stomach_pump/success(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery/surgery, default_display_results = FALSE)
|
|
if(ishuman(target))
|
|
var/mob/living/carbon/human/target_human = target
|
|
display_results(
|
|
user,
|
|
target,
|
|
span_notice("[user] forces [target_human] to vomit, cleansing their stomach of some chemicals!"),
|
|
span_notice("[user] forces [target_human] to vomit, cleansing their stomach of some chemicals!"),
|
|
span_notice("[user] forces [target_human] to vomit!"),
|
|
)
|
|
target_human.vomit((MOB_VOMIT_MESSAGE | MOB_VOMIT_STUN), lost_nutrition = 20, purge_ratio = 0.67) //higher purge ratio than regular vomiting
|
|
return ..()
|
|
|
|
/datum/surgery_step/stomach_pump/failure(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
if(ishuman(target))
|
|
var/mob/living/carbon/human/target_human = target
|
|
display_results(
|
|
user,
|
|
target,
|
|
span_warning("You screw up, bruising [target_human]'s chest!"),
|
|
span_warning("[user] screws up, brusing [target_human]'s chest!"),
|
|
span_warning("[user] screws up!"),
|
|
)
|
|
target_human.adjustOrganLoss(ORGAN_SLOT_STOMACH, 5)
|
|
target_human.adjustBruteLoss(5)
|