mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-10 09:42:29 +00:00
4d6a8bc537
Makes the code compatible with 515.1594+
Few simple changes and one very painful one.
Let's start with the easy:
* puts call behind `LIBCALL` define, so call_ext is properly used in 515
* Adds `NAMEOF_STATIC(_,X)` macro for nameof in static definitions since
src is now invalid there.
* Fixes tgui and devserver. From 515 onward the tmp3333{procid} cache
directory is not appened to base path in browser controls so we don't
check for it in base js and put the dev server dummy window file in
actual directory not the byond root.
* Renames the few things that had /final/ in typepath to ultimate since
final is a new keyword
And the very painful change:
`.proc/whatever` format is no longer valid, so we're replacing it with
new nameof() function. All this wrapped in three new macros.
`PROC_REF(X)`,`TYPE_PROC_REF(TYPE,X)`,`GLOBAL_PROC_REF(X)`. Global is
not actually necessary but if we get nameof that does not allow globals
it would be nice validation.
This is pretty unwieldy but there's no real alternative.
If you notice anything weird in the commits let me know because majority
was done with regex replace.
@tgstation/commit-access Since the .proc/stuff is pretty big change.
Co-authored-by: san7890 <the@san7890.com>
Co-authored-by: Mothblocks <35135081+Mothblocks@users.noreply.github.com>
83 lines
3.3 KiB
Plaintext
83 lines
3.3 KiB
Plaintext
/datum/component/jousting
|
|
var/current_direction = NONE
|
|
var/max_tile_charge = 5
|
|
var/min_tile_charge = 2 //tiles before this code gets into effect.
|
|
var/current_tile_charge = 0
|
|
var/movement_reset_tolerance = 3 //deciseconds
|
|
var/unmounted_damage_boost_per_tile = 0
|
|
var/unmounted_knockdown_chance_per_tile = 0
|
|
var/unmounted_knockdown_time = 0
|
|
var/mounted_damage_boost_per_tile = 2
|
|
var/mounted_knockdown_chance_per_tile = 20
|
|
var/mounted_knockdown_time = 20
|
|
var/requires_mob_riding = TRUE //whether this only works if the attacker is riding a mob, rather than anything they can buckle to.
|
|
var/requires_mount = TRUE //kinda defeats the point of jousting if you're not mounted but whatever.
|
|
var/mob/current_holder
|
|
var/current_timerid
|
|
|
|
/datum/component/jousting/Initialize()
|
|
if(!isitem(parent))
|
|
return COMPONENT_INCOMPATIBLE
|
|
RegisterSignal(parent, COMSIG_ITEM_EQUIPPED, PROC_REF(on_equip))
|
|
RegisterSignal(parent, COMSIG_ITEM_DROPPED, PROC_REF(on_drop))
|
|
RegisterSignal(parent, COMSIG_ITEM_ATTACK, PROC_REF(on_attack))
|
|
|
|
/datum/component/jousting/proc/on_equip(datum/source, mob/user, slot)
|
|
SIGNAL_HANDLER
|
|
|
|
RegisterSignal(user, COMSIG_MOVABLE_MOVED, PROC_REF(mob_move), TRUE)
|
|
current_holder = user
|
|
|
|
/datum/component/jousting/proc/on_drop(datum/source, mob/user)
|
|
SIGNAL_HANDLER
|
|
|
|
UnregisterSignal(user, COMSIG_MOVABLE_MOVED)
|
|
current_holder = null
|
|
current_direction = NONE
|
|
current_tile_charge = 0
|
|
|
|
/datum/component/jousting/proc/on_attack(datum/source, mob/living/target, mob/user)
|
|
SIGNAL_HANDLER
|
|
|
|
if(user != current_holder)
|
|
return
|
|
var/current = current_tile_charge
|
|
var/obj/item/I = parent
|
|
var/target_buckled = target.buckled ? TRUE : FALSE //we don't need the reference of what they're buckled to, just whether they are.
|
|
if((requires_mount && ((requires_mob_riding && !ismob(user.buckled)) || (!user.buckled))) || !current_direction || (current_tile_charge < min_tile_charge))
|
|
return
|
|
var/turf/target_turf = get_step(user, current_direction)
|
|
if(target in range(1, target_turf))
|
|
var/knockdown_chance = (target_buckled? mounted_knockdown_chance_per_tile : unmounted_knockdown_chance_per_tile) * current
|
|
var/knockdown_time = (target_buckled? mounted_knockdown_time : unmounted_knockdown_time)
|
|
var/damage = (target_buckled? mounted_damage_boost_per_tile : unmounted_damage_boost_per_tile) * current
|
|
var/sharp = I.get_sharpness()
|
|
var/msg
|
|
if(damage)
|
|
msg += "[user] [sharp? "impales" : "slams into"] [target] [sharp? "on" : "with"] their [parent]"
|
|
target.apply_damage(damage, BRUTE, user.zone_selected, 0)
|
|
if(prob(knockdown_chance))
|
|
msg += " and knocks [target] [target_buckled? "off of [target.buckled]" : "down"]"
|
|
if(target_buckled)
|
|
target.buckled.unbuckle_mob(target)
|
|
target.Paralyze(knockdown_time)
|
|
if(length(msg))
|
|
user.visible_message(span_danger("[msg]!"))
|
|
|
|
/datum/component/jousting/proc/mob_move(datum/source, newloc, dir)
|
|
SIGNAL_HANDLER
|
|
|
|
if(!current_holder || (requires_mount && ((requires_mob_riding && !ismob(current_holder.buckled)) || (!current_holder.buckled))))
|
|
return
|
|
if(dir != current_direction)
|
|
current_tile_charge = 0
|
|
current_direction = dir
|
|
if(current_tile_charge < max_tile_charge)
|
|
current_tile_charge++
|
|
if(current_timerid)
|
|
deltimer(current_timerid)
|
|
current_timerid = addtimer(CALLBACK(src, PROC_REF(reset_charge)), movement_reset_tolerance, TIMER_STOPPABLE)
|
|
|
|
/datum/component/jousting/proc/reset_charge()
|
|
current_tile_charge = 0
|