mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-20 14:45:05 +00:00
e65a48e91f
* Adds SIGNAL_HANDLER and SIGNAL_HANDLER_DOES_SLEEP to prevent signal callbacks from blocking (#52761) Adds SIGNAL_HANDLER, a macro that sets SHOULD_NOT_SLEEP(TRUE). This should ideally be required on all new signal callbacks. Adds BLOCKING_SIGNAL_HANDLER, a macro that does nothing except symbolize "this is an older signal that didn't necessitate a code rewrite". It should not be allowed for new work. This comes from discussion around #52735, which yields by calling input, and (though it sets the return type beforehand) will not properly return the flag to prevent attack from slapping. To fix 60% of the yielding cases, WrapAdminProcCall no longer waits for another admin's proc call to finish. I'm not an admin, so I don't know how many behinds this has saved, but if this is problematic for admins I can just make it so that it lets you do it anyway. I'm not sure what the point of this babysitting was anyway. Requested by @optimumtact. Changelog cl admin: Calling a proc while another admin is calling one will no longer wait for the first to finish. You will simply just have to call it again. /cl * Adds SIGNAL_HANDLER and SIGNAL_HANDLER_DOES_SLEEP to prevent signal callbacks from blocking Co-authored-by: Jared-Fogle <35135081+Jared-Fogle@users.noreply.github.com>
47 lines
1.4 KiB
Plaintext
47 lines
1.4 KiB
Plaintext
/**
|
|
* Can be applied to /atom/movable subtypes to make them apply fire stacks to things they hit
|
|
*/
|
|
/datum/element/firestacker
|
|
element_flags = ELEMENT_BESPOKE
|
|
id_arg_index = 2
|
|
/// How many firestacks to apply per hit
|
|
var/amount
|
|
|
|
/datum/element/firestacker/Attach(datum/target, amount)
|
|
. = ..()
|
|
|
|
if(!ismovable(target))
|
|
return ELEMENT_INCOMPATIBLE
|
|
|
|
src.amount = amount
|
|
|
|
RegisterSignal(target, COMSIG_MOVABLE_IMPACT, .proc/impact, override = TRUE)
|
|
if(isitem(target))
|
|
RegisterSignal(target, COMSIG_ITEM_ATTACK, .proc/item_attack, override = TRUE)
|
|
RegisterSignal(target, COMSIG_ITEM_ATTACK_SELF, .proc/item_attack_self, override = TRUE)
|
|
|
|
/datum/element/firestacker/Detach(datum/source, force)
|
|
. = ..()
|
|
UnregisterSignal(source, list(COMSIG_MOVABLE_IMPACT, COMSIG_ITEM_ATTACK, COMSIG_ITEM_ATTACK_SELF))
|
|
|
|
/datum/element/firestacker/proc/stack_on(datum/owner, mob/living/target)
|
|
target.adjust_fire_stacks(amount)
|
|
|
|
/datum/element/firestacker/proc/impact(datum/source, atom/hit_atom, datum/thrownthing/throwingdatum)
|
|
SIGNAL_HANDLER
|
|
|
|
if(isliving(hit_atom))
|
|
stack_on(source, hit_atom)
|
|
|
|
/datum/element/firestacker/proc/item_attack(datum/source, atom/movable/target, mob/living/user)
|
|
SIGNAL_HANDLER
|
|
|
|
if(isliving(target))
|
|
stack_on(source, target)
|
|
|
|
/datum/element/firestacker/proc/item_attack_self(datum/source, mob/user)
|
|
SIGNAL_HANDLER
|
|
|
|
if(isliving(user))
|
|
stack_on(source, user)
|