mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-02 21:11:57 +00:00
e65a48e91f
* Adds SIGNAL_HANDLER and SIGNAL_HANDLER_DOES_SLEEP to prevent signal callbacks from blocking (#52761) Adds SIGNAL_HANDLER, a macro that sets SHOULD_NOT_SLEEP(TRUE). This should ideally be required on all new signal callbacks. Adds BLOCKING_SIGNAL_HANDLER, a macro that does nothing except symbolize "this is an older signal that didn't necessitate a code rewrite". It should not be allowed for new work. This comes from discussion around #52735, which yields by calling input, and (though it sets the return type beforehand) will not properly return the flag to prevent attack from slapping. To fix 60% of the yielding cases, WrapAdminProcCall no longer waits for another admin's proc call to finish. I'm not an admin, so I don't know how many behinds this has saved, but if this is problematic for admins I can just make it so that it lets you do it anyway. I'm not sure what the point of this babysitting was anyway. Requested by @optimumtact. Changelog cl admin: Calling a proc while another admin is calling one will no longer wait for the first to finish. You will simply just have to call it again. /cl * Adds SIGNAL_HANDLER and SIGNAL_HANDLER_DOES_SLEEP to prevent signal callbacks from blocking Co-authored-by: Jared-Fogle <35135081+Jared-Fogle@users.noreply.github.com>
121 lines
4.0 KiB
Plaintext
121 lines
4.0 KiB
Plaintext
//Nearsightedness restricts your vision by several tiles.
|
|
/datum/mutation/human/nearsight
|
|
name = "Near Sightness"
|
|
desc = "The holder of this mutation has poor eyesight."
|
|
quality = MINOR_NEGATIVE
|
|
text_gain_indication = "<span class='danger'>You can't see very well.</span>"
|
|
|
|
/datum/mutation/human/nearsight/on_acquiring(mob/living/carbon/human/owner)
|
|
if(..())
|
|
return
|
|
owner.become_nearsighted(GENETIC_MUTATION)
|
|
|
|
/datum/mutation/human/nearsight/on_losing(mob/living/carbon/human/owner)
|
|
if(..())
|
|
return
|
|
owner.cure_nearsighted(GENETIC_MUTATION)
|
|
|
|
|
|
///Blind makes you blind. Who knew?
|
|
/datum/mutation/human/blind
|
|
name = "Blindness"
|
|
desc = "Renders the subject completely blind."
|
|
quality = NEGATIVE
|
|
text_gain_indication = "<span class='danger'>You can't seem to see anything.</span>"
|
|
|
|
/datum/mutation/human/blind/on_acquiring(mob/living/carbon/human/owner)
|
|
if(..())
|
|
return
|
|
owner.become_blind(GENETIC_MUTATION)
|
|
|
|
/datum/mutation/human/blind/on_losing(mob/living/carbon/human/owner)
|
|
if(..())
|
|
return
|
|
owner.cure_blind(GENETIC_MUTATION)
|
|
|
|
///Thermal Vision lets you see mobs through walls
|
|
/datum/mutation/human/thermal
|
|
name = "Thermal Vision"
|
|
desc = "The user of this genome can visually perceive the unique human thermal signature."
|
|
quality = POSITIVE
|
|
difficulty = 18
|
|
text_gain_indication = "<span class='notice'>You can see the heat rising off of your skin...</span>"
|
|
time_coeff = 2
|
|
instability = 25
|
|
var/visionflag = TRAIT_THERMAL_VISION
|
|
|
|
/datum/mutation/human/thermal/on_acquiring(mob/living/carbon/human/owner)
|
|
if(..())
|
|
return
|
|
|
|
ADD_TRAIT(owner, visionflag, GENETIC_MUTATION)
|
|
owner.update_sight()
|
|
|
|
/datum/mutation/human/thermal/on_losing(mob/living/carbon/human/owner)
|
|
if(..())
|
|
return
|
|
REMOVE_TRAIT(owner, visionflag, GENETIC_MUTATION)
|
|
owner.update_sight()
|
|
|
|
///X-ray Vision lets you see through walls.
|
|
/datum/mutation/human/thermal/x_ray
|
|
name = "X Ray Vision"
|
|
desc = "A strange genome that allows the user to see between the spaces of walls." //actual x-ray would mean you'd constantly be blasting rads, wich might be fun for later //hmb
|
|
text_gain_indication = "<span class='notice'>The walls suddenly disappear!</span>"
|
|
instability = 35
|
|
locked = TRUE
|
|
visionflag = TRAIT_XRAY_VISION
|
|
|
|
///Laser Eyes lets you shoot lasers from your eyes!
|
|
/datum/mutation/human/laser_eyes
|
|
name = "Laser Eyes"
|
|
desc = "Reflects concentrated light back from the eyes."
|
|
quality = POSITIVE
|
|
locked = TRUE
|
|
difficulty = 16
|
|
text_gain_indication = "<span class='notice'>You feel pressure building up behind your eyes.</span>"
|
|
layer_used = FRONT_MUTATIONS_LAYER
|
|
limb_req = BODY_ZONE_HEAD
|
|
|
|
/datum/mutation/human/laser_eyes/New(class_ = MUT_OTHER, timer, datum/mutation/human/copymut)
|
|
..()
|
|
if(!(type in visual_indicators))
|
|
visual_indicators[type] = list(mutable_appearance('icons/effects/genetics.dmi', "lasereyes", -FRONT_MUTATIONS_LAYER))
|
|
|
|
/datum/mutation/human/laser_eyes/on_acquiring(mob/living/carbon/human/H)
|
|
. = ..()
|
|
if(.)
|
|
return
|
|
RegisterSignal(H, COMSIG_MOB_ATTACK_RANGED, .proc/on_ranged_attack)
|
|
|
|
/datum/mutation/human/laser_eyes/on_losing(mob/living/carbon/human/H)
|
|
. = ..()
|
|
if(.)
|
|
return
|
|
UnregisterSignal(H, COMSIG_MOB_ATTACK_RANGED)
|
|
|
|
/datum/mutation/human/laser_eyes/get_visual_indicator()
|
|
return visual_indicators[type][1]
|
|
|
|
///Triggers on COMSIG_MOB_ATTACK_RANGED. Does the projectile shooting.
|
|
/datum/mutation/human/laser_eyes/proc/on_ranged_attack(mob/living/carbon/human/source, atom/target, mouseparams)
|
|
SIGNAL_HANDLER_DOES_SLEEP
|
|
|
|
if(source.a_intent != INTENT_HARM)
|
|
return
|
|
to_chat(source, "<span class='warning'>You shoot with your laser eyes!</span>")
|
|
source.changeNext_move(CLICK_CD_RANGE)
|
|
source.newtonian_move(get_dir(target, source))
|
|
var/obj/projectile/beam/laser_eyes/LE = new(source.loc)
|
|
LE.firer = source
|
|
LE.def_zone = ran_zone(source.zone_selected)
|
|
LE.preparePixelProjectile(target, source, mouseparams)
|
|
LE.fire()
|
|
playsound(source, 'sound/weapons/taser2.ogg', 75, TRUE)
|
|
|
|
///Projectile type used by laser eyes
|
|
/obj/projectile/beam/laser_eyes
|
|
name = "beam"
|
|
icon = 'icons/effects/genetics.dmi'
|
|
icon_state = "eyelasers"
|