mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-09 00:13:55 +00:00
9e1ef0ffe2
* Add the system for managed global variables * Travis ban old globals * So you CAN inline proccall, that's neat * Fix that * master.dm * Remove the hack procs * Move InitGlobals to the proper spot * configuration.dm * Fix the missing pre-slash * clockcult.dm * This is probably for the best * Doy * Fix shit * Rest of the DEFINES tree * Fix * Use global. for access * Update find_references_in_globals Always hated that proc Whoever made it must've bee a r e a l idiot... * __HELPERS tree * Move global initialization to master. Fix the declaration * database.dm * Dat newline * I said DECLARATIVE order! * Here's something you can chew on @Iamgoofball * game_modes.dm * Fix this * genetics.dm * flavor_misc.dm * More stuff * Do it mso's way. Keep the controllers as global * Make master actually see it * Fix * Finish _globalvars/lists * Finish the rest of the _globalvars tree * This is weird * Migrate the controllers * SLOTH -> GLOB * Lighting globals * round_start_time -> ticker * PAI card list -> pai SS * record_id_num -> static * Diseases list -> SSdisease * More disease globals to the SS * More disease stuff * Emote list * Better and better * Bluh * So much stuff * Ahh * Wires * dview * station_areas * Teleportlocs * blood_splatter_icons * Stuff and such * More stuff * RAD IO * More stuff and such * Blob shit * Changeling stuff * Add "Balance" to changelogs * Balance for changelog compiler + Auto Tagging * Update the PR template * hivemind_bank * Bip * sacrificed * Good shit * Better define * More cult shit * Devil shit * Gang shit * > borers Fix shit * Rename the define * Nuke * Objectives * Sandbox * Multiverse sword * Announce systems * Stuff and such * TC con * Airlock * doppllllerrrrrr * holopads * Shut up byond you inconsistent fuck * Sneaky fuck * Burp * Bip * Fixnshit * Port without regard * askdlfjs; * asdfjasoidojfi * Protected globals and more * SO MANY * ajsimkvahsaoisd * akfdsiaopwimfeoiwafaw * gsdfigjosidjfgiosdg * AHHHHHHHHHHHHHHHHHHHHHHH!!!!! * facerolll * ASDFASDFASDF * Removes the unused parts of dmm_suite * WIP * Fix quote * asdfjauwfnkjs * afwlunhskjfda * asfjlaiwuefhaf * SO CLOSE * wwwweeeeeewwwww * agdgmoewranwg * HOLY MOTHER OF FUCK AND THATS JUST HALF THE JOB?!? * Fix syntax errors * 100 errors * Another 100 * So many... * Ugh * More shit * kilme * Stuuuuuufffff * ajrgmrlshio;djfa;sdkl * jkbhkhjbmjvjmh * soi soi soi * butt * TODAY WE LEARNED THAT GLOBAL AND STATIC ARE THE EXACT SAME FUCKING THING * lllllllllllllllllllllllllllllllllllllllllll * afsdijfiawhnflnjhnwsdfs * yugykihlugk,kj * time to go * STUFFF!!! * AAAAAAAAAAAAAAAAAHHHHHHHHHHHHHHHHHHHHHHHHHHH!!!!!!!!!!!!!!!!!!!!!!! * ngoaijdjlfkamsdlkf * Break time * aufjsdklfalsjfi * CONTROL KAY AND PRAY * IT COMPILEELEELELAKLJFKLDAFJLKFDJLADKJHFLJKAJGAHIEJALDFJ!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! * Goteem * Fix testing mode * This does not belong in this PR * Convert it to a controller * Eh, fuck this option * Revert controllerization Ill do it some other time * Fix * Working controllerization * FOR THE LOVE OF CHRIST PROTECT THE LOGS * Protect admins and deadmins * Use the inbuilt proc
130 lines
3.3 KiB
Plaintext
130 lines
3.3 KiB
Plaintext
|
|
///////////
|
|
// EASEL //
|
|
///////////
|
|
|
|
/obj/structure/easel
|
|
name = "easel"
|
|
desc = "only for the finest of art!"
|
|
icon = 'icons/obj/artstuff.dmi'
|
|
icon_state = "easel"
|
|
density = 1
|
|
resistance_flags = FLAMMABLE
|
|
obj_integrity = 60
|
|
max_integrity = 60
|
|
var/obj/item/weapon/canvas/painting = null
|
|
|
|
|
|
//Adding canvases
|
|
/obj/structure/easel/attackby(obj/item/I, mob/user, params)
|
|
if(istype(I, /obj/item/weapon/canvas))
|
|
var/obj/item/weapon/canvas/C = I
|
|
user.dropItemToGround(C)
|
|
painting = C
|
|
C.loc = get_turf(src)
|
|
C.layer = layer+0.1
|
|
user.visible_message("<span class='notice'>[user] puts \the [C] on \the [src].</span>","<span class='notice'>You place \the [C] on \the [src].</span>")
|
|
else
|
|
return ..()
|
|
|
|
|
|
//Stick to the easel like glue
|
|
/obj/structure/easel/Move()
|
|
var/turf/T = get_turf(src)
|
|
..()
|
|
if(painting && painting.loc == T) //Only move if it's near us.
|
|
painting.loc = get_turf(src)
|
|
else
|
|
painting = null
|
|
|
|
|
|
//////////////
|
|
// CANVASES //
|
|
//////////////
|
|
|
|
#define AMT_OF_CANVASES 4 //Keep this up to date or shit will break.
|
|
|
|
//To safe memory on making /icons we cache the blanks..
|
|
GLOBAL_LIST_INIT(globalBlankCanvases, new(AMT_OF_CANVASES))
|
|
|
|
/obj/item/weapon/canvas
|
|
name = "canvas"
|
|
desc = "draw out your soul on this canvas!"
|
|
icon = 'icons/obj/artstuff.dmi'
|
|
icon_state = "11x11"
|
|
resistance_flags = FLAMMABLE
|
|
var/whichGlobalBackup = 1 //List index
|
|
|
|
/obj/item/weapon/canvas/nineteenXnineteen
|
|
icon_state = "19x19"
|
|
whichGlobalBackup = 2
|
|
|
|
/obj/item/weapon/canvas/twentythreeXnineteen
|
|
icon_state = "23x19"
|
|
whichGlobalBackup = 3
|
|
|
|
/obj/item/weapon/canvas/twentythreeXtwentythree
|
|
icon_state = "23x23"
|
|
whichGlobalBackup = 4
|
|
|
|
|
|
//Find the right size blank canvas
|
|
/obj/item/weapon/canvas/proc/getGlobalBackup()
|
|
. = null
|
|
if(GLOB.globalBlankCanvases[whichGlobalBackup])
|
|
. = GLOB.globalBlankCanvases[whichGlobalBackup]
|
|
else
|
|
var/icon/I = icon(initial(icon),initial(icon_state))
|
|
GLOB.globalBlankCanvases[whichGlobalBackup] = I
|
|
. = I
|
|
|
|
|
|
|
|
//One pixel increments
|
|
/obj/item/weapon/canvas/attackby(obj/item/I, mob/user, params)
|
|
//Click info
|
|
var/list/click_params = params2list(params)
|
|
var/pixX = text2num(click_params["icon-x"])
|
|
var/pixY = text2num(click_params["icon-y"])
|
|
|
|
//Should always be true, otherwise you didn't click the object, but let's check because SS13~
|
|
if(!click_params || !click_params["icon-x"] || !click_params["icon-y"])
|
|
return
|
|
|
|
//Cleaning one pixel with a soap or rag
|
|
if(istype(I, /obj/item/weapon/soap) || istype(I, /obj/item/weapon/reagent_containers/glass/rag))
|
|
//Pixel info created only when needed
|
|
var/icon/masterpiece = icon(icon,icon_state)
|
|
var/thePix = masterpiece.GetPixel(pixX,pixY)
|
|
var/icon/Ico = getGlobalBackup()
|
|
if(!Ico)
|
|
qdel(masterpiece)
|
|
return
|
|
|
|
var/theOriginalPix = Ico.GetPixel(pixX,pixY)
|
|
if(thePix != theOriginalPix) //colour changed
|
|
DrawPixelOn(theOriginalPix,pixX,pixY)
|
|
qdel(masterpiece)
|
|
|
|
//Drawing one pixel with a crayon
|
|
else if(istype(I, /obj/item/toy/crayon))
|
|
var/obj/item/toy/crayon/C = I
|
|
DrawPixelOn(C.paint_color, pixX, pixY)
|
|
else
|
|
return ..()
|
|
|
|
|
|
//Clean the whole canvas
|
|
/obj/item/weapon/canvas/attack_self(mob/user)
|
|
if(!user)
|
|
return
|
|
var/icon/blank = getGlobalBackup()
|
|
if(blank)
|
|
//it's basically a giant etch-a-sketch
|
|
icon = blank
|
|
user.visible_message("<span class='notice'>[user] cleans the canvas.</span>","<span class='notice'>You clean the canvas.</span>")
|
|
|
|
|
|
|
|
#undef AMT_OF_CANVASES
|