mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-16 12:07:48 +00:00
3e7184c975
Aiming to implement the framework oranges has detailed in https://tgstation13.org/phpBB/viewtopic.php?f=10&t=19102 Moves canmove to a bitflag in a new variable called mobility_flags, that will allow finer grain control of what someone can do codewise, for example, letting them move but not stand up, or stand up but not move. Adds Immobilize()d status effect that freezes movement but does not prevent anything else. Adds Paralyze()d which is oldstun "You can't do anything at all and knock down). Stun() will now prevent any item/UI usage and movement (which is similar to before). Knockdown() will now only knockdown without preventing item usage/movement. People knocked down will be able to crawl at softcrit-speeds Refactors some /mob variables and procs to /mob/living. update_canmove() refactored to update_mobility() and will handle mobility_flags instead of the removed canmove cl rscadd: Crawling is now possible if you are down but not stunned. Obviously, you will be slower. /cl Refactors are done. I'd rather get this merged faster than try to fine tune stuff like slips. The most obvious gameplay effect this pr has will be crawling, and I believe I made tiny tweaks but I can't find it Anything I missed or weird behavior should be reported.
142 lines
4.4 KiB
Plaintext
142 lines
4.4 KiB
Plaintext
|
|
|
|
/atom/movable
|
|
var/can_buckle = 0
|
|
var/buckle_lying = -1 //bed-like behaviour, forces mob.lying = buckle_lying if != -1
|
|
var/buckle_requires_restraints = 0 //require people to be handcuffed before being able to buckle. eg: pipes
|
|
var/list/mob/living/buckled_mobs = null //list()
|
|
var/max_buckled_mobs = 1
|
|
var/buckle_prevents_pull = FALSE
|
|
|
|
//Interaction
|
|
/atom/movable/attack_hand(mob/living/user)
|
|
. = ..()
|
|
if(.)
|
|
return
|
|
if(can_buckle && has_buckled_mobs())
|
|
if(buckled_mobs.len > 1)
|
|
var/unbuckled = input(user, "Who do you wish to unbuckle?","Unbuckle Who?") as null|mob in buckled_mobs
|
|
if(user_unbuckle_mob(unbuckled,user))
|
|
return 1
|
|
else
|
|
if(user_unbuckle_mob(buckled_mobs[1],user))
|
|
return 1
|
|
|
|
/atom/movable/MouseDrop_T(mob/living/M, mob/living/user)
|
|
. = ..()
|
|
if(can_buckle && istype(M) && istype(user))
|
|
if(user_buckle_mob(M, user))
|
|
return 1
|
|
|
|
/atom/movable/proc/has_buckled_mobs()
|
|
if(!buckled_mobs)
|
|
return FALSE
|
|
if(buckled_mobs.len)
|
|
return TRUE
|
|
|
|
//procs that handle the actual buckling and unbuckling
|
|
/atom/movable/proc/buckle_mob(mob/living/M, force = FALSE, check_loc = TRUE)
|
|
if(!buckled_mobs)
|
|
buckled_mobs = list()
|
|
|
|
if(!istype(M))
|
|
return FALSE
|
|
|
|
if(check_loc && M.loc != loc)
|
|
return FALSE
|
|
|
|
if((!can_buckle && !force) || M.buckled || (buckled_mobs.len >= max_buckled_mobs) || (buckle_requires_restraints && !M.restrained()) || M == src)
|
|
return FALSE
|
|
M.buckling = src
|
|
if(!M.can_buckle() && !force)
|
|
if(M == usr)
|
|
to_chat(M, "<span class='warning'>You are unable to buckle yourself to [src]!</span>")
|
|
else
|
|
to_chat(usr, "<span class='warning'>You are unable to buckle [M] to [src]!</span>")
|
|
M.buckling = null
|
|
return FALSE
|
|
|
|
if(M.pulledby && buckle_prevents_pull)
|
|
M.pulledby.stop_pulling()
|
|
|
|
if(!check_loc && M.loc != loc)
|
|
M.forceMove(loc)
|
|
|
|
M.buckling = null
|
|
M.buckled = src
|
|
M.setDir(dir)
|
|
buckled_mobs |= M
|
|
M.update_mobility()
|
|
M.throw_alert("buckled", /obj/screen/alert/restrained/buckled)
|
|
post_buckle_mob(M)
|
|
|
|
SEND_SIGNAL(src, COMSIG_MOVABLE_BUCKLE, M, force)
|
|
return TRUE
|
|
|
|
/obj/buckle_mob(mob/living/M, force = FALSE, check_loc = TRUE)
|
|
. = ..()
|
|
if(.)
|
|
if(resistance_flags & ON_FIRE) //Sets the mob on fire if you buckle them to a burning atom/movableect
|
|
M.adjust_fire_stacks(1)
|
|
M.IgniteMob()
|
|
|
|
/atom/movable/proc/unbuckle_mob(mob/living/buckled_mob, force=FALSE)
|
|
if(istype(buckled_mob) && buckled_mob.buckled == src && (buckled_mob.can_unbuckle() || force))
|
|
. = buckled_mob
|
|
buckled_mob.buckled = null
|
|
buckled_mob.anchored = initial(buckled_mob.anchored)
|
|
buckled_mob.update_mobility()
|
|
buckled_mob.clear_alert("buckled")
|
|
buckled_mobs -= buckled_mob
|
|
SEND_SIGNAL(src, COMSIG_MOVABLE_UNBUCKLE, buckled_mob, force)
|
|
|
|
post_unbuckle_mob(.)
|
|
|
|
/atom/movable/proc/unbuckle_all_mobs(force=FALSE)
|
|
if(!has_buckled_mobs())
|
|
return
|
|
for(var/m in buckled_mobs)
|
|
unbuckle_mob(m, force)
|
|
|
|
//Handle any extras after buckling
|
|
//Called on buckle_mob()
|
|
/atom/movable/proc/post_buckle_mob(mob/living/M)
|
|
|
|
//same but for unbuckle
|
|
/atom/movable/proc/post_unbuckle_mob(mob/living/M)
|
|
|
|
//Wrapper procs that handle sanity and user feedback
|
|
/atom/movable/proc/user_buckle_mob(mob/living/M, mob/user, check_loc = TRUE)
|
|
if(!in_range(user, src) || !isturf(user.loc) || user.incapacitated() || M.anchored)
|
|
return FALSE
|
|
|
|
add_fingerprint(user)
|
|
. = buckle_mob(M, check_loc = check_loc)
|
|
if(.)
|
|
if(M == user)
|
|
M.visible_message(\
|
|
"<span class='notice'>[M] buckles [M.p_them()]self to [src].</span>",\
|
|
"<span class='notice'>You buckle yourself to [src].</span>",\
|
|
"<span class='italics'>You hear metal clanking.</span>")
|
|
else
|
|
M.visible_message(\
|
|
"<span class='warning'>[user] buckles [M] to [src]!</span>",\
|
|
"<span class='warning'>[user] buckles you to [src]!</span>",\
|
|
"<span class='italics'>You hear metal clanking.</span>")
|
|
|
|
/atom/movable/proc/user_unbuckle_mob(mob/living/buckled_mob, mob/user)
|
|
var/mob/living/M = unbuckle_mob(buckled_mob)
|
|
if(M)
|
|
if(M != user)
|
|
M.visible_message(\
|
|
"<span class='notice'>[user] unbuckles [M] from [src].</span>",\
|
|
"<span class='notice'>[user] unbuckles you from [src].</span>",\
|
|
"<span class='italics'>You hear metal clanking.</span>")
|
|
else
|
|
M.visible_message(\
|
|
"<span class='notice'>[M] unbuckles [M.p_them()]self from [src].</span>",\
|
|
"<span class='notice'>You unbuckle yourself from [src].</span>",\
|
|
"<span class='italics'>You hear metal clanking.</span>")
|
|
add_fingerprint(user)
|
|
return M
|