mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-04 14:01:22 +00:00
0f3c4e51f7
Implements the Modernizing radiation design document ( https://hackmd.io/@tgstation/rJNIyeBHt ) and replaces the current radiation sources with the new system, as well as replacing/removing a bunch of old consumers of radiation that either had no reason to exist, or could be replaced by something else. Diverges from the doc in that items radiation don't go up like explained. I was going to, but items get irradiated so easily that it just feels pretty lame. Items still get irradiated, but it's mostly just so that radiation sources look cooler (wow, lots of stuff around going green), and for things like the geiger counter. Instead of the complicated radiation_wave system, radiation now just checks everything between the radiation source and the potential target, losing power along the way based on the radiation insulation of whats in between. If this reaches too low a point (specified by radiation_pulse consumers), then the radiation will not pass. Otherwise, will roll a chance to irradiate. Uranium structures allow a delay before irradiating, so stay away!
100 lines
2.6 KiB
Plaintext
100 lines
2.6 KiB
Plaintext
|
|
/**********************Ore box**************************/
|
|
|
|
/obj/structure/ore_box
|
|
icon = 'icons/obj/mining.dmi'
|
|
icon_state = "orebox"
|
|
name = "ore box"
|
|
desc = "A heavy wooden box, which can be filled with a lot of ores."
|
|
density = TRUE
|
|
pressure_resistance = 5*ONE_ATMOSPHERE
|
|
|
|
/obj/structure/ore_box/attackby(obj/item/W, mob/user, params)
|
|
if (istype(W, /obj/item/stack/ore))
|
|
user.transferItemToLoc(W, src)
|
|
else if(SEND_SIGNAL(W, COMSIG_CONTAINS_STORAGE))
|
|
SEND_SIGNAL(W, COMSIG_TRY_STORAGE_TAKE_TYPE, /obj/item/stack/ore, src)
|
|
to_chat(user, span_notice("You empty the ore in [W] into \the [src]."))
|
|
else
|
|
return ..()
|
|
|
|
/obj/structure/ore_box/crowbar_act(mob/living/user, obj/item/I)
|
|
if(I.use_tool(src, user, 50, volume=50))
|
|
user.visible_message(span_notice("[user] pries \the [src] apart."),
|
|
span_notice("You pry apart \the [src]."),
|
|
span_hear("You hear splitting wood."))
|
|
deconstruct(TRUE, user)
|
|
return TRUE
|
|
|
|
/obj/structure/ore_box/examine(mob/living/user)
|
|
if(Adjacent(user) && istype(user))
|
|
ui_interact(user)
|
|
. = ..()
|
|
|
|
/obj/structure/ore_box/attack_hand(mob/user, list/modifiers)
|
|
. = ..()
|
|
if(.)
|
|
return
|
|
if(Adjacent(user))
|
|
ui_interact(user)
|
|
|
|
/obj/structure/ore_box/attack_robot(mob/user)
|
|
if(Adjacent(user))
|
|
ui_interact(user)
|
|
|
|
/obj/structure/ore_box/proc/dump_box_contents()
|
|
var/drop = drop_location()
|
|
for(var/obj/item/stack/ore/O in src)
|
|
if(QDELETED(O))
|
|
continue
|
|
if(QDELETED(src))
|
|
break
|
|
O.forceMove(drop)
|
|
if(TICK_CHECK)
|
|
stoplag()
|
|
drop = drop_location()
|
|
|
|
/obj/structure/ore_box/ui_interact(mob/user, datum/tgui/ui)
|
|
ui = SStgui.try_update_ui(user, src, ui)
|
|
if(!ui)
|
|
ui = new(user, src, "OreBox", name)
|
|
ui.open()
|
|
|
|
/obj/structure/ore_box/ui_data()
|
|
var/contents = list()
|
|
for(var/obj/item/stack/ore/O in src)
|
|
contents[O.type] += O.amount
|
|
|
|
var/data = list()
|
|
data["materials"] = list()
|
|
for(var/type in contents)
|
|
var/obj/item/stack/ore/O = type
|
|
var/name = initial(O.name)
|
|
data["materials"] += list(list("name" = name, "amount" = contents[type], "id" = type))
|
|
|
|
return data
|
|
|
|
/obj/structure/ore_box/ui_act(action, params)
|
|
. = ..()
|
|
if(.)
|
|
return
|
|
if(!Adjacent(usr))
|
|
return
|
|
add_fingerprint(usr)
|
|
usr.set_machine(src)
|
|
switch(action)
|
|
if("removeall")
|
|
dump_box_contents()
|
|
to_chat(usr, span_notice("You open the release hatch on the box.."))
|
|
|
|
/obj/structure/ore_box/deconstruct(disassembled = TRUE, mob/user)
|
|
var/obj/item/stack/sheet/mineral/wood/WD = new (loc, 4)
|
|
if(user && !QDELETED(WD))
|
|
WD.add_fingerprint(user)
|
|
dump_box_contents()
|
|
qdel(src)
|
|
|
|
/// Special override for notify_contents = FALSE.
|
|
/obj/structure/ore_box/on_changed_z_level(turf/old_turf, turf/new_turf, notify_contents = FALSE)
|
|
return ..()
|