mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-10 17:04:36 +00:00
9e4df6aa78
Adds a simple way to quarantine individuals but doesn't make it roundstart, as it has potential to make 2 antags have a very difficult time: Bad virologists and (mainly) sentient diseases. Uses a sliver of silver because of this. It uses the exact same proc as the MEDHUD, so it CAN be countered by buffing stealth. Virologists can also activate the free-access so long as they do it while not infected with anything bad. That said, it has a build delay and is relatively easy to destroy. Think of it as a more obvious visual for people without huds to know "hey, I should probably avoid everyone else until I get better" and not necessarily an actual barrier device. sprites edited by me if you like them, by someone else if you don't!
171 lines
5.4 KiB
Plaintext
171 lines
5.4 KiB
Plaintext
|
|
//holographic signs and barriers
|
|
|
|
/obj/structure/holosign
|
|
name = "holo sign"
|
|
icon = 'icons/effects/effects.dmi'
|
|
anchored = TRUE
|
|
max_integrity = 1
|
|
armor = list("melee" = 0, "bullet" = 50, "laser" = 50, "energy" = 50, "bomb" = 0, "bio" = 0, "rad" = 0, "fire" = 20, "acid" = 20)
|
|
var/obj/item/holosign_creator/projector
|
|
|
|
/obj/structure/holosign/New(loc, source_projector)
|
|
if(source_projector)
|
|
projector = source_projector
|
|
projector.signs += src
|
|
..()
|
|
|
|
/obj/structure/holosign/Destroy()
|
|
if(projector)
|
|
projector.signs -= src
|
|
projector = null
|
|
return ..()
|
|
|
|
/obj/structure/holosign/attack_hand(mob/living/user)
|
|
. = ..()
|
|
if(.)
|
|
return
|
|
user.do_attack_animation(src, ATTACK_EFFECT_PUNCH)
|
|
user.changeNext_move(CLICK_CD_MELEE)
|
|
take_damage(5 , BRUTE, "melee", 1)
|
|
|
|
/obj/structure/holosign/play_attack_sound(damage_amount, damage_type = BRUTE, damage_flag = 0)
|
|
switch(damage_type)
|
|
if(BRUTE)
|
|
playsound(loc, 'sound/weapons/egloves.ogg', 80, 1)
|
|
if(BURN)
|
|
playsound(loc, 'sound/weapons/egloves.ogg', 80, 1)
|
|
|
|
/obj/structure/holosign/wetsign
|
|
name = "wet floor sign"
|
|
desc = "The words flicker as if they mean nothing."
|
|
icon = 'icons/effects/effects.dmi'
|
|
icon_state = "holosign"
|
|
|
|
/obj/structure/holosign/barrier
|
|
name = "holo barrier"
|
|
desc = "A short holographic barrier which can only be passed by walking."
|
|
icon_state = "holosign_sec"
|
|
pass_flags = LETPASSTHROW
|
|
density = TRUE
|
|
max_integrity = 20
|
|
var/allow_walk = 1 //can we pass through it on walk intent
|
|
|
|
/obj/structure/holosign/barrier/CanPass(atom/movable/mover, turf/target)
|
|
if(!density)
|
|
return 1
|
|
if(mover.pass_flags & (PASSGLASS|PASSTABLE|PASSGRILLE))
|
|
return 1
|
|
if(iscarbon(mover))
|
|
var/mob/living/carbon/C = mover
|
|
if(allow_walk && C.m_intent == MOVE_INTENT_WALK)
|
|
return 1
|
|
|
|
/obj/structure/holosign/barrier/engineering
|
|
icon_state = "holosign_engi"
|
|
|
|
/obj/structure/holosign/barrier/engineering/ComponentInitialize()
|
|
. = ..()
|
|
AddComponent(/datum/component/rad_insulation, RAD_LIGHT_INSULATION)
|
|
|
|
/obj/structure/holosign/barrier/atmos
|
|
name = "holo firelock"
|
|
desc = "A holographic barrier resembling a firelock. Though it does not prevent solid objects from passing through, gas is kept out."
|
|
icon_state = "holo_firelock"
|
|
density = FALSE
|
|
layer = ABOVE_MOB_LAYER
|
|
anchored = TRUE
|
|
CanAtmosPass = ATMOS_PASS_NO
|
|
layer = ABOVE_MOB_LAYER
|
|
alpha = 150
|
|
|
|
/obj/structure/holosign/barrier/atmos/Initialize()
|
|
. = ..()
|
|
air_update_turf(TRUE)
|
|
|
|
/obj/structure/holosign/barrier/cyborg
|
|
name = "Energy Field"
|
|
desc = "A fragile energy field that blocks movement. Excels at blocking lethal projectiles."
|
|
density = TRUE
|
|
max_integrity = 10
|
|
allow_walk = 0
|
|
|
|
/obj/structure/holosign/barrier/cyborg/bullet_act(obj/item/projectile/P)
|
|
take_damage((P.damage / 5) , BRUTE, "melee", 1) //Doesn't really matter what damage flag it is.
|
|
if(istype(P, /obj/item/projectile/energy/electrode))
|
|
take_damage(10, BRUTE, "melee", 1) //Tasers aren't harmful.
|
|
if(istype(P, /obj/item/projectile/beam/disabler))
|
|
take_damage(5, BRUTE, "melee", 1) //Disablers aren't harmful.
|
|
|
|
/obj/structure/holosign/barrier/medical
|
|
name = "\improper PENLITE holobarrier"
|
|
desc = "A holobarrier that uses biometrics to detect human viruses. Denies passing to personnel with easily-detected, malicious viruses. Good for quarantines."
|
|
icon_state = "holo_medical"
|
|
alpha = 125 //lazy :)
|
|
layer = ABOVE_MOB_LAYER
|
|
var/force_allaccess = FALSE
|
|
var/buzzcd = 0
|
|
|
|
/obj/structure/holosign/barrier/medical/examine(mob/user)
|
|
..()
|
|
to_chat(user,"<span class='notice'>The biometric scanners are <b>[force_allaccess ? "off" : "on"]</b>.</span>")
|
|
|
|
/obj/structure/holosign/barrier/medical/CanPass(atom/movable/mover, turf/target)
|
|
icon_state = "holo_medical"
|
|
if(force_allaccess)
|
|
return TRUE
|
|
if(ishuman(mover))
|
|
var/mob/living/carbon/human/sickboi = mover
|
|
var/threat = sickboi.check_virus()
|
|
switch(threat)
|
|
if(DISEASE_SEVERITY_MINOR, DISEASE_SEVERITY_MEDIUM, DISEASE_SEVERITY_HARMFUL, DISEASE_SEVERITY_DANGEROUS, DISEASE_SEVERITY_BIOHAZARD)
|
|
if(buzzcd < world.time)
|
|
playsound(get_turf(src),'sound/machines/buzz-sigh.ogg',65,1,4)
|
|
buzzcd = (world.time + 60)
|
|
icon_state = "holo_medical-deny"
|
|
return FALSE
|
|
else
|
|
return TRUE //nice or benign diseases!
|
|
return TRUE
|
|
|
|
/obj/structure/holosign/barrier/medical/attack_hand(mob/living/user)
|
|
if(CanPass(user) && user.a_intent == INTENT_HELP)
|
|
force_allaccess = !force_allaccess
|
|
to_chat(user, "<span class='warning'>You [force_allaccess ? "deactivate" : "activate"] the biometric scanners.</span>") //warning spans because you can make the station sick!
|
|
else
|
|
return ..()
|
|
|
|
/obj/structure/holosign/barrier/cyborg/hacked
|
|
name = "Charged Energy Field"
|
|
desc = "A powerful energy field that blocks movement. Energy arcs off it."
|
|
max_integrity = 20
|
|
var/shockcd = 0
|
|
|
|
/obj/structure/holosign/barrier/cyborg/hacked/bullet_act(obj/item/projectile/P)
|
|
take_damage(P.damage, BRUTE, "melee", 1) //Yeah no this doesn't get projectile resistance.
|
|
|
|
/obj/structure/holosign/barrier/cyborg/hacked/proc/cooldown()
|
|
shockcd = FALSE
|
|
|
|
/obj/structure/holosign/barrier/cyborg/hacked/attack_hand(mob/living/user)
|
|
. = ..()
|
|
if(.)
|
|
return
|
|
if(!shockcd)
|
|
if(ismob(user))
|
|
var/mob/living/M = user
|
|
M.electrocute_act(15,"Energy Barrier", safety=1)
|
|
shockcd = TRUE
|
|
addtimer(CALLBACK(src, .proc/cooldown), 5)
|
|
|
|
/obj/structure/holosign/barrier/cyborg/hacked/Bumped(atom/movable/AM)
|
|
if(shockcd)
|
|
return
|
|
|
|
if(!ismob(AM))
|
|
return
|
|
|
|
var/mob/living/M = AM
|
|
M.electrocute_act(15,"Energy Barrier", safety=1)
|
|
shockcd = TRUE
|
|
addtimer(CALLBACK(src, .proc/cooldown), 5) |