mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-21 07:03:05 +00:00
e65a48e91f
* Adds SIGNAL_HANDLER and SIGNAL_HANDLER_DOES_SLEEP to prevent signal callbacks from blocking (#52761) Adds SIGNAL_HANDLER, a macro that sets SHOULD_NOT_SLEEP(TRUE). This should ideally be required on all new signal callbacks. Adds BLOCKING_SIGNAL_HANDLER, a macro that does nothing except symbolize "this is an older signal that didn't necessitate a code rewrite". It should not be allowed for new work. This comes from discussion around #52735, which yields by calling input, and (though it sets the return type beforehand) will not properly return the flag to prevent attack from slapping. To fix 60% of the yielding cases, WrapAdminProcCall no longer waits for another admin's proc call to finish. I'm not an admin, so I don't know how many behinds this has saved, but if this is problematic for admins I can just make it so that it lets you do it anyway. I'm not sure what the point of this babysitting was anyway. Requested by @optimumtact. Changelog cl admin: Calling a proc while another admin is calling one will no longer wait for the first to finish. You will simply just have to call it again. /cl * Adds SIGNAL_HANDLER and SIGNAL_HANDLER_DOES_SLEEP to prevent signal callbacks from blocking Co-authored-by: Jared-Fogle <35135081+Jared-Fogle@users.noreply.github.com>
104 lines
3.1 KiB
Plaintext
104 lines
3.1 KiB
Plaintext
/datum/component/manual_breathing
|
|
dupe_mode = COMPONENT_DUPE_UNIQUE
|
|
|
|
var/obj/item/organ/lungs/L
|
|
var/warn_grace = FALSE
|
|
var/warn_dying = FALSE
|
|
var/last_breath
|
|
var/check_every = 12 SECONDS
|
|
var/grace_period = 6 SECONDS
|
|
var/damage_rate = 1 // organ damage taken per tick
|
|
var/datum/emote/next_breath_type = /datum/emote/inhale
|
|
|
|
/datum/component/manual_breathing/Initialize()
|
|
if(!iscarbon(parent))
|
|
return COMPONENT_INCOMPATIBLE
|
|
|
|
var/mob/living/carbon/C = parent
|
|
L = C.getorganslot(ORGAN_SLOT_LUNGS)
|
|
|
|
if(L)
|
|
START_PROCESSING(SSdcs, src)
|
|
last_breath = world.time
|
|
to_chat(C, "<span class='notice'>You suddenly realize you're breathing manually.</span>")
|
|
|
|
/datum/component/manual_breathing/Destroy(force, silent)
|
|
L = null
|
|
STOP_PROCESSING(SSdcs, src)
|
|
to_chat(parent, "<span class='notice'>You revert back to automatic breathing.</span>")
|
|
return ..()
|
|
|
|
/datum/component/manual_breathing/RegisterWithParent()
|
|
RegisterSignal(parent, COMSIG_MOB_EMOTE, .proc/check_emote)
|
|
RegisterSignal(parent, COMSIG_CARBON_GAIN_ORGAN, .proc/check_added_organ)
|
|
RegisterSignal(parent, COMSIG_CARBON_LOSE_ORGAN, .proc/check_removed_organ)
|
|
RegisterSignal(parent, COMSIG_LIVING_REVIVE, .proc/restart)
|
|
RegisterSignal(parent, COMSIG_MOB_DEATH, .proc/pause)
|
|
|
|
/datum/component/manual_breathing/UnregisterFromParent()
|
|
UnregisterSignal(parent, COMSIG_MOB_EMOTE)
|
|
UnregisterSignal(parent, COMSIG_CARBON_GAIN_ORGAN)
|
|
UnregisterSignal(parent, COMSIG_CARBON_LOSE_ORGAN)
|
|
UnregisterSignal(parent, COMSIG_LIVING_REVIVE)
|
|
UnregisterSignal(parent, COMSIG_MOB_DEATH)
|
|
|
|
/datum/component/manual_breathing/proc/restart()
|
|
SIGNAL_HANDLER
|
|
|
|
START_PROCESSING(SSdcs, src)
|
|
|
|
/datum/component/manual_breathing/proc/pause()
|
|
SIGNAL_HANDLER
|
|
|
|
STOP_PROCESSING(SSdcs, src)
|
|
|
|
/datum/component/manual_breathing/process()
|
|
var/mob/living/carbon/C = parent
|
|
|
|
var/next_text = initial(next_breath_type.key)
|
|
if(world.time > (last_breath + check_every + grace_period))
|
|
if(!warn_dying)
|
|
to_chat(C, "<span class='userdanger'>You begin to suffocate, you need to [next_text]!</span>")
|
|
warn_dying = TRUE
|
|
|
|
L.applyOrganDamage(damage_rate)
|
|
C.losebreath += 0.8
|
|
else if(world.time > (last_breath + check_every))
|
|
if(!warn_grace)
|
|
to_chat(C, "<span class='danger'>You feel a need to [next_text]!</span>")
|
|
warn_grace = TRUE
|
|
|
|
/datum/component/manual_breathing/proc/check_added_organ(mob/who_cares, obj/item/organ/O)
|
|
SIGNAL_HANDLER
|
|
|
|
var/obj/item/organ/eyes/new_lungs = O
|
|
|
|
if(istype(new_lungs,/obj/item/organ/lungs))
|
|
L = new_lungs
|
|
START_PROCESSING(SSdcs, src)
|
|
|
|
/datum/component/manual_breathing/proc/check_removed_organ(mob/who_cares, obj/item/organ/O)
|
|
SIGNAL_HANDLER
|
|
|
|
var/obj/item/organ/lungs/old_lungs = O
|
|
|
|
if(istype(old_lungs, /obj/item/organ/lungs))
|
|
L = null
|
|
STOP_PROCESSING(SSdcs, src)
|
|
|
|
/datum/component/manual_breathing/proc/check_emote(mob/living/carbon/user, datum/emote/emote)
|
|
SIGNAL_HANDLER
|
|
|
|
if(emote.type == next_breath_type)
|
|
if(next_breath_type == /datum/emote/inhale)
|
|
next_breath_type = /datum/emote/exhale
|
|
else
|
|
next_breath_type = /datum/emote/inhale
|
|
|
|
warn_grace = FALSE
|
|
warn_dying = FALSE
|
|
last_breath = world.time
|
|
|
|
var/mob/living/carbon/C = parent
|
|
C.losebreath = max(0, C.losebreath - 0.4)
|