mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-28 10:01:58 +00:00
d656f0f4ec
## About The Pull Request So, some admin verbs/tools that used tguis, i.e edit/debug planes, were available to admins with +DEBUG... but the ui_state used `GLOB.admin_state`, which checks for +ADMIN - meaning that if they _only_ had +DEBUG, they would have the verb... but it would do nothing when they used it. I've refactored `GLOB.admin_state`, `GLOB.debug_state`, and `GLOB.fun_state` into a merged `/datum/ui_state/admin_state`, with a var for which specific permissions are being checked for. You now use the `ADMIN_STATE(perms)` macro to get the UI state for those specific perms, i.e `admin_state(R_ADMIN)` or `admin_state(R_DEBUG)`, and the resulting UI state will check for _those specific perms_. These are initialized and cached in `GLOB.admin_states` (which should never be directly accessed). So, I've went thru every single usage of `GLOB.admin_state`, `GLOB.fun_state`, and `GLOB.debug_state`, and made them all use `ADMIN_STATE()` with the actual permission flags needed to use said UI in the first place. ## Why It's Good For The Game Kinda dumb for specific admin permissions to be granted verbs that don't let them use it anyways. ## Changelog 🆑 admin: Certain UI-based tools (plane debugger, filter editor, etc) that were given to admins with only +VAREDIT or +DEBUG, but refused to open without +ADMIN, now actually work for admins that have the needed permission. /🆑
85 lines
3.0 KiB
Plaintext
85 lines
3.0 KiB
Plaintext
//very similar to centcom_podlauncher in terms of how this is coded, so i kept a lot of comments from it
|
|
|
|
ADMIN_VERB(ghost_pool_protection, R_ADMIN, "Ghost Pool Protection", "Choose which ways people can get into the round, or just clear it out completely for admin events.", ADMIN_CATEGORY_EVENTS)
|
|
var/datum/ghost_pool_menu/tgui = new(user)
|
|
tgui.ui_interact(user.mob)
|
|
|
|
/datum/ghost_pool_menu
|
|
var/client/holder //client of whoever is using this datum
|
|
|
|
//when submitted, what the pool flags will be set to
|
|
var/new_role_flags = ALL
|
|
|
|
//EVERY TYPE OF WAY SOMEONE IS GETTING BACK INTO THE ROUND!
|
|
//these are the same comments as the ones in admin.dm defines, please update those if you change them here
|
|
/*
|
|
var/events_or_midrounds = TRUE //ie fugitives, space dragon, etc. also includes dynamic midrounds as it's the same deal
|
|
var/spawners = TRUE //ie ashwalkers, free golems, beach bums
|
|
var/station_sentience = TRUE //ie posibrains, mind monkeys, sentience potion, etc.
|
|
var/minigames = TRUE //ie mafia, ctf
|
|
var/misc = TRUE //oddities like split personality and any animal ones like spiders, xenos
|
|
*/
|
|
|
|
/datum/ghost_pool_menu/New(user)//user can either be a client or a mob due to byondcode(tm)
|
|
if (istype(user, /client))
|
|
var/client/user_client = user
|
|
holder = user_client //if its a client, assign it to holder
|
|
else
|
|
var/mob/user_mob = user
|
|
holder = user_mob.client //if its a mob, assign the mob's client to holder
|
|
new_role_flags = GLOB.ghost_role_flags
|
|
|
|
/datum/ghost_pool_menu/ui_state(mob/user)
|
|
return ADMIN_STATE(R_ADMIN)
|
|
|
|
/datum/ghost_pool_menu/ui_close()
|
|
qdel(src)
|
|
|
|
/datum/ghost_pool_menu/ui_interact(mob/user, datum/tgui/ui)
|
|
ui = SStgui.try_update_ui(user, src, ui)
|
|
if(!ui)
|
|
ui = new(user, src, "GhostPoolProtection")
|
|
ui.open()
|
|
|
|
/datum/ghost_pool_menu/ui_data(mob/user)
|
|
var/list/data = list()
|
|
data["events_or_midrounds"] = (new_role_flags & GHOSTROLE_MIDROUND_EVENT)
|
|
data["spawners"] = (new_role_flags & GHOSTROLE_SPAWNER)
|
|
data["station_sentience"] = (new_role_flags & GHOSTROLE_STATION_SENTIENCE)
|
|
data["silicons"] = (new_role_flags & GHOSTROLE_SILICONS)
|
|
data["minigames"] = (new_role_flags & GHOSTROLE_MINIGAME)
|
|
return data
|
|
|
|
/datum/ghost_pool_menu/ui_act(action, list/params, datum/tgui/ui, datum/ui_state/state)
|
|
. = ..()
|
|
if(.)
|
|
return
|
|
. = TRUE
|
|
switch(action)
|
|
if("toggle_events_or_midrounds")
|
|
new_role_flags ^= GHOSTROLE_MIDROUND_EVENT
|
|
if("toggle_spawners")
|
|
new_role_flags ^= GHOSTROLE_SPAWNER
|
|
if("toggle_station_sentience")
|
|
new_role_flags ^= GHOSTROLE_STATION_SENTIENCE
|
|
if("toggle_silicons")
|
|
new_role_flags ^= GHOSTROLE_SILICONS
|
|
if("toggle_minigames")
|
|
new_role_flags ^= GHOSTROLE_MINIGAME
|
|
if("all_roles")
|
|
new_role_flags = ALL
|
|
if("no_roles")
|
|
new_role_flags = NONE
|
|
if("apply_settings")
|
|
to_chat(usr, "Settings Applied!")
|
|
var/msg
|
|
switch(new_role_flags)
|
|
if(ALL)
|
|
msg = "enabled all of"
|
|
if(NONE)
|
|
msg = "disabled all of"
|
|
else
|
|
msg = "modified"
|
|
message_admins("[key_name_admin(holder)] has [msg] this round's allowed ghost roles.")
|
|
GLOB.ghost_role_flags = new_role_flags
|