mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-08-19 11:08:35 +01:00
b84a9f97b2
Co-authored-by: Watermelon914 <3052169-Watermelon914@users.noreply.gitlab.com> Co-authored-by: Mothblocks <35135081+Mothblocks@users.noreply.github.com> Co-authored-by: ATH1909 <42606352+ATH1909@users.noreply.github.com> Co-authored-by: Maurukas <66576896+Maurukas@users.noreply.github.com>
50 lines
1.4 KiB
Plaintext
50 lines
1.4 KiB
Plaintext
/obj/item/multitool/circuit
|
|
name = "circuit multitool"
|
|
desc = "A circuit multitool. Used to mark entities which can then be uploaded to components by pressing the upload button on a port. \
|
|
Acts as a normal multitool otherwise. Use in hand to clear marked entity so that you can mark another entity."
|
|
|
|
/// The marked atom of this multitool
|
|
var/atom/marked_atom
|
|
|
|
/obj/item/multitool/circuit/Destroy()
|
|
marked_atom = null
|
|
return ..()
|
|
|
|
/obj/item/multitool/circuit/examine(mob/user)
|
|
. = ..()
|
|
. += "<span class='notice'>It has [marked_atom? "a" : "no"] marked entity registered.</span>"
|
|
|
|
/obj/item/multitool/circuit/attack_self(mob/user, modifiers)
|
|
. = ..()
|
|
if(.)
|
|
return
|
|
if(!marked_atom)
|
|
return
|
|
|
|
say("Cleared marked targets.")
|
|
clear_marked_atom()
|
|
return TRUE
|
|
|
|
/obj/item/multitool/circuit/melee_attack_chain(mob/user, atom/target, params)
|
|
var/is_right_clicking = LAZYACCESS(params2list(params), RIGHT_CLICK)
|
|
|
|
if(marked_atom || !user.Adjacent(target) || is_right_clicking)
|
|
return ..()
|
|
|
|
say("Marked [target].")
|
|
marked_atom = target
|
|
RegisterSignal(marked_atom, COMSIG_PARENT_QDELETING, .proc/cleanup_marked_atom)
|
|
return TRUE
|
|
|
|
/// Clears the current marked atom
|
|
/obj/item/multitool/circuit/proc/clear_marked_atom()
|
|
if(!marked_atom)
|
|
return
|
|
UnregisterSignal(marked_atom, COMSIG_PARENT_QDELETING)
|
|
marked_atom = null
|
|
|
|
/obj/item/multitool/circuit/proc/cleanup_marked_atom(datum/source)
|
|
SIGNAL_HANDLER
|
|
if(source == marked_atom)
|
|
clear_marked_atom()
|