mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-10 01:34:01 +00:00
ab5a4d0f99
* split area.contained_turfs up by zlevel, make init 10 seconds faster (#80941) ## About The Pull Request Situation: areas have a list of all turfs in their area. Problem: `/area/space` is an area and has a 6 to 7 digit count of turfs that has to be traversed for every turf we need to remove from it. This can take multiple byond ticks just to preform this action for a single space rune Solution: split the list by zlevel, and only search the right zlevel list when removing turfs from areas. replaces `area.get_contained_turfs()` with a few new procs: * `get_highest_zlevel()` - returns the highest zlevel the area contains turfs in. useful for use with `get_turfs_by_zlevel` * `get_turfs_by_zlevel(zlevel)` - returns a list of turfs in the area in a given zlevel. Useful for code that only cares about a specific zlevel or changes behavior based on zlevel like lighting init. * `get_turfs_from_all_zlevels()` - the replacement for `get_contained_turfs()`, renamed as such so anybody copying/cargo culting code gets a hint that a zlevel specific version might exist. Still used in for loops that type checked so byond would do that all at once * `get_zlevel_turf_lists()` - returns the area's zlevel lists of lists but only for non-empty zlevels. very useful for for loops. The area contents unit test has been rewritten to ensure any improper data triggers failures or runtimes by not having it use the helpers above (some of which ensure a list is always returned) and access the lists directly. * split area.contained_turfs up by zlevel, make init 10 seconds faster * eeyes * Update area_spawn_subsystem.dm * Unshits turf contain code slightly (#81023) Literally just implements my reviews from #80941 I am frankly a smidge pissed that the pr was merged without them being handled. No code is worth merging past known issues, and if the author is just gonna dip then that's life. I don't like privileging mso on stuff like this, especially because frankly I'm kinda mad at him rn but also because when a pr is made the onus on finishing it falls to the person who made it. Should not need to clean up after someone as a maintainer, and shouldn't normalize doing it. I'm not like mad at zypher directly mind he offered to do this too, just the idea he was espousing here. --------- Co-authored-by: Kyle Spier-Swenson <kyleshome@gmail.com> Co-authored-by: Gandalf <9026500+Gandalf2k15@users.noreply.github.com> Co-authored-by: LemonInTheDark <58055496+LemonInTheDark@users.noreply.github.com>
71 lines
3.1 KiB
Plaintext
71 lines
3.1 KiB
Plaintext
#define ALLOWED_LOOSE_TURFS 100
|
|
/**
|
|
* Responsible for managing the sizes of area.contained_turfs and area.turfs_to_uncontain
|
|
* These lists do not check for duplicates, which is fine, but it also means they can balloon in size over time
|
|
* as a consequence of repeated changes in area in a space
|
|
* They additionally may not always resolve often enough to avoid memory leaks
|
|
* This is annoying, so lets keep an eye on them and cut them down to size if needed
|
|
*/
|
|
SUBSYSTEM_DEF(area_contents)
|
|
name = "Area Contents"
|
|
flags = SS_NO_INIT
|
|
runlevels = RUNLEVEL_LOBBY|RUNLEVELS_DEFAULT
|
|
var/list/currentrun
|
|
var/list/area/marked_for_clearing = list()
|
|
|
|
/datum/controller/subsystem/area_contents/stat_entry(msg)
|
|
var/total_clearing_from = 0
|
|
var/total_to_clear = 0
|
|
for(var/area/to_clear as anything in marked_for_clearing)
|
|
for (var/area_zlevel in 1 to length(to_clear.turfs_to_uncontain_by_zlevel))
|
|
if (length(to_clear.turfs_to_uncontain_by_zlevel[area_zlevel]))
|
|
total_to_clear += length(to_clear.turfs_to_uncontain_by_zlevel[area_zlevel])
|
|
if (length(to_clear.turfs_by_zlevel) >= area_zlevel) //this should always be true, but stat_entry is no place for runtimes. fire() can handle that
|
|
total_clearing_from += length(to_clear.turfs_by_zlevel[area_zlevel])
|
|
msg = "A:[length(currentrun)] MR:[length(marked_for_clearing)] TC:[total_to_clear] CF:[total_clearing_from]"
|
|
return ..()
|
|
|
|
|
|
/datum/controller/subsystem/area_contents/fire(resumed)
|
|
if(!resumed)
|
|
currentrun = GLOB.areas.Copy()
|
|
|
|
while(length(currentrun))
|
|
var/area/test = currentrun[length(currentrun)]
|
|
for (var/area_zlevel in 1 to length(test.turfs_to_uncontain_by_zlevel))
|
|
if(length(test.turfs_to_uncontain_by_zlevel[area_zlevel]) > ALLOWED_LOOSE_TURFS)
|
|
marked_for_clearing |= test
|
|
break
|
|
currentrun.len--
|
|
if(MC_TICK_CHECK)
|
|
return
|
|
|
|
// Alright, if we've done a scan on all our areas, it's time to knock the existing ones down to size
|
|
while(length(marked_for_clearing))
|
|
var/area/clear = marked_for_clearing[length(marked_for_clearing)]
|
|
|
|
for (var/area_zlevel in 1 to length(clear.turfs_to_uncontain_by_zlevel))
|
|
if (!length(clear.turfs_to_uncontain_by_zlevel[area_zlevel]))
|
|
continue
|
|
if (length(clear.turfs_by_zlevel) < area_zlevel)
|
|
stack_trace("[clear]([clear.type])'s turfs_by_zlevel is length [length(clear.turfs_by_zlevel)] but we are being asked to remove turfs from zlevel [area_zlevel] from it.")
|
|
clear.turfs_to_uncontain_by_zlevel[area_zlevel] = list()
|
|
continue
|
|
|
|
// The operation of cutting large lists can be expensive
|
|
// It scales almost directly with the size of the list we're cutting with
|
|
// Because of this, we're gonna stick to cutting 1 entry at a time
|
|
// There's no reason to batch it I promise, this is faster. No overtime too
|
|
var/amount_cut = 0
|
|
var/list/cut_from = clear.turfs_to_uncontain_by_zlevel[area_zlevel]
|
|
for(amount_cut in 1 to length(cut_from))
|
|
clear.turfs_by_zlevel[area_zlevel] -= cut_from[amount_cut]
|
|
if(MC_TICK_CHECK)
|
|
cut_from.Cut(1, amount_cut + 1)
|
|
return
|
|
|
|
clear.turfs_to_uncontain_by_zlevel = list()
|
|
marked_for_clearing.len--
|
|
|
|
#undef ALLOWED_LOOSE_TURFS
|