mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-01 04:21:42 +00:00
bca463316b
About The Pull Request
Separated compiling the integration tests and running them as separate steps for organization purposes.
Added a TEST_ASSERT_NULL(value, reason) and TEST_ASSERT_NOTNULL(value, reason) because those are conceptually simple tests.
Makes the PASS and FAIL prefixes in the integration test log be green and red for better readability.
Failure reasons now display the file and line number.
In order to achieve this, direct calls to Fail() are now wrapped in a macro, TEST_FAIL(), as Fail() itself needs preprocessor stuff passed to it.
In the midst of updating it, I noticed multiple cases of tests directly calling Fail() and returning when they should have used a better macro, so those were updated. There was at least one case where it appeared that the code assumed that the test ended at Fail(), but made no attempt to do so, such as with the RCD test.
Feel free to double check all of the changed unit tests in case I made a functional behavior change, but they currently pass.
To take advantage of the previous change, failures are now marked as annotations. Note that outside of github, this creates an ugly-looking line but the primary environment is as a github action.
Examples with intentionally botched unit test:
image
image
image
Why It's Good For The Game
Makes inspecting failed unit tests significantly easier.
Changelog
N/A
56 lines
2.5 KiB
Plaintext
56 lines
2.5 KiB
Plaintext
/datum/unit_test/chain_pull_through_space
|
|
var/turf/open/space/space_tile
|
|
var/claimed_tile
|
|
var/mob/living/carbon/human/alice
|
|
var/mob/living/carbon/human/bob
|
|
var/mob/living/carbon/human/charlie
|
|
|
|
/datum/unit_test/chain_pull_through_space/New()
|
|
..()
|
|
|
|
// Create a space tile that goes to another z-level
|
|
claimed_tile = run_loc_floor_bottom_left.type
|
|
|
|
space_tile = new(locate(run_loc_floor_bottom_left.x, run_loc_floor_bottom_left.y, run_loc_floor_bottom_left.z))
|
|
space_tile.destination_x = 100
|
|
space_tile.destination_y = 100
|
|
space_tile.destination_z = 5
|
|
|
|
// Create our list of humans, all adjacent to one another
|
|
alice = new(locate(run_loc_floor_bottom_left.x + 2, run_loc_floor_bottom_left.y, run_loc_floor_bottom_left.z))
|
|
alice.name = "Alice"
|
|
|
|
bob = new(locate(run_loc_floor_bottom_left.x + 3, run_loc_floor_bottom_left.y, run_loc_floor_bottom_left.z))
|
|
bob.name = "Bob"
|
|
|
|
charlie = new(locate(run_loc_floor_bottom_left.x + 4, run_loc_floor_bottom_left.y, run_loc_floor_bottom_left.z))
|
|
charlie.name = "Charlie"
|
|
|
|
/datum/unit_test/chain_pull_through_space/Destroy()
|
|
space_tile.ChangeTurf(claimed_tile)
|
|
qdel(alice)
|
|
qdel(bob)
|
|
qdel(charlie)
|
|
return ..()
|
|
|
|
/datum/unit_test/chain_pull_through_space/Run()
|
|
// Alice pulls Bob, who pulls Charlie
|
|
// Normally, when Alice moves forward, the rest follow
|
|
alice.start_pulling(bob)
|
|
bob.start_pulling(charlie)
|
|
|
|
// Walk normally to the left, make sure we're still a chain
|
|
alice.Move(locate(run_loc_floor_bottom_left.x + 1, run_loc_floor_bottom_left.y, run_loc_floor_bottom_left.z))
|
|
TEST_ASSERT_EQUAL(bob.x, run_loc_floor_bottom_left.x + 2, "During normal move, Bob was not at the correct x ([bob.x])")
|
|
TEST_ASSERT_EQUAL(charlie.x, run_loc_floor_bottom_left.x + 3, "During normal move, Charlie was not at the correct x ([charlie.x])")
|
|
|
|
// We're going through the space turf now that should teleport us
|
|
alice.Move(run_loc_floor_bottom_left)
|
|
TEST_ASSERT_EQUAL(alice.z, space_tile.destination_z, "Alice did not teleport to the destination z-level. Current location: ([alice.x], [alice.y], [alice.z])")
|
|
|
|
TEST_ASSERT_EQUAL(bob.z, space_tile.destination_z, "Bob did not teleport to the destination z-level. Current location: ([bob.x], [bob.y], [bob.z])")
|
|
TEST_ASSERT(bob.Adjacent(alice), "Bob is not adjacent to Alice. Bob is at [bob.x], Alice is at [alice.x]")
|
|
|
|
TEST_ASSERT_EQUAL(charlie.z, space_tile.destination_z, "Charlie did not teleport to the destination z-level. Current location: ([charlie.x], [charlie.y], [charlie.z])")
|
|
TEST_ASSERT(charlie.Adjacent(bob), "Charlie is not adjacent to Bob. Charlie is at [charlie.x], Bob is at [bob.x]")
|