mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-19 22:23:11 +00:00
e65a48e91f
* Adds SIGNAL_HANDLER and SIGNAL_HANDLER_DOES_SLEEP to prevent signal callbacks from blocking (#52761) Adds SIGNAL_HANDLER, a macro that sets SHOULD_NOT_SLEEP(TRUE). This should ideally be required on all new signal callbacks. Adds BLOCKING_SIGNAL_HANDLER, a macro that does nothing except symbolize "this is an older signal that didn't necessitate a code rewrite". It should not be allowed for new work. This comes from discussion around #52735, which yields by calling input, and (though it sets the return type beforehand) will not properly return the flag to prevent attack from slapping. To fix 60% of the yielding cases, WrapAdminProcCall no longer waits for another admin's proc call to finish. I'm not an admin, so I don't know how many behinds this has saved, but if this is problematic for admins I can just make it so that it lets you do it anyway. I'm not sure what the point of this babysitting was anyway. Requested by @optimumtact. Changelog cl admin: Calling a proc while another admin is calling one will no longer wait for the first to finish. You will simply just have to call it again. /cl * Adds SIGNAL_HANDLER and SIGNAL_HANDLER_DOES_SLEEP to prevent signal callbacks from blocking Co-authored-by: Jared-Fogle <35135081+Jared-Fogle@users.noreply.github.com>
68 lines
2.6 KiB
Plaintext
68 lines
2.6 KiB
Plaintext
/datum/component/knockback
|
|
/// distance the atom will be thrown
|
|
var/throw_distance
|
|
/// whether this can throw anchored targets (tables, etc)
|
|
var/throw_anchored
|
|
/// whether this is a gentle throw (default false means people thrown into walls are stunned / take damage)
|
|
var/throw_gentle
|
|
|
|
/datum/component/knockback/Initialize(throw_distance=1, throw_anchored=FALSE, throw_gentle=FALSE)
|
|
if(!isitem(parent) && !ishostile(parent) && !isgun(parent) && !ismachinery(parent) && !isstructure(parent))
|
|
return COMPONENT_INCOMPATIBLE
|
|
|
|
src.throw_distance = throw_distance
|
|
src.throw_anchored = throw_anchored
|
|
src.throw_gentle = throw_gentle
|
|
|
|
/datum/component/knockback/RegisterWithParent()
|
|
if(ismachinery(parent) || isstructure(parent) || isgun(parent)) // turrets, etc
|
|
RegisterSignal(parent, COMSIG_PROJECTILE_ON_HIT, .proc/projectile_hit)
|
|
else if(isitem(parent))
|
|
RegisterSignal(parent, COMSIG_ITEM_AFTERATTACK, .proc/item_afterattack)
|
|
else if(ishostile(parent))
|
|
RegisterSignal(parent, COMSIG_HOSTILE_ATTACKINGTARGET, .proc/hostile_attackingtarget)
|
|
|
|
/datum/component/knockback/UnregisterFromParent()
|
|
UnregisterSignal(parent, list(COMSIG_ITEM_AFTERATTACK, COMSIG_HOSTILE_ATTACKINGTARGET, COMSIG_PROJECTILE_ON_HIT))
|
|
|
|
/// triggered after an item attacks something
|
|
/datum/component/knockback/proc/item_afterattack(obj/item/source, atom/target, mob/user, proximity_flag, click_parameters)
|
|
SIGNAL_HANDLER
|
|
|
|
if(!proximity_flag)
|
|
return
|
|
do_knockback(target, user, get_dir(source, target))
|
|
|
|
/// triggered after a hostile simplemob attacks something
|
|
/datum/component/knockback/proc/hostile_attackingtarget(mob/living/simple_animal/hostile/attacker, atom/target)
|
|
SIGNAL_HANDLER
|
|
|
|
do_knockback(target, attacker, get_dir(attacker, target))
|
|
|
|
/// triggered after a projectile hits something
|
|
/datum/component/knockback/proc/projectile_hit(atom/fired_from, atom/movable/firer, atom/target, Angle)
|
|
SIGNAL_HANDLER
|
|
|
|
do_knockback(target, null, angle2dir(Angle))
|
|
|
|
|
|
/**
|
|
* Throw a target in a direction
|
|
*
|
|
* Arguments:
|
|
* * target - Target atom to throw
|
|
* * thrower - Thing that caused this atom to be thrown
|
|
* * throw_dir - Direction to throw the atom
|
|
*/
|
|
/datum/component/knockback/proc/do_knockback(atom/target, mob/thrower, throw_dir)
|
|
if(!ismovable(target) || throw_dir == null)
|
|
return
|
|
var/atom/movable/throwee = target
|
|
if(throwee.anchored && !throw_anchored)
|
|
return
|
|
if(throw_distance < 0)
|
|
throw_dir = turn(throw_dir, 180)
|
|
throw_distance *= -1
|
|
var/atom/throw_target = get_edge_target_turf(throwee, throw_dir)
|
|
throwee.safe_throw_at(throw_target, throw_distance, 1, thrower, gentle = throw_gentle)
|