mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-14 19:03:21 +00:00
dedf5f5ed9
* Virus antagonist initial commit * Updated disease code * Sentient virus improvements * Renamed /mob/living/var/viruses to diseases, and /mob/living/var/resistances to disease_resistances * Added sentient virus event * Renamed VIRUS defines to DISEASE defines * Fixed bugs in rewritten disease code * Fixed advanced disease Copy() * Finalized disease antagonist * Made cooldown buttons stop processing if they are removed from an owner. Made sentient disease active sneeze and cough not available if the host is unconscious. Made sentient disease menu refresh when adaptations are ready or hosts are added or removed. Made sentient disease following use movement signals instead of fastprocess. * Added better icons to sentient disease abilities
128 lines
4.4 KiB
Plaintext
128 lines
4.4 KiB
Plaintext
/obj/item/reagent_containers
|
|
name = "Container"
|
|
desc = "..."
|
|
icon = 'icons/obj/chemical.dmi'
|
|
icon_state = null
|
|
w_class = WEIGHT_CLASS_TINY
|
|
var/amount_per_transfer_from_this = 5
|
|
var/list/possible_transfer_amounts = list(5,10,15,20,25,30)
|
|
var/volume = 30
|
|
var/list/list_reagents = null
|
|
var/spawned_disease = null
|
|
var/disease_amount = 20
|
|
var/spillable = FALSE
|
|
|
|
/obj/item/reagent_containers/Initialize(mapload, vol)
|
|
. = ..()
|
|
if(isnum(vol) && vol > 0)
|
|
volume = vol
|
|
create_reagents(volume)
|
|
if(spawned_disease)
|
|
var/datum/disease/F = new spawned_disease()
|
|
var/list/data = list("viruses"= list(F))
|
|
reagents.add_reagent("blood", disease_amount, data)
|
|
|
|
add_initial_reagents()
|
|
|
|
/obj/item/reagent_containers/proc/add_initial_reagents()
|
|
if(list_reagents)
|
|
reagents.add_reagent_list(list_reagents)
|
|
|
|
/obj/item/reagent_containers/attack_self(mob/user)
|
|
if(possible_transfer_amounts.len)
|
|
var/i=0
|
|
for(var/A in possible_transfer_amounts)
|
|
i++
|
|
if(A == amount_per_transfer_from_this)
|
|
if(i<possible_transfer_amounts.len)
|
|
amount_per_transfer_from_this = possible_transfer_amounts[i+1]
|
|
else
|
|
amount_per_transfer_from_this = possible_transfer_amounts[1]
|
|
to_chat(user, "<span class='notice'>[src]'s transfer amount is now [amount_per_transfer_from_this] units.</span>")
|
|
return
|
|
|
|
/obj/item/reagent_containers/attack(mob/M, mob/user, def_zone)
|
|
if(user.a_intent == INTENT_HARM)
|
|
return ..()
|
|
|
|
/obj/item/reagent_containers/afterattack(obj/target, mob/user , flag)
|
|
return
|
|
|
|
/obj/item/reagent_containers/proc/canconsume(mob/eater, mob/user)
|
|
if(!iscarbon(eater))
|
|
return 0
|
|
var/mob/living/carbon/C = eater
|
|
var/covered = ""
|
|
if(C.is_mouth_covered(head_only = 1))
|
|
covered = "headgear"
|
|
else if(C.is_mouth_covered(mask_only = 1))
|
|
covered = "mask"
|
|
if(covered)
|
|
var/who = (isnull(user) || eater == user) ? "your" : "[eater.p_their()]"
|
|
to_chat(user, "<span class='warning'>You have to remove [who] [covered] first!</span>")
|
|
return 0
|
|
return 1
|
|
|
|
/obj/item/reagent_containers/ex_act()
|
|
if(reagents)
|
|
for(var/datum/reagent/R in reagents.reagent_list)
|
|
R.on_ex_act()
|
|
if(!QDELETED(src))
|
|
..()
|
|
|
|
/obj/item/reagent_containers/fire_act(exposed_temperature, exposed_volume)
|
|
reagents.expose_temperature(exposed_temperature)
|
|
..()
|
|
|
|
/obj/item/reagent_containers/throw_impact(atom/target)
|
|
. = ..()
|
|
SplashReagents(target, TRUE)
|
|
|
|
/obj/item/reagent_containers/proc/bartender_check(atom/target)
|
|
. = FALSE
|
|
if(target.CanPass(src, get_turf(src)) && thrownby && thrownby.actions)
|
|
for(var/datum/action/innate/drink_fling/D in thrownby.actions)
|
|
if(D.active)
|
|
return TRUE
|
|
|
|
/obj/item/reagent_containers/proc/SplashReagents(atom/target, thrown = FALSE)
|
|
if(!reagents || !reagents.total_volume || !spillable)
|
|
return
|
|
|
|
if(ismob(target) && target.reagents)
|
|
if(thrown)
|
|
reagents.total_volume *= rand(5,10) * 0.1 //Not all of it makes contact with the target
|
|
var/mob/M = target
|
|
var/R
|
|
target.visible_message("<span class='danger'>[M] has been splashed with something!</span>", \
|
|
"<span class='userdanger'>[M] has been splashed with something!</span>")
|
|
for(var/datum/reagent/A in reagents.reagent_list)
|
|
R += A.id + " ("
|
|
R += num2text(A.volume) + "),"
|
|
|
|
if(thrownby)
|
|
add_logs(thrownby, M, "splashed", R)
|
|
reagents.reaction(target, TOUCH)
|
|
|
|
else if(bartender_check(target) && thrown)
|
|
visible_message("<span class='notice'>[src] lands onto the [target.name] without spilling a single drop.</span>")
|
|
return
|
|
|
|
else
|
|
if(isturf(target) && reagents.reagent_list.len && thrownby)
|
|
add_logs(thrownby, target, "splashed (thrown) [english_list(reagents.reagent_list)]", "at [target][COORD(target)]")
|
|
log_game("[key_name(thrownby)] splashed (thrown) [english_list(reagents.reagent_list)] at [COORD(target)].")
|
|
message_admins("[key_name_admin(thrownby)] splashed (thrown) [english_list(reagents.reagent_list)] at [ADMIN_COORDJMP(target)].")
|
|
visible_message("<span class='notice'>[src] spills its contents all over [target].</span>")
|
|
reagents.reaction(target, TOUCH)
|
|
if(QDELETED(src))
|
|
return
|
|
|
|
reagents.clear_reagents()
|
|
|
|
/obj/item/reagent_containers/microwave_act(obj/machinery/microwave/M)
|
|
reagents.expose_temperature(1000)
|
|
..()
|
|
|
|
/obj/item/reagent_containers/temperature_expose(datum/gas_mixture/air, exposed_temperature, exposed_volume)
|
|
reagents.expose_temperature(exposed_temperature) |