cyberpresidentvanellope/Bubberstation
1
0
Fork 0
mirror of https://github.com/Bubberstation/Bubberstation.git synced 2025-12-10 09:42:29 +00:00
Code Issues Packages Projects Releases Wiki Activity
Files
1ac4a67c27d6bb19da547b75d889f7a7c219b107
Bubberstation/code/modules/reagents/reagent_containers.dm
MrMelbert 1ac4a67c27 Chefs can now kiss food they make to make it with love. (And a lot of cooking refactoring) (#70409) 
About The Pull Request

    Adds a skillchip to the chef's vendor. This vendor allows the chef to kiss their food to deliver a chef's kiss.
        Chef's kissing your food will add the "love" reagent to the food, which makes people much happier when they eat it. Be careful, overdosing on love can cause heart attacks.

    Refactors microwaving.
        Separates microwaving out of the edible component and makes it its own element, like grillable and bakeable.
        Also removes some magic numbers from microwave code.

    Code improvements all around baking and grilling code.

    Refactors edible component inheritance.
        Inheriting the edible component is now a viable way to cleanly add food types, flags, and callbacks. This makes it much much easier to change the values of an edible item without adding hacky signals / procs / getcomponent.

Why It's Good For The Game

Emergent chef gameplay.
Being able to further enhance your food with mood buffs.
Better code.
Changelog

cl Melbert
add: Chefs can now make food with love. They can purchase a skillchip from their vendor which enhances their kiss emote. Using your kiss on food you create will add a special reagent to it which makes it nicer.
refactor: Separated Microwavable from the Edible component, refactored microwave act to accompany this
refactor: Refactored how grilled items are generated
refactor: Refactored how silver slime food items are generated
refactor: Refactored how edible items inherit new edible statuses
code: Removed some magic numbers from microwaves
code: General code improvements for grillable / bakeable / etc
/cl
2022-11-04 09:45:01 +13:00

241 lines
8.8 KiB
Plaintext
Raw Blame History

/obj/item/reagent_containers
name = "Container"
desc = "..."
icon = 'icons/obj/medical/chemical.dmi'
icon_state = null
w_class = WEIGHT_CLASS_TINY
var/amount_per_transfer_from_this = 5
var/list/possible_transfer_amounts = list(5,10,15,20,25,30)
/// Where we are in the possible transfer amount list.
var/amount_list_position = 1
var/volume = 30
var/reagent_flags
var/list/list_reagents = null
var/spawned_disease = null
var/disease_amount = 20
var/spillable = FALSE
var/list/fill_icon_thresholds = null
var/fill_icon_state = null // Optional custom name for reagent fill icon_state prefix
/// The icon file to take fill icon appearances from
var/fill_icon = 'icons/obj/reagentfillings.dmi'
/obj/item/reagent_containers/Initialize(mapload, vol)
. = ..()
if(isnum(vol) && vol > 0)
volume = vol
create_reagents(volume, reagent_flags)
if(spawned_disease)
var/datum/disease/F = new spawned_disease()
var/list/data = list("viruses"= list(F))
reagents.add_reagent(/datum/reagent/blood, disease_amount, data)
add_initial_reagents()
/obj/item/reagent_containers/examine()
. = ..()
if(possible_transfer_amounts.len > 1)
. += span_notice("Left-click or right-click in-hand to increase or decrease its transfer amount.")
else if(possible_transfer_amounts.len)
. += span_notice("Left-click or right-click in-hand to view its transfer amount.")
/obj/item/reagent_containers/create_reagents(max_vol, flags)
. = ..()
RegisterSignal(reagents, list(COMSIG_REAGENTS_NEW_REAGENT, COMSIG_REAGENTS_ADD_REAGENT, COMSIG_REAGENTS_DEL_REAGENT, COMSIG_REAGENTS_REM_REAGENT), .proc/on_reagent_change)
RegisterSignal(reagents, COMSIG_PARENT_QDELETING, .proc/on_reagents_del)
/obj/item/reagent_containers/attack(mob/living/target_mob, mob/living/user, params)
if (!user.combat_mode)
return
return ..()
/obj/item/reagent_containers/proc/on_reagents_del(datum/reagents/reagents)
SIGNAL_HANDLER
UnregisterSignal(reagents, list(COMSIG_REAGENTS_NEW_REAGENT, COMSIG_REAGENTS_ADD_REAGENT, COMSIG_REAGENTS_DEL_REAGENT, COMSIG_REAGENTS_REM_REAGENT, COMSIG_PARENT_QDELETING))
return NONE
/obj/item/reagent_containers/proc/add_initial_reagents()
if(list_reagents)
reagents.add_reagent_list(list_reagents)
/obj/item/reagent_containers/attack_self(mob/user)
change_transfer_amount(user, FORWARD)
/obj/item/reagent_containers/attack_self_secondary(mob/user)
change_transfer_amount(user, BACKWARD)
/obj/item/reagent_containers/proc/mode_change_message(mob/user)
return
/obj/item/reagent_containers/proc/change_transfer_amount(mob/user, direction = FORWARD)
var/list_len = length(possible_transfer_amounts)
if(!list_len)
return
switch(direction)
if(FORWARD)
amount_list_position = (amount_list_position % list_len) + 1
if(BACKWARD)
amount_list_position = (amount_list_position - 1) || list_len
else
CRASH("change_transfer_amount() called with invalid direction value")
amount_per_transfer_from_this = possible_transfer_amounts[amount_list_position]
balloon_alert(user, "transferring [amount_per_transfer_from_this]u")
mode_change_message(user)
/obj/item/reagent_containers/pre_attack_secondary(atom/target, mob/living/user, params)
if(HAS_TRAIT(target, DO_NOT_SPLASH))
return ..()
if(!user.combat_mode)
return ..()
if (try_splash(user, target))
return SECONDARY_ATTACK_CANCEL_ATTACK_CHAIN
return ..()
/// Tries to splash the target. Used on both right-click and normal click when in combat mode.
/obj/item/reagent_containers/proc/try_splash(mob/user, atom/target)
if (!spillable)
return FALSE
if (!reagents?.total_volume)
return FALSE
var/punctuation = ismob(target) ? "!" : "."
var/reagent_text
user.visible_message(
span_danger("[user] splashes the contents of [src] onto [target][punctuation]"),
span_danger("You splash the contents of [src] onto [target][punctuation]"),
ignored_mobs = target,
)
if (ismob(target))
var/mob/target_mob = target
target_mob.show_message(
span_userdanger("[user] splash the contents of [src] onto you!"),
MSG_VISUAL,
span_userdanger("You feel drenched!"),
)
for(var/datum/reagent/reagent as anything in reagents.reagent_list)
reagent_text += "[reagent] ([num2text(reagent.volume)]),"
var/mob/thrown_by = thrownby?.resolve()
if(isturf(target) && reagents.reagent_list.len && thrown_by)
log_combat(thrown_by, target, "splashed (thrown) [english_list(reagents.reagent_list)]")
message_admins("[ADMIN_LOOKUPFLW(thrown_by)] splashed (thrown) [english_list(reagents.reagent_list)] on [target] at [ADMIN_VERBOSEJMP(target)].")
reagents.expose(target, TOUCH)
log_combat(user, target, "splashed", reagent_text)
reagents.clear_reagents()
return TRUE
/obj/item/reagent_containers/proc/canconsume(mob/eater, mob/user)
if(!iscarbon(eater))
return FALSE
var/mob/living/carbon/C = eater
var/covered = ""
if(C.is_mouth_covered(head_only = 1))
covered = "headgear"
else if(C.is_mouth_covered(mask_only = 1))
covered = "mask"
if(covered)
var/who = (isnull(user) || eater == user) ? "your" : "[eater.p_their()]"
to_chat(user, span_warning("You have to remove [who] [covered] first!"))
return FALSE
return TRUE
/*
* On accidental consumption, transfer a portion of the reagents to the eater and the item it's in, then continue to the base proc (to deal with shattering glass containers)
*/
/obj/item/reagent_containers/on_accidental_consumption(mob/living/carbon/M, mob/living/carbon/user, obj/item/source_item, discover_after = TRUE)
M.losebreath += 2
reagents?.trans_to(M, min(15, reagents.total_volume / rand(5,10)), transfered_by = user, methods = INGEST)
if(source_item?.reagents)
reagents.trans_to(source_item, min(source_item.reagents.total_volume / 2, reagents.total_volume / 5), transfered_by = user, methods = TOUCH)
return ..()
/obj/item/reagent_containers/fire_act(exposed_temperature, exposed_volume)
reagents.expose_temperature(exposed_temperature)
..()
/obj/item/reagent_containers/throw_impact(atom/hit_atom, datum/thrownthing/throwingdatum, do_splash = TRUE)
. = ..()
if(do_splash)
SplashReagents(hit_atom, TRUE)
/obj/item/reagent_containers/proc/bartender_check(atom/target)
. = FALSE
var/mob/thrown_by = thrownby?.resolve()
if(target.CanPass(src, get_dir(target, src)) && thrown_by && HAS_TRAIT(thrown_by, TRAIT_BOOZE_SLIDER))
. = TRUE
/obj/item/reagent_containers/proc/SplashReagents(atom/target, thrown = FALSE, override_spillable = FALSE)
if(!reagents || !reagents.total_volume || (!spillable && !override_spillable))
return
var/mob/thrown_by = thrownby?.resolve()
if(ismob(target) && target.reagents)
if(thrown)
reagents.total_volume *= rand(5,10) * 0.1 //Not all of it makes contact with the target
var/mob/M = target
var/R
target.visible_message(span_danger("[M] is splashed with something!"), \
span_userdanger("[M] is splashed with something!"))
for(var/datum/reagent/A in reagents.reagent_list)
R += "[A.type] ([num2text(A.volume)]),"
if(thrown_by)
log_combat(thrown_by, M, "splashed", R)
reagents.expose(target, TOUCH)
else if(bartender_check(target) && thrown)
visible_message(span_notice("[src] lands onto the [target.name] without spilling a single drop."))
return
else
if(isturf(target) && reagents.reagent_list.len && thrown_by)
log_combat(thrown_by, target, "splashed (thrown) [english_list(reagents.reagent_list)]", "in [AREACOORD(target)]")
thrown_by.log_message("splashed (thrown) [english_list(reagents.reagent_list)] on [target].", LOG_ATTACK)
message_admins("[ADMIN_LOOKUPFLW(thrown_by)] splashed (thrown) [english_list(reagents.reagent_list)] on [target] in [ADMIN_VERBOSEJMP(target)].")
visible_message(span_notice("[src] spills its contents all over [target]."))
reagents.expose(target, TOUCH)
if(QDELETED(src))
return
reagents.clear_reagents()
/obj/item/reagent_containers/microwave_act(obj/machinery/microwave/microwave_source, mob/microwaver)
reagents.expose_temperature(1000)
return ..() | COMPONENT_MICROWAVE_SUCCESS
/obj/item/reagent_containers/fire_act(temperature, volume)
reagents.expose_temperature(temperature)
/// Updates the icon of the container when the reagents change. Eats signal args
/obj/item/reagent_containers/proc/on_reagent_change(datum/reagents/holder, ...)
SIGNAL_HANDLER
update_appearance()
return NONE
/obj/item/reagent_containers/update_overlays()
. = ..()
if(!fill_icon_thresholds)
return
if(!reagents.total_volume)
return
var/fill_name = fill_icon_state? fill_icon_state : icon_state
var/mutable_appearance/filling = mutable_appearance(fill_icon, "[fill_name][fill_icon_thresholds[1]]")
var/percent = round((reagents.total_volume / volume) * 100)
for(var/i in 1 to fill_icon_thresholds.len)
var/threshold = fill_icon_thresholds[i]
var/threshold_end = (i == fill_icon_thresholds.len)? INFINITY : fill_icon_thresholds[i+1]
if(threshold <= percent && percent < threshold_end)
filling.icon_state = "[fill_name][fill_icon_thresholds[i]]"
filling.color = mix_color_from_reagents(reagents.reagent_list)
. += filling
Reference in New Issue View Git Blame Copy Permalink