mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-26 17:41:05 +00:00
c06a1324b3
* Pipe init runtime * Modular computer explosion runtime. * Waterbottle thrown by explosion runtime. * Spark runtime. Should systems continue after deletion ? * restore ghost appearance runtime * parallax update timer runtime. * borg unbuckling runtime * surgery cancel runtime. FALSE is not a null. * relic self deletion runtime. * dog collar runtime * Another part of that buckled_mobs robot runtime. * Let's go over all of these * free () Co-Authored-By: MrPerson <spamtaffic@gmail.com> Co-authored-by: MrPerson <spamtaffic@gmail.com>
82 lines
2.1 KiB
Plaintext
82 lines
2.1 KiB
Plaintext
/* This is an attempt to make some easily reusable "particle" type effect, to stop the code
|
|
constantly having to be rewritten. An item like the jetpack that uses the ion_trail_follow system, just has one
|
|
defined, then set up when it is created with New(). Then this same system can just be reused each time
|
|
it needs to create more trails.A beaker could have a steam_trail_follow system set up, then the steam
|
|
would spawn and follow the beaker, even if it is carried or thrown.
|
|
*/
|
|
|
|
|
|
/obj/effect/particle_effect
|
|
name = "particle effect"
|
|
mouse_opacity = MOUSE_OPACITY_TRANSPARENT
|
|
pass_flags = PASSTABLE | PASSGRILLE
|
|
anchored = TRUE
|
|
|
|
/obj/effect/particle_effect/Initialize()
|
|
. = ..()
|
|
GLOB.cameranet.updateVisibility(src)
|
|
|
|
/obj/effect/particle_effect/Destroy()
|
|
GLOB.cameranet.updateVisibility(src)
|
|
return ..()
|
|
|
|
/obj/effect/particle_effect/newtonian_move() // Prevents effects from getting registered for SSspacedrift
|
|
return TRUE
|
|
|
|
/datum/effect_system
|
|
var/number = 3
|
|
var/cardinals = FALSE
|
|
var/turf/location
|
|
var/atom/holder
|
|
var/effect_type
|
|
var/total_effects = 0
|
|
var/autocleanup = FALSE //will delete itself after use
|
|
|
|
/datum/effect_system/Destroy()
|
|
holder = null
|
|
location = null
|
|
return ..()
|
|
|
|
/datum/effect_system/proc/set_up(n = 3, c = FALSE, loca)
|
|
if(n > 10)
|
|
n = 10
|
|
number = n
|
|
cardinals = c
|
|
if(isturf(loca))
|
|
location = loca
|
|
else
|
|
location = get_turf(loca)
|
|
|
|
/datum/effect_system/proc/attach(atom/atom)
|
|
holder = atom
|
|
|
|
/datum/effect_system/proc/start()
|
|
if(QDELETED(src))
|
|
return
|
|
for(var/i in 1 to number)
|
|
if(total_effects > 20)
|
|
return
|
|
INVOKE_ASYNC(src, .proc/generate_effect)
|
|
|
|
/datum/effect_system/proc/generate_effect()
|
|
if(holder)
|
|
location = get_turf(holder)
|
|
var/obj/effect/E = new effect_type(location)
|
|
total_effects++
|
|
var/direction
|
|
if(cardinals)
|
|
direction = pick(GLOB.cardinals)
|
|
else
|
|
direction = pick(GLOB.alldirs)
|
|
var/steps_amt = pick(1,2,3)
|
|
for(var/j in 1 to steps_amt)
|
|
sleep(5)
|
|
step(E,direction)
|
|
if(!QDELETED(src))
|
|
addtimer(CALLBACK(src, .proc/decrement_total_effect), 20)
|
|
|
|
/datum/effect_system/proc/decrement_total_effect()
|
|
total_effects--
|
|
if(autocleanup && total_effects <= 0)
|
|
qdel(src)
|