mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-19 13:35:10 +00:00
3f28227f6c
About The Pull Request Part of #44440 Surgery now gives detailed description to the surgeon and anyone within one tile of distance, and more vague or ambiguous descriptions to the patient and anyone further away. This can lead to a surgeon being able to perform a brainwashing in place of a brain surgery with nobody being the wiser, or implanting a different organ than the one agreed on, and so on. Changelog cl add: Surgery steps are now shown in detail only to the surgeon and anyone standing adjacent to them; the patient and people watching from further away get a more vague/ambiguous description. /cl
51 lines
2.5 KiB
Plaintext
51 lines
2.5 KiB
Plaintext
/datum/surgery/brain_surgery
|
|
name = "Brain surgery"
|
|
steps = list(
|
|
/datum/surgery_step/incise,
|
|
/datum/surgery_step/retract_skin,
|
|
/datum/surgery_step/saw,
|
|
/datum/surgery_step/clamp_bleeders,
|
|
/datum/surgery_step/fix_brain,
|
|
/datum/surgery_step/close)
|
|
|
|
target_mobtypes = list(/mob/living/carbon/human, /mob/living/carbon/monkey)
|
|
possible_locs = list(BODY_ZONE_HEAD)
|
|
requires_bodypart_type = 0
|
|
|
|
/datum/surgery_step/fix_brain
|
|
name = "fix brain"
|
|
implements = list(/obj/item/hemostat = 85, TOOL_SCREWDRIVER = 35, /obj/item/pen = 15) //don't worry, pouring some alcohol on their open brain will get that chance to 100
|
|
time = 120 //long and complicated
|
|
|
|
/datum/surgery/brain_surgery/can_start(mob/user, mob/living/carbon/target)
|
|
var/obj/item/organ/brain/B = target.getorganslot(ORGAN_SLOT_BRAIN)
|
|
if(!B)
|
|
return FALSE
|
|
return TRUE
|
|
|
|
/datum/surgery_step/fix_brain/preop(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
display_results(user, target, "<span class='notice'>You begin to fix [target]'s brain...</span>",
|
|
"[user] begins to fix [target]'s brain.",
|
|
"[user] begins to perform surgery on [target]'s brain.")
|
|
|
|
/datum/surgery_step/fix_brain/success(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
display_results(user, target, "<span class='notice'>You succeed in fixing [target]'s brain.</span>",
|
|
"[user] successfully fixes [target]'s brain!",
|
|
"[user] completes the surgery on [target]'s brain.")
|
|
if(target.mind && target.mind.has_antag_datum(/datum/antagonist/brainwashed))
|
|
target.mind.remove_antag_datum(/datum/antagonist/brainwashed)
|
|
target.adjustBrainLoss(-60)
|
|
target.cure_all_traumas(TRAUMA_RESILIENCE_SURGERY)
|
|
return TRUE
|
|
|
|
/datum/surgery_step/fix_brain/failure(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
if(target.getorganslot(ORGAN_SLOT_BRAIN))
|
|
display_results(user, target, "<span class='warning'>You screw up, causing more damage!</span>",
|
|
"<span class='warning'>[user] screws up, causing brain damage!</span>",
|
|
"[user] completes the surgery on [target]'s brain.")
|
|
target.adjustBrainLoss(60)
|
|
target.gain_trauma_type(BRAIN_TRAUMA_SEVERE, TRAUMA_RESILIENCE_LOBOTOMY)
|
|
else
|
|
user.visible_message("<span class='warning'>[user] suddenly notices that the brain [user.p_they()] [user.p_were()] working on is not there anymore.", "<span class='warning'>You suddenly notice that the brain you were working on is not there anymore.</span>")
|
|
return FALSE
|