mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-20 22:54:46 +00:00
58f82b5161
* [Ready] MODsuits * we dont need to add these people as codeowners, goodness gracious * have to remove this because upstream * part 1 of these fixes * EEEE * Update peacekeeper_clothing.dm * E * E * Auto stash before merge of "upstream-merge-59109" and "origin/upstream-merge-59109" * E * Update expeditionary_trooper.dm * more removal * nice * modsuti modstui modusuti * fixes * E * ITS MODsuit not HARDSUIT * more hardsuit references * MODSUIT NOT HARSUITEDSA * Maps * More ,map * oop * e * oo aa * 0 * ting tang * Update modsuit_tailsprites.dm * hi fikou * bs tech update Co-authored-by: Fikou <23585223+Fikou@users.noreply.github.com> Co-authored-by: jjpark-kb <55967837+jjpark-kb@users.noreply.github.com> Co-authored-by: Gandalf <jzo123@hotmail.com> Co-authored-by: Tom <8881105+tf-4@users.noreply.github.com>
51 lines
1.7 KiB
Plaintext
51 lines
1.7 KiB
Plaintext
/obj/projectile/bullet/dart
|
|
name = "dart"
|
|
icon_state = "cbbolt"
|
|
damage = 6
|
|
embedding = null
|
|
shrapnel_type = null
|
|
var/inject_flags = null
|
|
|
|
/obj/projectile/bullet/dart/Initialize(mapload)
|
|
. = ..()
|
|
create_reagents(50, NO_REACT)
|
|
|
|
/obj/projectile/bullet/dart/on_hit(atom/target, blocked = FALSE)
|
|
if(iscarbon(target))
|
|
var/mob/living/carbon/M = target
|
|
if(blocked != 100) // not completely blocked
|
|
if(M.can_inject(target_zone = def_zone, injection_flags = inject_flags)) // Pass the hit zone to see if it can inject by whether it hit the head or the body.
|
|
..()
|
|
reagents.trans_to(M, reagents.total_volume, methods = INJECT)
|
|
return BULLET_ACT_HIT
|
|
else
|
|
blocked = 100
|
|
target.visible_message(span_danger("\The [src] is deflected!"), \
|
|
span_userdanger("You are protected against \the [src]!"))
|
|
|
|
..(target, blocked)
|
|
reagents.flags &= ~(NO_REACT)
|
|
reagents.handle_reactions()
|
|
return BULLET_ACT_HIT
|
|
|
|
/obj/projectile/bullet/dart/metalfoam/Initialize(mapload)
|
|
. = ..()
|
|
reagents.add_reagent(/datum/reagent/aluminium, 15)
|
|
reagents.add_reagent(/datum/reagent/foaming_agent, 5)
|
|
reagents.add_reagent(/datum/reagent/toxin/acid/fluacid, 5)
|
|
|
|
/obj/projectile/bullet/dart/syringe
|
|
name = "syringe"
|
|
icon_state = "syringeproj"
|
|
|
|
/obj/projectile/bullet/dart/syringe/Initialize(mapload)
|
|
. = ..()
|
|
|
|
// This prevents the Ody from being used as a combat mech spamming RDX/Teslium syringes all over the place.
|
|
// Other syringe guns are loaded manually with pre-filled syringes which will react chems themselves.
|
|
// The traitor chem dartgun uses /obj/projectile/bullet/dart/piercing, so this does not impact it.
|
|
reagents.flags &= ~NO_REACT
|
|
|
|
/obj/projectile/bullet/dart/piercing
|
|
inject_flags = INJECT_CHECK_PENETRATE_THICK
|