mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-07 23:42:44 +00:00
f7eb2c905b
* Unicode support Part 2 -- copytext() This is the transition of all copytext() calls to be unicode aware and also some nearby calls in the same functions. Most things are just replacing copytext() with copytext_char() as a terrible character limiter but a few others were slightly more involved. I replaced a ton of ```` var/something = sanitize(input()) something = copytext(something, 1, MAX_MESSAGE_LEN) ```` with a single stripped_input() call. stripped_input() already calls html_encode(), trim(), and some other sanitization so there shouldn't be any major issues there. This is still VERY rough btw; DNA is a mess, the status displays are complete ass, there's a copytext() in code\datums\shuttles.dm that I'm not sure what to do with, and I didn't touch anything in the tools folder. I haven't tested this much at all yet, I only got it to compile earlier this morning. There's also likely to be weird bugs until I get around to fixing length(), findtext(), and the rest of the string procs. * Makes the code functional * Assume color hex strings are always # followed by ascii. Properly encodes and decodes the stuff in mob_helpers.dm which fixes some issues there. * Removes ninjaspeak since it's unused
76 lines
3.0 KiB
Plaintext
76 lines
3.0 KiB
Plaintext
/mob/verb/pray(msg as text)
|
|
set category = "IC"
|
|
set name = "Pray"
|
|
|
|
if(GLOB.say_disabled) //This is here to try to identify lag problems
|
|
to_chat(usr, "<span class='danger'>Speech is currently admin-disabled.</span>")
|
|
return
|
|
|
|
msg = copytext_char(sanitize(msg), 1, MAX_MESSAGE_LEN)
|
|
if(!msg)
|
|
return
|
|
log_prayer("[src.key]/([src.name]): [msg]")
|
|
if(usr.client)
|
|
if(usr.client.prefs.muted & MUTE_PRAY)
|
|
to_chat(usr, "<span class='danger'>You cannot pray (muted).</span>")
|
|
return
|
|
if(src.client.handle_spam_prevention(msg,MUTE_PRAY))
|
|
return
|
|
|
|
var/mutable_appearance/cross = mutable_appearance('icons/obj/storage.dmi', "bible")
|
|
var/font_color = "purple"
|
|
var/prayer_type = "PRAYER"
|
|
var/deity
|
|
if(usr.job == "Chaplain")
|
|
cross.icon_state = "kingyellow"
|
|
font_color = "blue"
|
|
prayer_type = "CHAPLAIN PRAYER"
|
|
if(GLOB.deity)
|
|
deity = GLOB.deity
|
|
else if(iscultist(usr))
|
|
cross.icon_state = "tome"
|
|
font_color = "red"
|
|
prayer_type = "CULTIST PRAYER"
|
|
deity = "Nar'Sie"
|
|
else if(isliving(usr))
|
|
var/mob/living/L = usr
|
|
if(HAS_TRAIT(L, TRAIT_SPIRITUAL))
|
|
cross.icon_state = "holylight"
|
|
font_color = "blue"
|
|
prayer_type = "SPIRITUAL PRAYER"
|
|
|
|
var/msg_tmp = msg
|
|
msg = "<span class='adminnotice'>[icon2html(cross, GLOB.admins)]<b><font color=[font_color]>[prayer_type][deity ? " (to [deity])" : ""]: </font>[ADMIN_FULLMONTY(src)] [ADMIN_SC(src)]:</b> <span class='linkify'>[msg]</span></span>"
|
|
|
|
for(var/client/C in GLOB.admins)
|
|
if(C.prefs.chat_toggles & CHAT_PRAYER)
|
|
to_chat(C, msg)
|
|
if(C.prefs.toggles & SOUND_PRAYERS)
|
|
if(usr.job == "Chaplain")
|
|
SEND_SOUND(C, sound('sound/effects/pray.ogg'))
|
|
to_chat(usr, "<span class='info'>You pray to the gods: \"[msg_tmp]\"</span>")
|
|
|
|
SSblackbox.record_feedback("tally", "admin_verb", 1, "Prayer") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
|
|
//log_admin("HELP: [key_name(src)]: [msg]")
|
|
|
|
/proc/CentCom_announce(text , mob/Sender)
|
|
var/msg = copytext_char(sanitize(text), 1, MAX_MESSAGE_LEN)
|
|
msg = "<span class='adminnotice'><b><font color=orange>CENTCOM:</font>[ADMIN_FULLMONTY(Sender)] [ADMIN_CENTCOM_REPLY(Sender)]:</b> [msg]</span>"
|
|
to_chat(GLOB.admins, msg)
|
|
for(var/obj/machinery/computer/communications/C in GLOB.machines)
|
|
C.overrideCooldown()
|
|
|
|
/proc/Syndicate_announce(text , mob/Sender)
|
|
var/msg = copytext_char(sanitize(text), 1, MAX_MESSAGE_LEN)
|
|
msg = "<span class='adminnotice'><b><font color=crimson>SYNDICATE:</font>[ADMIN_FULLMONTY(Sender)] [ADMIN_SYNDICATE_REPLY(Sender)]:</b> [msg]</span>"
|
|
to_chat(GLOB.admins, msg)
|
|
for(var/obj/machinery/computer/communications/C in GLOB.machines)
|
|
C.overrideCooldown()
|
|
|
|
/proc/Nuke_request(text , mob/Sender)
|
|
var/msg = copytext_char(sanitize(text), 1, MAX_MESSAGE_LEN)
|
|
msg = "<span class='adminnotice'><b><font color=orange>NUKE CODE REQUEST:</font>[ADMIN_FULLMONTY(Sender)] [ADMIN_CENTCOM_REPLY(Sender)] [ADMIN_SET_SD_CODE]:</b> [msg]</span>"
|
|
to_chat(GLOB.admins, msg)
|
|
for(var/obj/machinery/computer/communications/C in GLOB.machines)
|
|
C.overrideCooldown()
|