mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-14 10:53:42 +00:00
75af862fee
* *blink *inhale *exhale *blink *inhale *blink *exhale * rapidly blinks * mass immersion * how was that even working * manual blinking today, manual breathing tomorrow * b * cleansed * more neatening * minus check * Update code/modules/admin/verbs/randomverbs.dm Co-Authored-By: Emmett Gaines <ninjanomnom@gmail.com> * un-nom's my code Co-Authored-By: Emmett Gaines <ninjanomnom@gmail.com> * un-nom's my code * less
82 lines
2.7 KiB
Plaintext
82 lines
2.7 KiB
Plaintext
//The code execution of the emote datum is located at code/datums/emotes.dm
|
|
/mob/proc/emote(act, m_type = null, message = null, intentional = FALSE)
|
|
act = lowertext(act)
|
|
var/param = message
|
|
var/custom_param = findchar(act, " ")
|
|
if(custom_param)
|
|
param = copytext(act, custom_param + 1, length(act) + 1)
|
|
act = copytext(act, 1, custom_param)
|
|
|
|
var/list/key_emotes = GLOB.emote_list[act]
|
|
|
|
if(!length(key_emotes))
|
|
if(intentional)
|
|
to_chat(src, "<span class='notice'>'[act]' emote does not exist. Say *help for a list.</span>")
|
|
return FALSE
|
|
var/silenced = FALSE
|
|
for(var/datum/emote/P in key_emotes)
|
|
if(!P.check_cooldown(src, intentional))
|
|
silenced = TRUE
|
|
continue
|
|
if(P.run_emote(src, param, m_type, intentional))
|
|
SEND_SIGNAL(src, COMSIG_MOB_EMOTE, P, act, m_type, message, intentional)
|
|
return TRUE
|
|
if(intentional && !silenced)
|
|
to_chat(src, "<span class='notice'>Unusable emote '[act]'. Say *help for a list.</span>")
|
|
return FALSE
|
|
|
|
/datum/emote/flip
|
|
key = "flip"
|
|
key_third_person = "flips"
|
|
restraint_check = TRUE
|
|
mob_type_allowed_typecache = list(/mob/living, /mob/dead/observer)
|
|
mob_type_ignore_stat_typecache = list(/mob/dead/observer)
|
|
|
|
/datum/emote/flip/run_emote(mob/user, params , type_override, intentional)
|
|
. = ..()
|
|
if(.)
|
|
user.SpinAnimation(7,1)
|
|
|
|
/datum/emote/flip/check_cooldown(mob/user, intentional)
|
|
. = ..()
|
|
if(.)
|
|
return
|
|
if(!can_run_emote(user, intentional=intentional))
|
|
return
|
|
if(isliving(user))
|
|
var/mob/living/flippy_mcgee = user
|
|
if(prob(20))
|
|
flippy_mcgee.Knockdown(1 SECONDS)
|
|
flippy_mcgee.visible_message(
|
|
"<span class='notice'>[flippy_mcgee] attempts to do a flip and falls over, what a doofus!</span>",
|
|
"<span class='notice'>You attempt to do a flip while still off balance from the last flip and fall down!</span>"
|
|
)
|
|
if(prob(50))
|
|
flippy_mcgee.adjustBruteLoss(1)
|
|
else
|
|
flippy_mcgee.visible_message(
|
|
"<span class='notice'>[flippy_mcgee] stumbles a bit after their flip.</span>",
|
|
"<span class='notice'>You stumble a bit from still being off balance from your last flip.</span>"
|
|
)
|
|
|
|
/datum/emote/spin
|
|
key = "spin"
|
|
key_third_person = "spins"
|
|
restraint_check = TRUE
|
|
mob_type_allowed_typecache = list(/mob/living, /mob/dead/observer)
|
|
mob_type_ignore_stat_typecache = list(/mob/dead/observer)
|
|
|
|
/datum/emote/spin/run_emote(mob/user, params , type_override, intentional)
|
|
. = ..()
|
|
if(.)
|
|
user.spin(20, 1)
|
|
|
|
if((iscyborg(user) || isanimal(user)) && user.has_buckled_mobs())
|
|
var/mob/living/L = user
|
|
var/datum/component/riding/riding_datum = L.GetComponent(/datum/component/riding)
|
|
if(riding_datum)
|
|
for(var/mob/M in L.buckled_mobs)
|
|
riding_datum.force_dismount(M)
|
|
else
|
|
L.unbuckle_all_mobs()
|