mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-10 09:42:29 +00:00
7663b39cc8
## About The Pull Request I've been meaning to do this for some time. I need this for portable/handheld aquariums/fishtanks to be possible. I'll sprite and code them before I call this PR ready, however suggestions and code reviews are welcome in the meantime. Being a pretty heavy refactor, some things might break (we have more than a few unit tests so perhaps not) while others, coincidentally, might be fixed without me knowing. Anyway I'm sure this PR fixes aquarium beauty, which wasn't really working to begin with because the code was so fucking bad. Nothing really worth of a CL entry tho. TODO: - [x] handheld aquariums, craftable with a kit and little plastic or buyable from the fun vendor ig. - [x] an aquarium upgrade for handheld aquariums to bypass possible restrictions. - [x] update the beauty element to consider items, which shouldn't contribute to the area beauty when held or otherwise not on a turf. ## Why It's Good For The Game This should make handheld aquariums possible. ## Changelog 🆑 refactor: refactored aquariums heavily. Please report any fishy bug. add: Added portable/handheld fish tanks to the game. They can be crafted with an aquarium kit and 5 sheets of plastic. While portable, they cannot store fish that are too big or if there're too many already. This restriction can be removed by using the new "bluespace fish tank kit" techweb item. map: Replaced the lawyer's stationary pet aquarium with a fish tank, so you can carry McGill around. balance: Reduced the iron cost of stationary aquariums a little. /🆑
47 lines
1.7 KiB
Plaintext
47 lines
1.7 KiB
Plaintext
/// You can't use machines unless they are in a whitelist
|
|
/datum/component/technointrovert
|
|
can_transfer = TRUE
|
|
/// Typecache of allowed machinery
|
|
var/list/whitelist
|
|
/// Message presented when
|
|
var/message = "That %TARGET is strange! Let's avoid it."
|
|
|
|
/datum/component/technointrovert/Initialize(whitelist, message)
|
|
if(!ismob(parent))
|
|
return COMPONENT_INCOMPATIBLE
|
|
src.whitelist = whitelist
|
|
if(message)
|
|
src.message = message
|
|
|
|
/datum/component/technointrovert/RegisterWithParent()
|
|
RegisterSignal(parent, COMSIG_TRY_USE_MACHINE, PROC_REF(on_try_use_machine))
|
|
RegisterSignal(parent, COMSIG_TRY_WIRES_INTERACT, PROC_REF(on_try_wires_interact))
|
|
|
|
/datum/component/technointrovert/UnregisterFromParent()
|
|
UnregisterSignal(parent, list(COMSIG_TRY_USE_MACHINE, COMSIG_TRY_WIRES_INTERACT))
|
|
|
|
/datum/component/technointrovert/PostTransfer(datum/new_parent)
|
|
if(!ismob(parent))
|
|
return COMPONENT_INCOMPATIBLE
|
|
|
|
/datum/component/technointrovert/InheritComponent(datum/component/technointrovert/friend, i_am_original, list/arguments)
|
|
if(i_am_original)
|
|
whitelist = friend.whitelist
|
|
message = friend.message
|
|
|
|
/datum/component/technointrovert/proc/is_in_whitelist(datum/source, obj/machinery/machine)
|
|
if(!is_type_in_typecache(machine, whitelist))
|
|
to_chat(source, span_warning("[replacetext(message, "%TARGET", machine)]"))
|
|
return FALSE
|
|
return TRUE
|
|
|
|
/datum/component/technointrovert/proc/on_try_use_machine(datum/source, obj/machinery/machine)
|
|
SIGNAL_HANDLER
|
|
if(!is_in_whitelist(source, machine))
|
|
return COMPONENT_CANT_USE_MACHINE_INTERACT | COMPONENT_CANT_USE_MACHINE_TOOLS
|
|
|
|
/datum/component/technointrovert/proc/on_try_wires_interact(datum/source, atom/machine)
|
|
SIGNAL_HANDLER
|
|
if(ismachinery(machine) && !is_in_whitelist(source, machine))
|
|
return COMPONENT_CANT_INTERACT_WIRES
|