mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-08-20 19:49:39 +01:00
MrMelbertandGitHub
ff6b41aa07
## About The Pull Request - Afterattack is a very simple proc now: All it does is this, and all it's used for is for having a convenient place to put effects an item does after a successful attack (IE, the attack was not blocked)  - An overwhelming majority of afterattack implementations have been moved to `interact_with_atom` or the new `ranged_interact_with_atom` I have manually tested many of the refactored procs but there was 200+ so it's kinda hard ## Why It's Good For The Game Afterattack is one of the worst parts of the attack chain, as it simultaneously serves as a way of doing random interactions NOT AT ALL related to attacks (despite the name) while ALSO serving as the defacto way to do a ranged interaction with an item This means careless coders (most of them) may throw stuff in afterattack without realizing how wide reaching it is, which causes bugs. By making two well defined, separate procs for handing adjacent vs ranged interactions, it becomes WAY WAY WAY more easy to develop for. If you want to do something when you click on something else and you're adjacent, use `interact_with_atom` If you want to do something when you click on something else and you're not adjacent, use 'ranged_interact_with_atom` This does result in some instances of boilerplate as shown here:  But I think it's acceptable, feel free to oppose if you don't I'm sure we can think of another solution ~~Additionally it makes it easier to implement swing combat. That's a bonus I guess~~ ## Changelog 🆑 Melbert refactor: Over 200 item interactions have been refactored to use a newer, easier-to-use system. Report any oddities with using items on other objects you may see (such as surgery, reagent containers like cups and spray bottles, or construction devices), especially using something at range (such as guns or chisels) refactor: Item-On-Modsuit interactions have changed slightly. While on combat mode, you will attempt to "use" the item on the suit instead of inserting it into the suit's storage. This means being on combat mode while the suit's panel is open will block you from inserting items entirely via click (but other methods such as hotkey, clicking on the storage boxes, and mousedrop will still work). refactor: The detective's scanner will now be inserted into storage items if clicked normally, and will scan the storage item if on combat mode /🆑
121 lines
4.5 KiB
Plaintext
121 lines
4.5 KiB
Plaintext
/obj/item/geiger_counter //DISCLAIMER: I know nothing about how real-life Geiger counters work. This will not be realistic. ~Xhuis
|
|
name = "\improper Geiger counter"
|
|
desc = "A handheld device used for detecting and measuring radiation pulses."
|
|
icon = 'icons/obj/devices/scanner.dmi'
|
|
icon_state = "geiger_off"
|
|
inhand_icon_state = "multitool"
|
|
worn_icon_state = "geiger_counter"
|
|
lefthand_file = 'icons/mob/inhands/equipment/tools_lefthand.dmi'
|
|
righthand_file = 'icons/mob/inhands/equipment/tools_righthand.dmi'
|
|
w_class = WEIGHT_CLASS_SMALL
|
|
slot_flags = ITEM_SLOT_BELT
|
|
item_flags = NOBLUDGEON
|
|
custom_materials = list(/datum/material/iron = SMALL_MATERIAL_AMOUNT * 1.5, /datum/material/glass = SMALL_MATERIAL_AMOUNT * 1.5)
|
|
|
|
var/last_perceived_radiation_danger = null
|
|
|
|
var/scanning = FALSE
|
|
|
|
/obj/item/geiger_counter/Initialize(mapload)
|
|
. = ..()
|
|
|
|
RegisterSignal(src, COMSIG_IN_RANGE_OF_IRRADIATION, PROC_REF(on_pre_potential_irradiation))
|
|
|
|
/obj/item/geiger_counter/examine(mob/user)
|
|
. = ..()
|
|
if(!scanning)
|
|
return
|
|
. += span_info("Alt-click it to clear stored radiation levels.")
|
|
switch(last_perceived_radiation_danger)
|
|
if(null)
|
|
. += span_notice("Ambient radiation level count reports that all is well.")
|
|
if(PERCEIVED_RADIATION_DANGER_LOW)
|
|
. += span_alert("Ambient radiation levels slightly above average.")
|
|
if(PERCEIVED_RADIATION_DANGER_MEDIUM)
|
|
. += span_warning("Ambient radiation levels above average.")
|
|
if(PERCEIVED_RADIATION_DANGER_HIGH)
|
|
. += span_danger("Ambient radiation levels highly above average.")
|
|
if(PERCEIVED_RADIATION_DANGER_EXTREME)
|
|
. += span_suicide("Ambient radiation levels reaching critical level!")
|
|
|
|
/obj/item/geiger_counter/update_icon_state()
|
|
if(!scanning)
|
|
icon_state = "geiger_off"
|
|
return ..()
|
|
|
|
switch(last_perceived_radiation_danger)
|
|
if(null)
|
|
icon_state = "geiger_on_1"
|
|
if(PERCEIVED_RADIATION_DANGER_LOW)
|
|
icon_state = "geiger_on_2"
|
|
if(PERCEIVED_RADIATION_DANGER_MEDIUM)
|
|
icon_state = "geiger_on_3"
|
|
if(PERCEIVED_RADIATION_DANGER_HIGH)
|
|
icon_state = "geiger_on_4"
|
|
if(PERCEIVED_RADIATION_DANGER_EXTREME)
|
|
icon_state = "geiger_on_5"
|
|
return ..()
|
|
|
|
/obj/item/geiger_counter/attack_self(mob/user)
|
|
scanning = !scanning
|
|
|
|
if (scanning)
|
|
AddComponent(/datum/component/geiger_sound)
|
|
else
|
|
qdel(GetComponent(/datum/component/geiger_sound))
|
|
|
|
update_appearance(UPDATE_ICON)
|
|
balloon_alert(user, "switch [scanning ? "on" : "off"]")
|
|
|
|
/obj/item/geiger_counter/ranged_interact_with_atom(atom/interacting_with, mob/living/user, list/modifiers)
|
|
return interact_with_atom(interacting_with, user, modifiers)
|
|
|
|
/obj/item/geiger_counter/interact_with_atom(atom/interacting_with, mob/living/user, list/modifiers)
|
|
if (user.combat_mode)
|
|
return NONE
|
|
if (!CAN_IRRADIATE(interacting_with))
|
|
return NONE
|
|
|
|
user.visible_message(span_notice("[user] scans [interacting_with] with [src]."), span_notice("You scan [interacting_with]'s radiation levels with [src]..."))
|
|
addtimer(CALLBACK(src, PROC_REF(scan), interacting_with, user), 20, TIMER_UNIQUE) // Let's not have spamming GetAllContents
|
|
return ITEM_INTERACT_SUCCESS
|
|
|
|
/obj/item/geiger_counter/equipped(mob/user, slot, initial)
|
|
. = ..()
|
|
|
|
RegisterSignal(user, COMSIG_IN_RANGE_OF_IRRADIATION, PROC_REF(on_pre_potential_irradiation))
|
|
|
|
/obj/item/geiger_counter/dropped(mob/user, silent = FALSE)
|
|
. = ..()
|
|
|
|
UnregisterSignal(user, COMSIG_IN_RANGE_OF_IRRADIATION)
|
|
|
|
/obj/item/geiger_counter/proc/on_pre_potential_irradiation(datum/source, datum/radiation_pulse_information/pulse_information, insulation_to_target)
|
|
SIGNAL_HANDLER
|
|
|
|
last_perceived_radiation_danger = get_perceived_radiation_danger(pulse_information, insulation_to_target)
|
|
addtimer(CALLBACK(src, PROC_REF(reset_perceived_danger)), TIME_WITHOUT_RADIATION_BEFORE_RESET, TIMER_UNIQUE | TIMER_OVERRIDE)
|
|
|
|
if (scanning)
|
|
update_appearance(UPDATE_ICON)
|
|
|
|
/obj/item/geiger_counter/proc/reset_perceived_danger()
|
|
last_perceived_radiation_danger = null
|
|
if (scanning)
|
|
update_appearance(UPDATE_ICON)
|
|
|
|
/obj/item/geiger_counter/proc/scan(atom/target, mob/user)
|
|
if (SEND_SIGNAL(target, COMSIG_GEIGER_COUNTER_SCAN, user, src) & COMSIG_GEIGER_COUNTER_SCAN_SUCCESSFUL)
|
|
return
|
|
|
|
to_chat(user, span_notice("[icon2html(src, user)] [isliving(target) ? "Subject" : "Target"] is free of radioactive contamination."))
|
|
|
|
/obj/item/geiger_counter/click_alt(mob/living/user)
|
|
if(!scanning)
|
|
to_chat(usr, span_warning("[src] must be on to reset its radiation level!"))
|
|
return CLICK_ACTION_BLOCKING
|
|
to_chat(usr, span_notice("You flush [src]'s radiation counts, resetting it to normal."))
|
|
last_perceived_radiation_danger = null
|
|
update_appearance(UPDATE_ICON)
|
|
return CLICK_ACTION_SUCCESS
|