mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-25 00:22:39 +00:00
a48ba0d256
-Centcom announcement proc merged with generic priority announcement proc -Re-added the Captain Announces accompanied by a new pleasant sound, instead of the generic priority announcement -Captain Announcements will automatically generate a newscaster article -Priority announcements without any defined accompanying sound will play a generic "Attention" soundbyte as an audio cue -Communications consoles will display who is currently logged in
45 lines
1.5 KiB
Plaintext
45 lines
1.5 KiB
Plaintext
/datum/round_event_control/alien_infestation
|
|
name = "Alien Infestation"
|
|
typepath = /datum/round_event/alien_infestation
|
|
weight = 5
|
|
max_occurrences = 1
|
|
|
|
/datum/round_event/alien_infestation
|
|
announceWhen = 400
|
|
|
|
var/spawncount = 1
|
|
var/successSpawn = 0 //So we don't make a command report if nothing gets spawned.
|
|
|
|
|
|
/datum/round_event/alien_infestation/setup()
|
|
announceWhen = rand(announceWhen, announceWhen + 50)
|
|
spawncount = rand(1, 2)
|
|
|
|
/datum/round_event/alien_infestation/kill()
|
|
if(!successSpawn && control)
|
|
control.occurrences--
|
|
return ..()
|
|
|
|
/datum/round_event/alien_infestation/announce()
|
|
if(successSpawn)
|
|
priority_announce("Unidentified lifesigns detected coming aboard [station_name()]. Secure any exterior access, including ducting and ventilation.", "Lifesign Alert", 'sound/AI/aliens.ogg')
|
|
|
|
|
|
/datum/round_event/alien_infestation/start()
|
|
var/list/vents = list()
|
|
for(var/obj/machinery/atmospherics/unary/vent_pump/temp_vent in world)
|
|
if(temp_vent.loc.z == 1 && !temp_vent.welded && temp_vent.network)
|
|
if(temp_vent.network.normal_members.len > 20) //Stops Aliens getting stuck in small networks. See: Security, Virology
|
|
vents += temp_vent
|
|
|
|
var/list/candidates = get_candidates(BE_ALIEN, ALIEN_AFK_BRACKET)
|
|
|
|
while(spawncount > 0 && vents.len && candidates.len)
|
|
var/obj/vent = pick_n_take(vents)
|
|
var/client/C = pick_n_take(candidates)
|
|
|
|
var/mob/living/carbon/alien/larva/new_xeno = new(vent.loc)
|
|
new_xeno.key = C.key
|
|
|
|
spawncount--
|
|
successSpawn = 1 |