mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-14 03:32:00 +00:00
124ddd7cca
* tgui Preferences Menu + total rewrite of the preferences backend * nah, we dont need to ping those people * trying to remove the funny stuff * unmodularizing this * prefs reset * this may need to be reverted, who knows * okay, this part * perhaps * EEEEEEEEE * unsanitary * E * Stage 1 + loadout system * more fixes * E * I mean, it launches? * More fixes and reorganisation * E * customisation code is spaget. * disable ERP prefs * Update erp_preferences.dm * Update erp_preferences.dm * E * Slowly getting there * It may be time for help :) * tri...colors... help * preferences now pass preferences * Update dna.dm * Fuck this man * missing savefile return, set_species works, removed dumb stuff from updateappearance * https://github.com/Skyrat-SS13/Skyrat-tg/pull/8199 * https://github.com/Skyrat-SS13/Skyrat-tg/pull/8224 * https://github.com/tgstation/tgstation/pull/61519 * https://github.com/Skyrat-SS13/Skyrat-tg/pull/8278 * e * le butonAZARAK HELLO * hhh * Proper recognition where it's due, MrMelbert! * EEEE * examine block * Better gen hit sounds from whitedream * final loadout touches, more bug fixes im sure to come * i said there would be bugfixes * Update LoadoutManager.js * Missing preferences in the html menu * LIVE TESTING PHASE BABY * Update LoadoutManager.js * EEE * LAUNCH TEST FIRE * Update job.dm * Update new_player.dm * 50gb DAY ONE PATCH * EEE * Update preferences.dm * buggle fixes * Update examine.dm * >LOOC starts on Co-authored-by: Mothblocks <35135081+Mothblocks@users.noreply.github.com> Co-authored-by: jjpark-kb <55967837+jjpark-kb@users.noreply.github.com> Co-authored-by: Gandalf <jzo123@hotmail.com> Co-authored-by: Azarak <azarak10@gmail.com>
69 lines
2.7 KiB
Plaintext
69 lines
2.7 KiB
Plaintext
/datum/buildmode_mode/delete
|
|
key = "delete"
|
|
|
|
/datum/buildmode_mode/delete/show_help(client/c)
|
|
to_chat(c, "<span class='notice'>***********************************************************\n\
|
|
Left Mouse Button on anything to delete it. If you break it, you buy it.\n\
|
|
Right Mouse Button on anything to delete everything of the type. Probably don\'t do this unless you know what you are doing.\n\
|
|
***********************************************************</span>")
|
|
|
|
/datum/buildmode_mode/delete/handle_click(client/c, params, object)
|
|
var/list/modifiers = params2list(params)
|
|
|
|
if(LAZYACCESS(modifiers, LEFT_CLICK))
|
|
if(isturf(object))
|
|
var/turf/T = object
|
|
T.ScrapeAway(flags = CHANGETURF_INHERIT_AIR)
|
|
else if(isatom(object))
|
|
// SKYRAT EDIT -- BS delete sparks. Original was just qdel(object)
|
|
var/turf/T = get_turf(object)
|
|
qdel(object)
|
|
if(T && c.prefs.read_preference(/datum/preference/toggle/admin/delete_sparks))
|
|
playsound(T, 'sound/magic/Repulse.ogg', 100, 1)
|
|
var/datum/effect_system/spark_spread/quantum/sparks = new
|
|
sparks.set_up(10, 1, T)
|
|
sparks.attach(T)
|
|
sparks.start()
|
|
|
|
if(LAZYACCESS(modifiers, RIGHT_CLICK))
|
|
if(check_rights(R_DEBUG|R_SERVER)) //Prevents buildmoded non-admins from breaking everything.
|
|
if(isturf(object))
|
|
return
|
|
var/atom/deleting = object
|
|
var/action_type = tgui_alert(usr,"Strict type ([deleting.type]) or type and all subtypes?",,list("Strict type","Type and subtypes","Cancel"))
|
|
if(action_type == "Cancel" || !action_type)
|
|
return
|
|
|
|
if(tgui_alert(usr,"Are you really sure you want to delete all instances of type [deleting.type]?",,list("Yes","No")) != "Yes")
|
|
return
|
|
|
|
if(tgui_alert(usr,"Second confirmation required. Delete?",,list("Yes","No")) != "Yes")
|
|
return
|
|
|
|
var/O_type = deleting.type
|
|
switch(action_type)
|
|
if("Strict type")
|
|
var/i = 0
|
|
for(var/atom/Obj in world)
|
|
if(Obj.type == O_type)
|
|
i++
|
|
qdel(Obj)
|
|
CHECK_TICK
|
|
if(!i)
|
|
to_chat(usr, "No instances of this type exist")
|
|
return
|
|
log_admin("[key_name(usr)] deleted all instances of type [O_type] ([i] instances deleted) ")
|
|
message_admins(span_notice("[key_name(usr)] deleted all instances of type [O_type] ([i] instances deleted) "))
|
|
if("Type and subtypes")
|
|
var/i = 0
|
|
for(var/Obj in world)
|
|
if(istype(Obj,O_type))
|
|
i++
|
|
qdel(Obj)
|
|
CHECK_TICK
|
|
if(!i)
|
|
to_chat(usr, "No instances of this type exist")
|
|
return
|
|
log_admin("[key_name(usr)] deleted all instances of type or subtype of [O_type] ([i] instances deleted) ")
|
|
message_admins(span_notice("[key_name(usr)] deleted all instances of type or subtype of [O_type] ([i] instances deleted) "))
|