mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-30 11:01:35 +00:00
0a1f06a2d1
* This tail refactor turned into an organ refactor. Funny how that works. * Firstly, fixing all the conflicts. * Fixes all our maps (hopefully) * Actually, this should fix pod people hair :) * Almost everything is working, just two major things to fix * Fixed a certain kind of external organ * Cleaning up some more stuff * Turned tail_cat into tail because why the fuck are they separate? * Moved all the tails into tails.dmi because that was just dumb to have like 3 in a different file * Adds relevant_layers to organs to help with rendering * Makes stored_feature_id also check mutant_bodyparts * Fixes the icon_state names of ALL the tails (pain) * Fixes wagging, gotta refactor most mutant bodyparts later on * I Love Added Failures * Fixed some organs that slipped through my searches * This could possibly fix the CI for this? * It doesn't look like it did fix it * This will make it pass, even if it's ugly as sin. * Fixed Felinids having a weird ghost tail * Fixes instances of snouts and tails not being properly colored Co-authored-by: Kapu1178 <75460809+Kapu1178@users.noreply.github.com> Co-authored-by: GoldenAlpharex <jerego1234@hotmail.com>
59 lines
2.9 KiB
Plaintext
59 lines
2.9 KiB
Plaintext
/datum/surgery/gastrectomy
|
|
name = "Gastrectomy"
|
|
target_mobtypes = list(/mob/living/carbon/human)
|
|
possible_locs = list(BODY_ZONE_CHEST)
|
|
requires_real_bodypart = TRUE
|
|
steps = list(
|
|
/datum/surgery_step/incise,
|
|
/datum/surgery_step/retract_skin,
|
|
/datum/surgery_step/saw,
|
|
/datum/surgery_step/clamp_bleeders,
|
|
/datum/surgery_step/incise,
|
|
/datum/surgery_step/gastrectomy,
|
|
/datum/surgery_step/clamp_bleeders,
|
|
/datum/surgery_step/close)
|
|
organ_to_manipulate = ORGAN_SLOT_STOMACH
|
|
|
|
/datum/surgery/gastrectomy/can_start(mob/user, mob/living/carbon/target)
|
|
var/obj/item/organ/internal/stomach/target_stomach = target.getorganslot(ORGAN_SLOT_STOMACH)
|
|
if(target_stomach?.damage > 50 && !(target_stomach.organ_flags & ORGAN_FAILING))
|
|
return TRUE
|
|
|
|
////Gastrectomy, because we truly needed a way to repair stomachs.
|
|
//95% chance of success to be consistent with most organ-repairing surgeries.
|
|
/datum/surgery_step/gastrectomy
|
|
name = "remove lower duodenum"
|
|
implements = list(
|
|
TOOL_SCALPEL = 95,
|
|
/obj/item/melee/energy/sword = 65,
|
|
/obj/item/knife = 45,
|
|
/obj/item/shard = 35)
|
|
time = 52
|
|
preop_sound = 'sound/surgery/scalpel1.ogg'
|
|
success_sound = 'sound/surgery/organ1.ogg'
|
|
failure_sound = 'sound/surgery/organ2.ogg'
|
|
|
|
/datum/surgery_step/gastrectomy/preop(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
display_results(user, target, span_notice("You begin to cut out a damaged piece of [target]'s stomach..."),
|
|
span_notice("[user] begins to make an incision in [target]."),
|
|
span_notice("[user] begins to make an incision in [target]."))
|
|
display_pain(target, "You feel a horrible stab in your gut!")
|
|
|
|
/datum/surgery_step/gastrectomy/success(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery/surgery, default_display_results = FALSE)
|
|
var/mob/living/carbon/human/target_human = target
|
|
target_human.setOrganLoss(ORGAN_SLOT_STOMACH, 20) // Stomachs have a threshold for being able to even digest food, so I might tweak this number
|
|
display_results(user, target, span_notice("You successfully remove the damaged part of [target]'s stomach."),
|
|
span_notice("[user] successfully removes the damaged part of [target]'s stomach."),
|
|
span_notice("[user] successfully removes the damaged part of [target]'s stomach."))
|
|
display_pain(target, "The pain in your gut ebbs and fades somewhat.")
|
|
return ..()
|
|
|
|
/datum/surgery_step/gastrectomy/failure(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery)
|
|
var/mob/living/carbon/human/target_human = target
|
|
target_human.adjustOrganLoss(ORGAN_SLOT_STOMACH, 15)
|
|
display_results(user, target, span_warning("You cut the wrong part of [target]'s stomach!"),
|
|
span_warning("[user] cuts the wrong part of [target]'s stomach!"),
|
|
span_warning("[user] cuts the wrong part of [target]'s stomach!"))
|
|
display_pain(target, "Your stomach throbs with pain; it's not getting any better!")
|
|
|