mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-29 02:21:44 +00:00
b8e5bb22bc
Fixes large crate, critter crate, cardboard and metal boxes showing a nonfitting sprite when wrapped. I added two new sprite for those wrapped box-like closet, one for wrapped and one for giftwrapped. You can now use tabs when writing on paper, by using "[tab]". Fixes clone damage not being transfered when humanizing/monkeyizing with a dna injector. Fixes chaplain's camera obscura showing invisible things other than ghosts. Fixes typo in carbon/examine.dm().
114 lines
2.8 KiB
Plaintext
114 lines
2.8 KiB
Plaintext
|
|
|
|
/*
|
|
* Wrapping Paper
|
|
*/
|
|
|
|
/obj/item/stack/wrapping_paper
|
|
name = "wrapping paper"
|
|
desc = "Wrap packages with this festive paper to make gifts."
|
|
icon = 'icons/obj/items.dmi'
|
|
icon_state = "wrap_paper"
|
|
flags = NOBLUDGEON
|
|
amount = 25
|
|
max_amount = 25
|
|
resistance_flags = FLAMMABLE
|
|
|
|
/obj/item/stack/wrapping_paper/Destroy()
|
|
if(!amount)
|
|
new /obj/item/weapon/c_tube(get_turf(src))
|
|
return ..()
|
|
|
|
|
|
/*
|
|
* Package Wrap
|
|
*/
|
|
|
|
/obj/item/stack/packageWrap
|
|
name = "package wrapper"
|
|
desc = "You can use this to wrap items in."
|
|
icon = 'icons/obj/items.dmi'
|
|
icon_state = "deliveryPaper"
|
|
flags = NOBLUDGEON
|
|
amount = 25
|
|
max_amount = 25
|
|
resistance_flags = FLAMMABLE
|
|
|
|
/obj/item/proc/can_be_package_wrapped() //can the item be wrapped with package wrapper into a delivery package
|
|
return 1
|
|
|
|
/obj/item/weapon/storage/can_be_package_wrapped()
|
|
return 0
|
|
|
|
/obj/item/weapon/storage/box/can_be_package_wrapped()
|
|
return 1
|
|
|
|
/obj/item/smallDelivery/can_be_package_wrapped()
|
|
return 0
|
|
|
|
/obj/item/stack/packageWrap/afterattack(obj/target, mob/user, proximity)
|
|
if(!proximity)
|
|
return
|
|
if(!istype(target))
|
|
return
|
|
if(target.anchored)
|
|
return
|
|
|
|
if(istype(target, /obj/item))
|
|
var/obj/item/I = target
|
|
if(!I.can_be_package_wrapped())
|
|
return
|
|
if(user.is_holding(I))
|
|
if(!user.unEquip(I))
|
|
return
|
|
else if(!isturf(I.loc))
|
|
return
|
|
if(use(1))
|
|
var/obj/item/smallDelivery/P = new /obj/item/smallDelivery(get_turf(I.loc))
|
|
if(user.Adjacent(I))
|
|
P.add_fingerprint(user)
|
|
I.add_fingerprint(user)
|
|
user.put_in_hands(P)
|
|
I.forceMove(P)
|
|
var/size = round(I.w_class)
|
|
P.w_class = size
|
|
size = min(size, 5)
|
|
P.icon_state = "deliverypackage[size]"
|
|
|
|
else if(istype (target, /obj/structure/closet))
|
|
var/obj/structure/closet/O = target
|
|
if(O.opened)
|
|
return
|
|
if(!O.delivery_icon) //no delivery icon means unwrappable closet (e.g. body bags)
|
|
user << "<span class='warning'>You can't wrap this!</span>"
|
|
return
|
|
if(use(3))
|
|
var/obj/structure/bigDelivery/P = new /obj/structure/bigDelivery(get_turf(O.loc))
|
|
P.icon_state = O.delivery_icon
|
|
O.loc = P
|
|
P.add_fingerprint(user)
|
|
O.add_fingerprint(user)
|
|
else
|
|
user << "<span class='warning'>You need more paper!</span>"
|
|
return
|
|
else
|
|
user << "<span class='warning'>The object you are trying to wrap is unsuitable for the sorting machinery!</span>"
|
|
return
|
|
|
|
user.visible_message("<span class='notice'>[user] wraps [target].</span>")
|
|
user.attack_log += text("\[[time_stamp()]\] <font color='blue'>Has used [name] on [target]</font>")
|
|
|
|
/obj/item/stack/packageWrap/Destroy()
|
|
if(!amount)
|
|
new /obj/item/weapon/c_tube(get_turf(src))
|
|
return ..()
|
|
|
|
/obj/item/weapon/c_tube
|
|
name = "cardboard tube"
|
|
desc = "A tube... of cardboard."
|
|
icon = 'icons/obj/items.dmi'
|
|
icon_state = "c_tube"
|
|
throwforce = 0
|
|
w_class = 1
|
|
throw_speed = 3
|
|
throw_range = 5 |