mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-05 14:32:52 +00:00
0a1f06a2d1
* This tail refactor turned into an organ refactor. Funny how that works. * Firstly, fixing all the conflicts. * Fixes all our maps (hopefully) * Actually, this should fix pod people hair :) * Almost everything is working, just two major things to fix * Fixed a certain kind of external organ * Cleaning up some more stuff * Turned tail_cat into tail because why the fuck are they separate? * Moved all the tails into tails.dmi because that was just dumb to have like 3 in a different file * Adds relevant_layers to organs to help with rendering * Makes stored_feature_id also check mutant_bodyparts * Fixes the icon_state names of ALL the tails (pain) * Fixes wagging, gotta refactor most mutant bodyparts later on * I Love Added Failures * Fixed some organs that slipped through my searches * This could possibly fix the CI for this? * It doesn't look like it did fix it * This will make it pass, even if it's ugly as sin. * Fixed Felinids having a weird ghost tail * Fixes instances of snouts and tails not being properly colored Co-authored-by: Kapu1178 <75460809+Kapu1178@users.noreply.github.com> Co-authored-by: GoldenAlpharex <jerego1234@hotmail.com>
62 lines
2.7 KiB
Plaintext
62 lines
2.7 KiB
Plaintext
/datum/surgery/lobectomy
|
|
name = "Lobectomy" //not to be confused with lobotomy
|
|
steps = list(
|
|
/datum/surgery_step/incise,
|
|
/datum/surgery_step/retract_skin,
|
|
/datum/surgery_step/saw,
|
|
/datum/surgery_step/clamp_bleeders,
|
|
/datum/surgery_step/lobectomy,
|
|
/datum/surgery_step/close)
|
|
possible_locs = list(BODY_ZONE_CHEST)
|
|
organ_to_manipulate = ORGAN_SLOT_LUNGS
|
|
|
|
/datum/surgery/lobectomy/can_start(mob/user, mob/living/carbon/target)
|
|
var/obj/item/organ/internal/lungs/target_lungs = target.getorganslot(ORGAN_SLOT_LUNGS)
|
|
if(target_lungs)
|
|
if(target_lungs.damage > 60 && !target_lungs.operated)
|
|
return TRUE
|
|
return FALSE
|
|
|
|
|
|
//lobectomy, removes the most damaged lung lobe with a 95% base success chance
|
|
/datum/surgery_step/lobectomy
|
|
name = "excise damaged lung node"
|
|
implements = list(
|
|
TOOL_SCALPEL = 95,
|
|
/obj/item/melee/energy/sword = 65,
|
|
/obj/item/knife = 45,
|
|
/obj/item/shard = 35)
|
|
time = 42
|
|
preop_sound = 'sound/surgery/scalpel1.ogg'
|
|
success_sound = 'sound/surgery/organ1.ogg'
|
|
failure_sound = 'sound/surgery/organ2.ogg'
|
|
|
|
/datum/surgery_step/lobectomy/preop(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
display_results(user, target, span_notice("You begin to make an incision in [target]'s lungs..."),
|
|
span_notice("[user] begins to make an incision in [target]."),
|
|
span_notice("[user] begins to make an incision in [target]."))
|
|
display_pain(target, "You feel a stabbing pain in your chest!")
|
|
|
|
/datum/surgery_step/lobectomy/success(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery/surgery, default_display_results = FALSE)
|
|
if(ishuman(target))
|
|
var/mob/living/carbon/human/human_target = target
|
|
var/obj/item/organ/internal/lungs/target_lungs = human_target.getorganslot(ORGAN_SLOT_LUNGS)
|
|
target_lungs.operated = TRUE
|
|
human_target.setOrganLoss(ORGAN_SLOT_LUNGS, 60)
|
|
display_results(user, target, span_notice("You successfully excise [human_target]'s most damaged lobe."),
|
|
span_notice("Successfully removes a piece of [human_target]'s lungs."),
|
|
"")
|
|
display_pain(target, "Your chest hurts like hell, but breathng becomes slightly easier.")
|
|
return ..()
|
|
|
|
/datum/surgery_step/lobectomy/failure(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
if(ishuman(target))
|
|
var/mob/living/carbon/human/human_target = target
|
|
display_results(user, target, span_warning("You screw up, failing to excise [human_target]'s damaged lobe!"),
|
|
span_warning("[user] screws up!"),
|
|
span_warning("[user] screws up!"))
|
|
display_pain(target, "You feel a sharp stab in your chest; the wind is knocked out of you and it hurts to catch your breath!")
|
|
human_target.losebreath += 4
|
|
human_target.adjustOrganLoss(ORGAN_SLOT_LUNGS, 10)
|
|
return FALSE
|