mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-15 20:22:07 +00:00
e65a48e91f
* Adds SIGNAL_HANDLER and SIGNAL_HANDLER_DOES_SLEEP to prevent signal callbacks from blocking (#52761) Adds SIGNAL_HANDLER, a macro that sets SHOULD_NOT_SLEEP(TRUE). This should ideally be required on all new signal callbacks. Adds BLOCKING_SIGNAL_HANDLER, a macro that does nothing except symbolize "this is an older signal that didn't necessitate a code rewrite". It should not be allowed for new work. This comes from discussion around #52735, which yields by calling input, and (though it sets the return type beforehand) will not properly return the flag to prevent attack from slapping. To fix 60% of the yielding cases, WrapAdminProcCall no longer waits for another admin's proc call to finish. I'm not an admin, so I don't know how many behinds this has saved, but if this is problematic for admins I can just make it so that it lets you do it anyway. I'm not sure what the point of this babysitting was anyway. Requested by @optimumtact. Changelog cl admin: Calling a proc while another admin is calling one will no longer wait for the first to finish. You will simply just have to call it again. /cl * Adds SIGNAL_HANDLER and SIGNAL_HANDLER_DOES_SLEEP to prevent signal callbacks from blocking Co-authored-by: Jared-Fogle <35135081+Jared-Fogle@users.noreply.github.com>
64 lines
2.0 KiB
Plaintext
64 lines
2.0 KiB
Plaintext
// This component is for forcing strange things into your pocket that fall out if you fall down
|
|
// Yes this exists purely for the spaghetti meme
|
|
|
|
/datum/component/spill
|
|
can_transfer = TRUE
|
|
var/preexisting_item_flags
|
|
|
|
var/list/droptext
|
|
var/list/dropsound
|
|
|
|
// droptext is an arglist for visible_message
|
|
// dropsound is a list of potential sounds that gets picked from
|
|
/datum/component/spill/Initialize(list/_droptext, list/_dropsound)
|
|
if(!isitem(parent))
|
|
return COMPONENT_INCOMPATIBLE
|
|
|
|
if(_droptext && !islist(_droptext))
|
|
_droptext = list(_droptext)
|
|
droptext = _droptext
|
|
|
|
if(_dropsound && !islist(_dropsound))
|
|
_dropsound = list(_dropsound)
|
|
dropsound = _dropsound
|
|
|
|
/datum/component/spill/PostTransfer()
|
|
if(!isitem(parent))
|
|
return COMPONENT_INCOMPATIBLE
|
|
|
|
/datum/component/spill/RegisterWithParent()
|
|
RegisterSignal(parent, COMSIG_ITEM_EQUIPPED, .proc/equip_react)
|
|
RegisterSignal(parent, COMSIG_ITEM_DROPPED, .proc/drop_react)
|
|
var/obj/item/master = parent
|
|
preexisting_item_flags = master.item_flags
|
|
master.item_flags |= ITEM_SLOT_POCKETS
|
|
|
|
/datum/component/spill/UnregisterFromParent()
|
|
UnregisterSignal(parent, list(COMSIG_ITEM_EQUIPPED, COMSIG_ITEM_DROPPED))
|
|
var/obj/item/master = parent
|
|
if(!(preexisting_item_flags & ITEM_SLOT_POCKETS))
|
|
master.item_flags &= ~ITEM_SLOT_POCKETS
|
|
|
|
/datum/component/spill/proc/equip_react(obj/item/source, mob/equipper, slot)
|
|
SIGNAL_HANDLER
|
|
|
|
if(slot == ITEM_SLOT_LPOCKET || slot == ITEM_SLOT_RPOCKET)
|
|
RegisterSignal(equipper, COMSIG_LIVING_STATUS_KNOCKDOWN, .proc/knockdown_react, TRUE)
|
|
else
|
|
UnregisterSignal(equipper, COMSIG_LIVING_STATUS_KNOCKDOWN)
|
|
|
|
/datum/component/spill/proc/drop_react(obj/item/source, mob/dropper)
|
|
SIGNAL_HANDLER
|
|
|
|
UnregisterSignal(dropper, COMSIG_LIVING_STATUS_KNOCKDOWN)
|
|
|
|
/datum/component/spill/proc/knockdown_react(mob/living/fool)
|
|
SIGNAL_HANDLER
|
|
|
|
var/obj/item/master = parent
|
|
fool.dropItemToGround(master)
|
|
if(droptext)
|
|
fool.visible_message(arglist(droptext))
|
|
if(dropsound)
|
|
playsound(master, pick(dropsound), 30)
|