mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-10 09:42:29 +00:00
eba6cc5306
* Stack overflow detection for the Master Controller. Using a weakref, we can detect if the mc's stack was ended by byond due to a stack overflow, and restart it without waiting the entire defcon countdown in the failsafe controller. I built a system around this concept under /datum/stack_end_detector and deployed it to the MC's main loop with checks in the failsafe controller.
33 lines
1001 B
Plaintext
33 lines
1001 B
Plaintext
/**
|
|
Stack End Detector.
|
|
Can detect if a given code stack has exited, used by the mc for stack overflow detection.
|
|
|
|
**/
|
|
/datum/stack_end_detector
|
|
var/datum/weakref/_WF
|
|
var/datum/stack_canary/_canary
|
|
|
|
/datum/stack_end_detector/New()
|
|
_canary = new()
|
|
_WF = WEAKREF(_canary)
|
|
|
|
/** Prime the stack overflow detector.
|
|
Store the return value of this proc call in a proc level var.
|
|
Can only be called once.
|
|
**/
|
|
/datum/stack_end_detector/proc/prime_canary()
|
|
if (!_canary)
|
|
CRASH("Prime_canary called twice")
|
|
. = _canary
|
|
_canary = null
|
|
|
|
/// Returns true if the stack is still going. Calling before the canary has been primed also returns true
|
|
/datum/stack_end_detector/proc/check()
|
|
return !!_WF.resolve()
|
|
|
|
/// Stack canary. Will go away if the stack it was primed by is ended by byond for return or stack overflow reasons.
|
|
/datum/stack_canary
|
|
|
|
/// empty proc to avoid warnings about unused variables. Call this proc on your canary in the stack it's watching.
|
|
/datum/stack_canary/proc/use_variable()
|