mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-08-18 18:47:53 +01:00
f56e32ab97
* Zombies can be decapped again, un-nerfs esword/armblade/etc wounding power, improvised cauterization tweaks (#53349) #53117 introduced a few minor bugs with the health system, in this case, zombies being un-decappable due to an oversight in the head/chest dismember requiring full death rather than either full crit or death. As zombies (or anything with TRAIT_NODEATH) can only reach hard crit and not death, this meant they couldn't be decapped/disemboweled. This fixes that. It also fixes krokodil addict zombies being unwoundable due to not having flesh or bone traits. Next up, I originally set really high negative wound bonuses for high damage weapons like eswords and armblades since they already had high damage and dismember power by themselves. Now that dismembering is tied to wounding power (and I have a better sense of balance values), these harsh nerfs are no longer needed or wanted, and you can actually dismember people worth a damn with an esword again. I also punched up the wounding power of a few other weapons like saws and scalpels to less awful (but still not optimal) against armor. Attacks currently have an 80% chance to hit the limb you're aiming at, which can make destroying a limb a complete pain even if the target is already down and out. As such, attacks against prone targets now have a 90% chance to hit the targeted limb, cutting the miss rate in half. Lastly, trying to cauterize bleeding wounds with improvised tools (anything hot that isn't a cautery) is now slightly less efficient than a real cautery and requires an aggro grab on the patient to apply. No more trying to cauterize the person you just attacked with an esword because you were on help intent! * Zombies can be decapped again, un-nerfs esword/armblade/etc wounding power, improvised cauterization tweaks Co-authored-by: Ryll Ryll <3589655+Ryll-Ryll@users.noreply.github.com>
89 lines
3.1 KiB
Plaintext
89 lines
3.1 KiB
Plaintext
/obj/item/melee/transforming
|
|
sharpness = SHARP_EDGED
|
|
bare_wound_bonus = 20
|
|
var/active = FALSE
|
|
var/force_on = 30 //force when active
|
|
var/faction_bonus_force = 0 //Bonus force dealt against certain factions
|
|
var/throwforce_on = 20
|
|
var/icon_state_on = "axe1"
|
|
var/hitsound_on = 'sound/weapons/blade1.ogg'
|
|
var/list/attack_verb_on = list("attacks", "slashes", "stabs", "slices", "tears", "lacerates", "rips", "dices", "cuts")
|
|
var/list/attack_verb_off = list("attacks", "slashes", "stabs", "slices", "tears", "lacerates", "rips", "dices", "cuts")
|
|
w_class = WEIGHT_CLASS_SMALL
|
|
var/bonus_active = FALSE //If the faction damage bonus is active
|
|
var/list/nemesis_factions //Any mob with a faction that exists in this list will take bonus damage/effects
|
|
var/w_class_on = WEIGHT_CLASS_BULKY
|
|
var/clumsy_check = TRUE
|
|
|
|
/obj/item/melee/transforming/Initialize()
|
|
. = ..()
|
|
if(active)
|
|
if(attack_verb_on.len)
|
|
attack_verb_continuous = attack_verb_on
|
|
else
|
|
if(attack_verb_off.len)
|
|
attack_verb_continuous = attack_verb_off
|
|
if(embedding)
|
|
updateEmbedding()
|
|
if(sharpness)
|
|
AddComponent(/datum/component/butchering, 50, 100, 0, hitsound)
|
|
|
|
/obj/item/melee/transforming/attack_self(mob/living/carbon/user)
|
|
if(transform_weapon(user))
|
|
clumsy_transform_effect(user)
|
|
|
|
/obj/item/melee/transforming/attack(mob/living/target, mob/living/carbon/human/user)
|
|
var/nemesis_faction = FALSE
|
|
if(LAZYLEN(nemesis_factions))
|
|
for(var/F in target.faction)
|
|
if(F in nemesis_factions)
|
|
nemesis_faction = TRUE
|
|
force += faction_bonus_force
|
|
nemesis_effects(user, target)
|
|
break
|
|
. = ..()
|
|
if(nemesis_faction)
|
|
force -= faction_bonus_force
|
|
|
|
/obj/item/melee/transforming/proc/transform_weapon(mob/living/user, supress_message_text)
|
|
active = !active
|
|
if(active)
|
|
force = force_on
|
|
throwforce = throwforce_on
|
|
hitsound = hitsound_on
|
|
throw_speed = 4
|
|
if(attack_verb_on.len)
|
|
attack_verb_continuous = attack_verb_on
|
|
icon_state = icon_state_on
|
|
w_class = w_class_on
|
|
if(embedding)
|
|
updateEmbedding()
|
|
else
|
|
force = initial(force)
|
|
throwforce = initial(throwforce)
|
|
hitsound = initial(hitsound)
|
|
throw_speed = initial(throw_speed)
|
|
if(attack_verb_off.len)
|
|
attack_verb_continuous = attack_verb_off
|
|
icon_state = initial(icon_state)
|
|
w_class = initial(w_class)
|
|
if(embedding)
|
|
disableEmbedding()
|
|
|
|
transform_messages(user, supress_message_text)
|
|
add_fingerprint(user)
|
|
return TRUE
|
|
|
|
/obj/item/melee/transforming/proc/nemesis_effects(mob/living/user, mob/living/target)
|
|
return
|
|
|
|
/obj/item/melee/transforming/proc/transform_messages(mob/living/user, supress_message_text)
|
|
playsound(user, active ? 'sound/weapons/saberon.ogg' : 'sound/weapons/saberoff.ogg', 35, TRUE) //changed it from 50% volume to 35% because deafness
|
|
if(!supress_message_text)
|
|
to_chat(user, "<span class='notice'>[src] [active ? "is now active":"can now be concealed"].</span>")
|
|
|
|
/obj/item/melee/transforming/proc/clumsy_transform_effect(mob/living/user)
|
|
if(clumsy_check && HAS_TRAIT(user, TRAIT_CLUMSY) && prob(50))
|
|
to_chat(user, "<span class='warning'>You accidentally cut yourself with [src], like a doofus!</span>")
|
|
user.take_bodypart_damage(5,5)
|