mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-27 10:02:12 +00:00
7a817300fd
## About The Pull Request Maked `fieldset_block` and `examine_block` more stylish and neat, also `fieldset_block` no longer has a centred title. Renamed `examine_block` to `boxed_message` and adds `custom_boxed_message` which can be colored. - AdminPMs, admin tickets and vote results has been wrapped into `fieldset_block` for comfort and visibility - Health Analyzer results painted to blue - Vote notice and tips of the round wrapped to purple `custom_boxed_message` - Tooltip text border color, now uses text color, not just white ## Why It's Good For The Game Demonstration in both themes <details><summary>Dark</summary>    </details> <details><summary>Light</summary>    </details> ## Changelog 🆑 qol: AdminPMs, admin tickets, vote results and started vote notification are now much more visible in the chat. qol: Boxed messages in chat (like examine), has been restyled. /🆑
49 lines
1.7 KiB
Plaintext
49 lines
1.7 KiB
Plaintext
/datum/buildmode_mode/mapgen
|
|
key = "mapgen"
|
|
|
|
use_corner_selection = TRUE
|
|
var/generator_path
|
|
|
|
/datum/buildmode_mode/mapgen/show_help(client/builder)
|
|
to_chat(builder, span_purple(boxed_message(
|
|
"[span_bold("Select corner")] -> Left Mouse Button on turf/obj/mob\n\
|
|
[span_bold("Select generator")] -> Right Mouse Button on buildmode button"))
|
|
)
|
|
|
|
/datum/buildmode_mode/mapgen/change_settings(client/c)
|
|
var/list/gen_paths = subtypesof(/datum/map_generator)
|
|
var/list/options = list()
|
|
for(var/path in gen_paths)
|
|
var/datum/map_generator/MP = path
|
|
options[initial(MP.buildmode_name)] = path
|
|
var/type = input(c,"Select Generator Type","Type") as null|anything in options
|
|
if(!type)
|
|
return
|
|
|
|
generator_path = options[type]
|
|
deselect_region()
|
|
|
|
/datum/buildmode_mode/mapgen/handle_click(client/c, params, obj/object)
|
|
if(isnull(generator_path))
|
|
to_chat(c, span_warning("Select generator type first."))
|
|
deselect_region()
|
|
return
|
|
..()
|
|
|
|
/datum/buildmode_mode/mapgen/handle_selected_area(client/c, params)
|
|
var/list/modifiers = params2list(params)
|
|
|
|
if(LAZYACCESS(modifiers, LEFT_CLICK))
|
|
var/datum/map_generator/G = new generator_path
|
|
if(istype(G, /datum/map_generator/repair/reload_station_map))
|
|
if(GLOB.reloading_map)
|
|
to_chat(c, span_boldwarning("You are already reloading an area! Please wait for it to fully finish loading before trying to load another!"))
|
|
deselect_region()
|
|
return
|
|
G.defineRegion(cornerA, cornerB, 1)
|
|
highlight_region(G.map)
|
|
var/confirm = tgui_alert(usr,"Are you sure you want to run the map generator?", "Run generator", list("Yes", "No"))
|
|
if(confirm == "Yes")
|
|
G.generate()
|
|
log_admin("Build Mode: [key_name(c)] ran the map generator '[G.buildmode_name]' in the region from [AREACOORD(cornerA)] to [AREACOORD(cornerB)]")
|