mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-06-23 15:14:43 +01:00
Tad Hardesty
4d7b9be4a2
* Fix uncapitalized sentences, lack of "the", and singular/plural mixup when inserting items into lathes * Conform some job descriptions to the pattern used by the majority: bitrunner, chemist, coroner, janitor, RD, shaft miner * Remove extra colon from "Open Special Role Information" action buttons * Uncapitalize "no alerts" / "systems nominal" messages in atmos and station alert consoles * Fix incorrect feedback when wrenching down a freezer/heater with its panel open * Fix "Thank you for restocking the station!" appearing in the wrong place in the cargo export summary * Fix "pizza boxs" on cargo manifests * Fix mid-sentence capital "The" when: * Examining walls with mounted items * Inserting parts into machine frames * Fix "Pete's the udder" * Fix double-"the" and stringified datum typepath when scooping reagents * Fix missing spaces in door remote descriptions * Fix uncapitalized "Nanotrasen" in emergency respone drone ghost role poll * Fix double-space in canister opening admin log * Fix missing "the" when casting bear-form spell * Fix "auxiliry" in NebulaStation airlocks * Add `check_grep.sh` rules against "maintainance", "maintainence", and "maintenence" * Fix "maintainance" in NebulaStation airlocks, TCG cards, and in examines of netpod, byteforge, quantum server * Fix "maintainence" in examines of autolathe, flatpacker, cryo cell, ore silo, floodlight, power storage unit, turbine, chromatography machine, ChemMaster, all-in-one grinder, smoke machine, R&D machines, vending machines * Fix "maintenence" in Sulaco ruin terminal * Add missing periods to: * "That's X." examine block header * steal objective explanation text * atmospheric shield generator examine * autolathe examine * telescreen examine * accidentally stepping on a mousetrap * netpod examine * byteforge examine * hat/mask visor toggling * bizza box stack examine * ChemMaster 3000 examine * floodlight examine * power storage unit examine * ChemMaster interact messages * disposal bin animal eject message * techfab examine * vending machine examine * flatpacker examine * Fix name capitalization/propriety of: * big manipulator * DeForest first aid station * Christmas tree * Thunderdome plaque * commission plaque * chalkboard coffee menu * experimental destructive scanner * scanner array * prison cube * RaptorDex * atmospheric shield generator * high-performance liquid chromatography machine * all-in-one grinder * keycard authentication device * Fix plurality of: * fake stairs * HUDs * restaurant and bar seating * Fix misc grammar/typos in: * recharging station description * worm description * surgery tray description * access failure message of restaurant portal * mysterious pillar description * Pennywise painting description * floodlight examine * power storage unit examine * flatpacker examine * Remove extra newline from "Debug Z-Levels" verb
100 lines
3.0 KiB
Plaintext
100 lines
3.0 KiB
Plaintext
/obj/machinery/byteforge
|
|
name = "byteforge"
|
|
|
|
circuit = /obj/item/circuitboard/machine/byteforge
|
|
desc = "A machine used by the quantum server. Quantum code converges here, materializing decrypted assets from the virtual abyss."
|
|
icon = 'icons/obj/machines/bitrunning.dmi'
|
|
icon_state = "byteforge"
|
|
base_icon_state = "byteforge"
|
|
obj_flags = BLOCKS_CONSTRUCTION | CAN_BE_HIT
|
|
/// Idle particles
|
|
var/mutable_appearance/byteforge_particles
|
|
|
|
/obj/machinery/byteforge/Initialize(mapload)
|
|
. = ..()
|
|
|
|
register_context()
|
|
|
|
/obj/machinery/byteforge/post_machine_initialize()
|
|
. = ..()
|
|
|
|
setup_particles()
|
|
|
|
/obj/machinery/byteforge/add_context(atom/source, list/context, obj/item/held_item, mob/user)
|
|
. = NONE
|
|
if(isnull(held_item))
|
|
return
|
|
|
|
if(held_item.tool_behaviour == TOOL_SCREWDRIVER)
|
|
context[SCREENTIP_CONTEXT_LMB] = "[panel_open ? "Close" : "Open"] Panel"
|
|
return CONTEXTUAL_SCREENTIP_SET
|
|
else if(held_item.tool_behaviour == TOOL_CROWBAR && panel_open)
|
|
context[SCREENTIP_CONTEXT_LMB] = "Deconstruct"
|
|
return CONTEXTUAL_SCREENTIP_SET
|
|
|
|
/obj/machinery/byteforge/examine(mob/user)
|
|
. = ..()
|
|
|
|
. += span_notice("Must be within 4 tiles of the quantum server.")
|
|
|
|
. += span_notice("Its maintenance panel can be [EXAMINE_HINT("screwed")] [panel_open ? "close" : "open"].")
|
|
if(panel_open)
|
|
. += span_notice("It can be [EXAMINE_HINT("pried")] apart.")
|
|
|
|
/obj/machinery/byteforge/update_appearance(updates)
|
|
. = ..()
|
|
|
|
setup_particles()
|
|
|
|
/obj/machinery/byteforge/screwdriver_act(mob/living/user, obj/item/screwdriver)
|
|
. = ITEM_INTERACT_FAILURE
|
|
if(default_deconstruction_screwdriver(user, "[base_icon_state]_panel", base_icon_state, screwdriver))
|
|
return ITEM_INTERACT_SUCCESS
|
|
|
|
/obj/machinery/byteforge/crowbar_act(mob/living/user, obj/item/crowbar)
|
|
. = ITEM_INTERACT_FAILURE
|
|
if(default_deconstruction_crowbar(crowbar))
|
|
return ITEM_INTERACT_SUCCESS
|
|
|
|
/// Does some sparks after it's done
|
|
/obj/machinery/byteforge/proc/flash(atom/movable/thing)
|
|
playsound(src, 'sound/effects/magic/blink.ogg', 50, TRUE)
|
|
|
|
var/datum/effect_system/spark_spread/quantum/sparks = new()
|
|
sparks.set_up(5, 1, loc)
|
|
sparks.start()
|
|
|
|
set_light(l_on = FALSE)
|
|
|
|
/// Forge begins to process
|
|
/obj/machinery/byteforge/proc/flicker(angry = FALSE)
|
|
var/mutable_appearance/lighting = mutable_appearance(initial(icon), "on_overlay[angry ? "_angry" : ""]")
|
|
flick_overlay_view(lighting, 1 SECONDS)
|
|
|
|
set_light(l_range = 2, l_power = 1.5, l_color = angry ? LIGHT_COLOR_BUBBLEGUM : LIGHT_COLOR_BABY_BLUE, l_on = TRUE)
|
|
|
|
/// Adds the particle overlays to the byteforge
|
|
/obj/machinery/byteforge/proc/setup_particles(angry = FALSE)
|
|
cut_overlay(byteforge_particles)
|
|
|
|
byteforge_particles = mutable_appearance(initial(icon), "on_particles[angry ? "_angry" : ""]", ABOVE_MOB_LAYER)
|
|
|
|
if(is_operational)
|
|
add_overlay(byteforge_particles)
|
|
|
|
/// Forge is done processing
|
|
/obj/machinery/byteforge/proc/spawn_cache(obj/cache)
|
|
if(QDELETED(cache))
|
|
return
|
|
|
|
flash()
|
|
|
|
cache.forceMove(loc)
|
|
|
|
/// Timed flash
|
|
/obj/machinery/byteforge/proc/start_to_spawn(obj/cache)
|
|
flicker()
|
|
|
|
addtimer(CALLBACK(src, PROC_REF(spawn_cache), cache), 1 SECONDS)
|
|
|