mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-28 10:31:59 +00:00
9e1ef0ffe2
* Add the system for managed global variables * Travis ban old globals * So you CAN inline proccall, that's neat * Fix that * master.dm * Remove the hack procs * Move InitGlobals to the proper spot * configuration.dm * Fix the missing pre-slash * clockcult.dm * This is probably for the best * Doy * Fix shit * Rest of the DEFINES tree * Fix * Use global. for access * Update find_references_in_globals Always hated that proc Whoever made it must've bee a r e a l idiot... * __HELPERS tree * Move global initialization to master. Fix the declaration * database.dm * Dat newline * I said DECLARATIVE order! * Here's something you can chew on @Iamgoofball * game_modes.dm * Fix this * genetics.dm * flavor_misc.dm * More stuff * Do it mso's way. Keep the controllers as global * Make master actually see it * Fix * Finish _globalvars/lists * Finish the rest of the _globalvars tree * This is weird * Migrate the controllers * SLOTH -> GLOB * Lighting globals * round_start_time -> ticker * PAI card list -> pai SS * record_id_num -> static * Diseases list -> SSdisease * More disease globals to the SS * More disease stuff * Emote list * Better and better * Bluh * So much stuff * Ahh * Wires * dview * station_areas * Teleportlocs * blood_splatter_icons * Stuff and such * More stuff * RAD IO * More stuff and such * Blob shit * Changeling stuff * Add "Balance" to changelogs * Balance for changelog compiler + Auto Tagging * Update the PR template * hivemind_bank * Bip * sacrificed * Good shit * Better define * More cult shit * Devil shit * Gang shit * > borers Fix shit * Rename the define * Nuke * Objectives * Sandbox * Multiverse sword * Announce systems * Stuff and such * TC con * Airlock * doppllllerrrrrr * holopads * Shut up byond you inconsistent fuck * Sneaky fuck * Burp * Bip * Fixnshit * Port without regard * askdlfjs; * asdfjasoidojfi * Protected globals and more * SO MANY * ajsimkvahsaoisd * akfdsiaopwimfeoiwafaw * gsdfigjosidjfgiosdg * AHHHHHHHHHHHHHHHHHHHHHHH!!!!! * facerolll * ASDFASDFASDF * Removes the unused parts of dmm_suite * WIP * Fix quote * asdfjauwfnkjs * afwlunhskjfda * asfjlaiwuefhaf * SO CLOSE * wwwweeeeeewwwww * agdgmoewranwg * HOLY MOTHER OF FUCK AND THATS JUST HALF THE JOB?!? * Fix syntax errors * 100 errors * Another 100 * So many... * Ugh * More shit * kilme * Stuuuuuufffff * ajrgmrlshio;djfa;sdkl * jkbhkhjbmjvjmh * soi soi soi * butt * TODAY WE LEARNED THAT GLOBAL AND STATIC ARE THE EXACT SAME FUCKING THING * lllllllllllllllllllllllllllllllllllllllllll * afsdijfiawhnflnjhnwsdfs * yugykihlugk,kj * time to go * STUFFF!!! * AAAAAAAAAAAAAAAAAHHHHHHHHHHHHHHHHHHHHHHHHHHH!!!!!!!!!!!!!!!!!!!!!!! * ngoaijdjlfkamsdlkf * Break time * aufjsdklfalsjfi * CONTROL KAY AND PRAY * IT COMPILEELEELELAKLJFKLDAFJLKFDJLADKJHFLJKAJGAHIEJALDFJ!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! * Goteem * Fix testing mode * This does not belong in this PR * Convert it to a controller * Eh, fuck this option * Revert controllerization Ill do it some other time * Fix * Working controllerization * FOR THE LOVE OF CHRIST PROTECT THE LOGS * Protect admins and deadmins * Use the inbuilt proc
61 lines
2.1 KiB
Plaintext
61 lines
2.1 KiB
Plaintext
/**
|
|
* tgui state: default_state
|
|
*
|
|
* Checks a number of things -- mostly physical distance for humans and view for robots.
|
|
**/
|
|
|
|
GLOBAL_DATUM_INIT(default_state, /datum/ui_state/default, new)
|
|
|
|
/datum/ui_state/default/can_use_topic(src_object, mob/user)
|
|
return user.default_can_use_topic(src_object) // Call the individual mob-overriden procs.
|
|
|
|
/mob/proc/default_can_use_topic(src_object)
|
|
return UI_CLOSE // Don't allow interaction by default.
|
|
|
|
/mob/living/default_can_use_topic(src_object)
|
|
. = shared_ui_interaction(src_object)
|
|
if(. > UI_CLOSE && loc)
|
|
. = min(., loc.contents_ui_distance(src_object, src)) // Check the distance...
|
|
if(. == UI_INTERACTIVE) // Non-human living mobs can only look, not touch.
|
|
return UI_UPDATE
|
|
|
|
/mob/living/carbon/human/default_can_use_topic(src_object)
|
|
. = shared_ui_interaction(src_object)
|
|
if(. > UI_CLOSE)
|
|
. = min(., shared_living_ui_distance(src_object)) // Check the distance...
|
|
// Derp a bit if we have brain loss.
|
|
if(prob(getBrainLoss()))
|
|
return UI_UPDATE
|
|
|
|
/mob/living/silicon/robot/default_can_use_topic(src_object)
|
|
. = shared_ui_interaction(src_object)
|
|
if(. <= UI_DISABLED)
|
|
return
|
|
|
|
// Robots can interact with anything they can see.
|
|
if(get_dist(src, src_object) <= client.view)
|
|
return UI_INTERACTIVE
|
|
return UI_DISABLED // Otherwise they can keep the UI open.
|
|
|
|
/mob/living/silicon/ai/default_can_use_topic(src_object)
|
|
. = shared_ui_interaction(src_object)
|
|
if(. < UI_INTERACTIVE)
|
|
return
|
|
|
|
// The AI can interact with anything it can see nearby, or with cameras.
|
|
if((get_dist(src, src_object) <= client.view) || GLOB.cameranet.checkTurfVis(get_turf_pixel(src_object)))
|
|
return UI_INTERACTIVE
|
|
return UI_CLOSE
|
|
|
|
/mob/living/simple_animal/default_can_use_topic(src_object)
|
|
. = shared_ui_interaction(src_object)
|
|
if(. > UI_CLOSE)
|
|
. = min(., shared_living_ui_distance(src_object)) //simple animals can only use things they're near.
|
|
|
|
/mob/living/silicon/pai/default_can_use_topic(src_object)
|
|
// pAIs can only use themselves and the owner's radio.
|
|
if((src_object == src || src_object == radio) && !stat)
|
|
return UI_INTERACTIVE
|
|
else
|
|
return ..()
|