mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-18 13:04:45 +00:00
ae5a4f955d
## About The Pull Request Signals were initially only usable with component listeners, which while no longer the case has lead to outdated documentation, names, and a similar location in code. This pr pulls the two apart. Partially because mso thinks we should, but also because they really aren't directly linked anymore, and having them in this midstate just confuses people. [Renames comp_lookup to listen_lookup, since that's what it does](102b79694f) [Moves signal procs over to their own file](33d07d01fd) [Renames the PREQDELETING and QDELETING comsigs to drop the parent bit since they can hook to more then just comps now](335ea4ad08) [Does something similar to the attackby comsigs (PARENT -> ATOM)](210e57051d) [And finally passes over the examine signals](65917658fb) ## Why It's Good For The Game Code makes more sense, things are better teased apart, s just good imo ## Changelog 🆑 refactor: Pulled apart the last vestiges of names/docs directly linking signals to components /🆑
74 lines
2.4 KiB
Plaintext
74 lines
2.4 KiB
Plaintext
/*
|
|
* Dehydrated Carp
|
|
* Instant carp, just add water
|
|
*/
|
|
|
|
//Child of carpplushie because this should do everything the toy does and more
|
|
/obj/item/toy/plush/carpplushie/dehy_carp
|
|
var/mob/owner = null //Carp doesn't attack owner, set when using in hand
|
|
var/mobtype = /mob/living/basic/carp //So admins can change what mob spawns via var fuckery
|
|
var/swelling = FALSE
|
|
|
|
//Attack self
|
|
/obj/item/toy/plush/carpplushie/dehy_carp/attack_self(mob/user)
|
|
if(owner)
|
|
return ..()
|
|
add_fingerprint(user)
|
|
to_chat(user, span_notice("You pet [src]. You swear it looks up at you."))
|
|
owner = user
|
|
RegisterSignal(owner, COMSIG_QDELETING, PROC_REF(owner_deleted))
|
|
|
|
/obj/item/toy/plush/carpplushie/dehy_carp/plop(obj/item/toy/plush/Daddy)
|
|
return FALSE
|
|
|
|
/obj/item/toy/plush/carpplushie/dehy_carp/proc/Swell()
|
|
if(swelling)
|
|
return
|
|
swelling = TRUE
|
|
desc = "It's growing!"
|
|
visible_message(span_notice("[src] swells up!"))
|
|
|
|
//Animation
|
|
icon = 'icons/mob/simple/carp.dmi'
|
|
flick("carp_swell", src)
|
|
//Wait for animation to end
|
|
addtimer(CALLBACK(src, PROC_REF(spawn_carp)), 0.6 SECONDS)
|
|
|
|
/obj/item/toy/plush/carpplushie/dehy_carp/suicide_act(mob/living/carbon/human/user)
|
|
user.visible_message(span_suicide("[user] starts eating [src]. It looks like [user.p_theyre()] trying to commit suicide!"))
|
|
playsound(src, 'sound/items/eatfood.ogg', 50, TRUE)
|
|
if(!istype(user))
|
|
return BRUTELOSS
|
|
user.Paralyze(3 SECONDS)
|
|
forceMove(user) //we move it AWAAAYY
|
|
sleep(2 SECONDS)
|
|
if(QDELETED(src))
|
|
return SHAME
|
|
if(!QDELETED(user))
|
|
user.spawn_gibs()
|
|
user.apply_damage(200, def_zone = BODY_ZONE_CHEST)
|
|
forceMove(drop_location()) //we move it back
|
|
swelling = TRUE
|
|
icon = 'icons/mob/simple/carp.dmi'
|
|
flick("carp_swell", src)
|
|
addtimer(CALLBACK(src, PROC_REF(spawn_carp)), 0.6 SECONDS)
|
|
return BRUTELOSS
|
|
|
|
/obj/item/toy/plush/carpplushie/dehy_carp/proc/spawn_carp()
|
|
if(QDELETED(src))//we got toasted while animating
|
|
return
|
|
//Make space carp
|
|
var/mob/living/spawned_mob = new mobtype(get_turf(src), owner)
|
|
//Make carp non-hostile to user
|
|
if(owner)
|
|
spawned_mob.faction = list("[REF(owner)]")
|
|
for(var/mob/living/viewer in viewers(5, get_turf(src)))
|
|
to_chat(viewer, viewer == owner ? span_notice("The newly grown [spawned_mob.name] looks up at you with friendly eyes.") : span_warning("You have a bad feeling about this."))
|
|
qdel(src)
|
|
|
|
/obj/item/toy/plush/carpplushie/dehy_carp/proc/owner_deleted(datum/source)
|
|
SIGNAL_HANDLER
|
|
|
|
UnregisterSignal(owner, COMSIG_QDELETING)
|
|
owner = null
|