mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-27 01:21:30 +00:00
58501dce77
## About The Pull Request <details> - renamed ai folder to announcer -- announcer -- - moved vox_fem to announcer - moved approachingTG to announcer - separated the ambience folder into ambience and instrumental -- ambience -- - created holy folder moved all related sounds there - created engineering folder and moved all related sounds there - created security folder and moved ambidet there - created general folder and moved ambigen there - created icemoon folder and moved all icebox-related ambience there - created medical folder and moved all medbay-related ambi there - created ruin folder and moves all ruins ambi there - created beach folder and moved seag and shore there - created lavaland folder and moved related ambi there - created aurora_caelus folder and placed its ambi there - created misc folder and moved the rest of the files that don't have a specific category into it -- instrumental -- - moved traitor folder here - created lobby_music folder and placed our songs there (title0 not used anywhere? - server-side modification?) -- items -- - moved secdeath to hailer - moved surgery to handling -- effects -- - moved chemistry into effects - moved hallucinations into effects - moved health into effects - moved magic into effects -- vehicles -- - moved mecha into vehicles created mobs folder -- mobs -- - moved creatures folder into mobs - moved voice into mobs renamed creatures to non-humanoids renamed voice to humanoids -- non-humanoids-- created cyborg folder created hiss folder moved harmalarm.ogg to cyborg -- humanoids -- -- misc -- moved ghostwhisper to misc moved insane_low_laugh to misc I give up trying to document this. </details> - [X] ambience - [x] announcer - [x] effects - [X] instrumental - [x] items - [x] machines - [x] misc - [X] mobs - [X] runtime - [X] vehicles - [ ] attributions ## Why It's Good For The Game This folder is so disorganized that it's vomit inducing, will make it easier to find and add new sounds, providng a minor structure to the sound folder. ## Changelog 🆑 grungussuss refactor: the sound folder in the source code has been reorganized, please report any oddities with sounds playing or not playing server: lobby music has been repathed to sound/music/lobby_music /🆑
93 lines
3.8 KiB
Plaintext
93 lines
3.8 KiB
Plaintext
/datum/surgery/brain_surgery
|
|
name = "Brain surgery"
|
|
possible_locs = list(BODY_ZONE_HEAD)
|
|
steps = list(
|
|
/datum/surgery_step/incise,
|
|
/datum/surgery_step/retract_skin,
|
|
/datum/surgery_step/saw,
|
|
/datum/surgery_step/clamp_bleeders,
|
|
/datum/surgery_step/fix_brain,
|
|
/datum/surgery_step/close,
|
|
)
|
|
|
|
/datum/surgery/brain_surgery/mechanic
|
|
name = "Wetware OS Diagnostics"
|
|
requires_bodypart_type = BODYTYPE_ROBOTIC
|
|
possible_locs = list(BODY_ZONE_HEAD)
|
|
steps = list(
|
|
/datum/surgery_step/mechanic_open,
|
|
/datum/surgery_step/open_hatch,
|
|
/datum/surgery_step/mechanic_unwrench,
|
|
/datum/surgery_step/fix_brain/mechanic,
|
|
/datum/surgery_step/mechanic_wrench,
|
|
/datum/surgery_step/mechanic_close,
|
|
)
|
|
|
|
/datum/surgery_step/fix_brain
|
|
name = "fix brain (hemostat)"
|
|
implements = list(
|
|
TOOL_HEMOSTAT = 85,
|
|
TOOL_SCREWDRIVER = 35,
|
|
/obj/item/pen = 15) //don't worry, pouring some alcohol on their open brain will get that chance to 100
|
|
repeatable = TRUE
|
|
time = 100 //long and complicated
|
|
preop_sound = 'sound/items/handling/surgery/hemostat1.ogg'
|
|
success_sound = 'sound/items/handling/surgery/hemostat1.ogg'
|
|
failure_sound = 'sound/items/handling/surgery/organ2.ogg'
|
|
|
|
/datum/surgery_step/fix_brain/mechanic
|
|
name = "perform neural debugging (hemostat or multitool)"
|
|
implements = list(
|
|
TOOL_HEMOSTAT = 85,
|
|
TOOL_MULTITOOL = 85,
|
|
TOOL_SCREWDRIVER = 35,
|
|
/obj/item/pen = 15)
|
|
preop_sound = 'sound/items/taperecorder/tape_flip.ogg'
|
|
success_sound = 'sound/items/taperecorder/taperecorder_close.ogg'
|
|
|
|
/datum/surgery/brain_surgery/can_start(mob/user, mob/living/carbon/target)
|
|
return target.get_organ_slot(ORGAN_SLOT_BRAIN) && ..()
|
|
|
|
/datum/surgery_step/fix_brain/preop(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
display_results(
|
|
user,
|
|
target,
|
|
span_notice("You begin to fix [target]'s brain..."),
|
|
span_notice("[user] begins to fix [target]'s brain."),
|
|
span_notice("[user] begins to perform surgery on [target]'s brain."),
|
|
)
|
|
display_pain(target, "Your head pounds with unimaginable pain!")
|
|
|
|
/datum/surgery_step/fix_brain/success(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery/surgery, default_display_results = FALSE)
|
|
display_results(
|
|
user,
|
|
target,
|
|
span_notice("You succeed in fixing [target]'s brain."),
|
|
span_notice("[user] successfully fixes [target]'s brain!"),
|
|
span_notice("[user] completes the surgery on [target]'s brain."),
|
|
)
|
|
display_pain(target, "The pain in your head receeds, thinking becomes a bit easier!")
|
|
if(target.mind?.has_antag_datum(/datum/antagonist/brainwashed))
|
|
target.mind.remove_antag_datum(/datum/antagonist/brainwashed)
|
|
target.setOrganLoss(ORGAN_SLOT_BRAIN, target.get_organ_loss(ORGAN_SLOT_BRAIN) - 50) //we set damage in this case in order to clear the "failing" flag
|
|
target.cure_all_traumas(TRAUMA_RESILIENCE_SURGERY)
|
|
if(target.get_organ_loss(ORGAN_SLOT_BRAIN) > 0)
|
|
to_chat(user, "[target]'s brain looks like it could be fixed further.")
|
|
return ..()
|
|
|
|
/datum/surgery_step/fix_brain/failure(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
if(target.get_organ_slot(ORGAN_SLOT_BRAIN))
|
|
display_results(
|
|
user,
|
|
target,
|
|
span_warning("You screw up, causing more damage!"),
|
|
span_warning("[user] screws up, causing brain damage!"),
|
|
span_notice("[user] completes the surgery on [target]'s brain."),
|
|
)
|
|
display_pain(target, "Your head throbs with horrible pain; thinking hurts!")
|
|
target.adjustOrganLoss(ORGAN_SLOT_BRAIN, 60)
|
|
target.gain_trauma_type(BRAIN_TRAUMA_SEVERE, TRAUMA_RESILIENCE_LOBOTOMY)
|
|
else
|
|
user.visible_message(span_warning("[user] suddenly notices that the brain [user.p_they()] [user.p_were()] working on is not there anymore."), span_warning("You suddenly notice that the brain you were working on is not there anymore."))
|
|
return FALSE
|