mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-08-23 05:00:55 +01:00
0b65cc596b
* Overlay lighting component (#52413) Sparks no longer lag, projectile beams move super smoothly, same with mobs and whatnot. This also allows for easy expansion into directional lights, field-of-view, wee-woo rotating lights or whatever. It does have a downside: things right-clicked or checked through the alt+click tab will show the light overlay: This is a BYOND limitation, very well worth it IMO. 🆑 add: Smooth movable lighting system implemented. Projectiles, sparks, thrown flashlights or moving mobs with lights should be much smoother and less laggy. balance: Light sources no longer stack in range, though they still do in intensity. /🆑 * Overlay lighting component Co-authored-by: Rohesie <rohesie@gmail.com>
156 lines
5.3 KiB
Plaintext
156 lines
5.3 KiB
Plaintext
/obj/screen/plane_master
|
|
screen_loc = "CENTER"
|
|
icon_state = "blank"
|
|
appearance_flags = PLANE_MASTER|NO_CLIENT_COLOR
|
|
blend_mode = BLEND_OVERLAY
|
|
var/show_alpha = 255
|
|
var/hide_alpha = 0
|
|
|
|
/obj/screen/plane_master/proc/Show(override)
|
|
alpha = override || show_alpha
|
|
|
|
/obj/screen/plane_master/proc/Hide(override)
|
|
alpha = override || hide_alpha
|
|
|
|
//Why do plane masters need a backdrop sometimes? Read https://secure.byond.com/forum/?post=2141928
|
|
//Trust me, you need one. Period. If you don't think you do, you're doing something extremely wrong.
|
|
/obj/screen/plane_master/proc/backdrop(mob/mymob)
|
|
|
|
///Things rendered on "openspace"; holes in multi-z
|
|
/obj/screen/plane_master/openspace
|
|
name = "open space plane master"
|
|
plane = OPENSPACE_BACKDROP_PLANE
|
|
appearance_flags = PLANE_MASTER
|
|
blend_mode = BLEND_MULTIPLY
|
|
alpha = 255
|
|
|
|
/obj/screen/plane_master/openspace/Initialize()
|
|
. = ..()
|
|
filters += filter(type = "drop_shadow", color = "#04080FAA", size = -10)
|
|
filters += filter(type = "drop_shadow", color = "#04080FAA", size = -15)
|
|
filters += filter(type = "drop_shadow", color = "#04080FAA", size = -20)
|
|
|
|
/obj/screen/plane_master/proc/outline(_size, _color)
|
|
filters += filter(type = "outline", size = _size, color = _color)
|
|
|
|
/obj/screen/plane_master/proc/shadow(_size, _border, _offset = 0, _x = 0, _y = 0, _color = "#04080FAA")
|
|
filters += filter(type = "drop_shadow", x = _x, y = _y, color = _color, size = _size, offset = _offset)
|
|
|
|
/obj/screen/plane_master/proc/clear_filters()
|
|
filters = list()
|
|
|
|
///Contains just the floor
|
|
/obj/screen/plane_master/floor
|
|
name = "floor plane master"
|
|
plane = FLOOR_PLANE
|
|
appearance_flags = PLANE_MASTER
|
|
blend_mode = BLEND_OVERLAY
|
|
|
|
/obj/screen/plane_master/floor/backdrop(mob/mymob)
|
|
filters = list()
|
|
if(istype(mymob) && mymob.eye_blurry)
|
|
filters += GAUSSIAN_BLUR(clamp(mymob.eye_blurry*0.1,0.6,3))
|
|
|
|
///Contains most things in the game world
|
|
/obj/screen/plane_master/game_world
|
|
name = "game world plane master"
|
|
plane = GAME_PLANE
|
|
appearance_flags = PLANE_MASTER //should use client color
|
|
blend_mode = BLEND_OVERLAY
|
|
|
|
/obj/screen/plane_master/game_world/backdrop(mob/mymob)
|
|
filters = list()
|
|
if(istype(mymob) && mymob.client && mymob.client.prefs && mymob.client.prefs.ambientocclusion)
|
|
filters += AMBIENT_OCCLUSION
|
|
if(istype(mymob) && mymob.eye_blurry)
|
|
filters += GAUSSIAN_BLUR(clamp(mymob.eye_blurry*0.1,0.6,3))
|
|
|
|
|
|
///Contains all lighting objects
|
|
/obj/screen/plane_master/lighting
|
|
name = "lighting plane master"
|
|
plane = LIGHTING_PLANE
|
|
blend_mode = BLEND_MULTIPLY
|
|
mouse_opacity = MOUSE_OPACITY_TRANSPARENT
|
|
|
|
/obj/screen/plane_master/lighting/backdrop(mob/mymob)
|
|
mymob.overlay_fullscreen("lighting_backdrop_lit", /obj/screen/fullscreen/lighting_backdrop/lit)
|
|
mymob.overlay_fullscreen("lighting_backdrop_unlit", /obj/screen/fullscreen/lighting_backdrop/unlit)
|
|
|
|
/obj/screen/plane_master/lighting/Initialize()
|
|
. = ..()
|
|
filters += filter(type="alpha", render_source = EMISSIVE_RENDER_TARGET, flags = MASK_INVERSE)
|
|
filters += filter(type="alpha", render_source = EMISSIVE_UNBLOCKABLE_RENDER_TARGET, flags = MASK_INVERSE)
|
|
filters += filter(type="alpha", render_source = O_LIGHTING_VISUAL_RENDER_TARGET, flags = MASK_INVERSE)
|
|
|
|
/**
|
|
* Things placed on this mask the lighting plane. Doesn't render directly.
|
|
*
|
|
* Gets masked by blocking plane. Use for things that you want blocked by
|
|
* mobs, items, etc.
|
|
*/
|
|
/obj/screen/plane_master/emissive
|
|
name = "emissive plane master"
|
|
plane = EMISSIVE_PLANE
|
|
mouse_opacity = MOUSE_OPACITY_TRANSPARENT
|
|
render_target = EMISSIVE_RENDER_TARGET
|
|
|
|
/obj/screen/plane_master/emissive/Initialize()
|
|
. = ..()
|
|
filters += filter(type="alpha", render_source=EMISSIVE_BLOCKER_RENDER_TARGET, flags=MASK_INVERSE)
|
|
|
|
/**
|
|
* Things placed on this always mask the lighting plane. Doesn't render directly.
|
|
*
|
|
* Always masks the light plane, isn't blocked by anything. Use for on mob glows,
|
|
* magic stuff, etc.
|
|
*/
|
|
/obj/screen/plane_master/emissive_unblockable
|
|
name = "unblockable emissive plane master"
|
|
plane = EMISSIVE_UNBLOCKABLE_PLANE
|
|
mouse_opacity = MOUSE_OPACITY_TRANSPARENT
|
|
render_target = EMISSIVE_UNBLOCKABLE_RENDER_TARGET
|
|
|
|
/**
|
|
* Things placed on this layer mask the emissive layer. Doesn't render directly
|
|
*
|
|
* You really shouldn't be directly using this, use atom helpers instead
|
|
*/
|
|
/obj/screen/plane_master/emissive_blocker
|
|
name = "emissive blocker plane master"
|
|
plane = EMISSIVE_BLOCKER_PLANE
|
|
mouse_opacity = MOUSE_OPACITY_TRANSPARENT
|
|
render_target = EMISSIVE_BLOCKER_RENDER_TARGET
|
|
|
|
///Contains space parallax
|
|
/obj/screen/plane_master/parallax
|
|
name = "parallax plane master"
|
|
plane = PLANE_SPACE_PARALLAX
|
|
blend_mode = BLEND_MULTIPLY
|
|
mouse_opacity = MOUSE_OPACITY_TRANSPARENT
|
|
|
|
/obj/screen/plane_master/parallax_white
|
|
name = "parallax whitifier plane master"
|
|
plane = PLANE_SPACE
|
|
|
|
/obj/screen/plane_master/camera_static
|
|
name = "camera static plane master"
|
|
plane = CAMERA_STATIC_PLANE
|
|
appearance_flags = PLANE_MASTER
|
|
blend_mode = BLEND_OVERLAY
|
|
|
|
/obj/screen/plane_master/excited_turfs
|
|
name = "atmos excited turfs"
|
|
plane = ATMOS_GROUP_PLANE
|
|
appearance_flags = PLANE_MASTER
|
|
blend_mode = BLEND_OVERLAY
|
|
alpha = 0
|
|
|
|
/obj/screen/plane_master/o_light_visual
|
|
name = "overlight light visual plane master"
|
|
layer = O_LIGHTING_VISUAL_LAYER
|
|
plane = O_LIGHTING_VISUAL_PLANE
|
|
render_target = O_LIGHTING_VISUAL_RENDER_TARGET
|
|
mouse_opacity = MOUSE_OPACITY_TRANSPARENT
|
|
blend_mode = BLEND_MULTIPLY
|