mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-06 23:12:36 +00:00
665fe76566
* Modifies right click logic so that it is not the same priority as modifier keys. (#59656) Strips out the existing right click code - Due to the myriad of ways right clicking has been implemented, dedicated signals and procs for right clicking without modifiers are fundamentally incompatible with our system of primary and secondary attacks. Adds additional signals to attacking code. These signals allow atoms to cancel the attack chain early on secondary attacks, or override the standard procs and not send signals to prevent any undesired behaviour from signal handlers. Items that used RightClick procs have been converted to attack_hand_secondary. The slaughter demon, having its own set of snowflake code as poor OOP principles have been applied in UnarmedAttack() procs with lacking calls to parent procs and arbitrary redefinition of behaviour, checks for a right click in its own UnarmedAttack() and performs a bodyslam off that. Storage components now hijack the secondary attackby stage via signals to handle their opening and closing shortcuts on right click. When you right click a storage component equipped item with an object in your active hand, the object has an opportunity to perform its logic in pre secondary attack code and cancel the attack chain. If it does not cancel the attack chain in pre-attack, then the storage component takes over for attackby and, if possible, opens the relevant inventory and ends the attack chain. The forensic scanner is a proof-of-concept of this working in action. With its scan logic moved from afterattack code to pre attack code for right clicking, right clicking with the scanner will now perform a scan where previously one was impossible. Left clicking still does what it always does - Scans at the very end of the attack chain. The logic still isn't perfect - For example, you still can't attack containers in melee even in combat mode (you'll either open them or put your weapon into them regardless of which option you choose) - But this is a better setup overall which allows for items to at least override this behaviour in pre-attack if needed. * Modifies right click logic so that it is not the same priority as modifier keys. * a Co-authored-by: Timberpoes <silent_insomnia_pp@hotmail.co.uk> Co-authored-by: Gandalf <jzo123@hotmail.com>
129 lines
4.1 KiB
Plaintext
129 lines
4.1 KiB
Plaintext
#define UNREADY 0
|
|
#define IDLE 1
|
|
#define READY 2
|
|
|
|
/obj/machinery/plumbing/buffer
|
|
name = "automatic buffer"
|
|
desc = "A chemical holding tank that waits for neighbouring automatic buffers to complete before allowing a withdrawal. Connect/reset by screwdrivering"
|
|
icon_state = "buffer"
|
|
buffer = 200
|
|
|
|
var/datum/buffer_net/buffer_net
|
|
var/activation_volume = 100
|
|
var/mode
|
|
|
|
/obj/machinery/plumbing/buffer/Initialize(mapload, bolt, layer)
|
|
. = ..()
|
|
|
|
AddComponent(/datum/component/plumbing/buffer, bolt, layer)
|
|
|
|
/obj/machinery/plumbing/buffer/create_reagents(max_vol, flags)
|
|
. = ..()
|
|
RegisterSignal(reagents, list(COMSIG_REAGENTS_ADD_REAGENT, COMSIG_REAGENTS_NEW_REAGENT, COMSIG_REAGENTS_REM_REAGENT, COMSIG_REAGENTS_DEL_REAGENT, COMSIG_REAGENTS_CLEAR_REAGENTS, COMSIG_REAGENTS_REACTED), .proc/on_reagent_change)
|
|
RegisterSignal(reagents, COMSIG_PARENT_QDELETING, .proc/on_reagents_del)
|
|
|
|
/// Handles properly detaching signal hooks.
|
|
/obj/machinery/plumbing/buffer/proc/on_reagents_del(datum/reagents/reagents)
|
|
SIGNAL_HANDLER
|
|
UnregisterSignal(reagents, list(COMSIG_REAGENTS_ADD_REAGENT, COMSIG_REAGENTS_NEW_REAGENT, COMSIG_REAGENTS_REM_REAGENT, COMSIG_REAGENTS_DEL_REAGENT, COMSIG_REAGENTS_CLEAR_REAGENTS, COMSIG_REAGENTS_REACTED, COMSIG_PARENT_QDELETING))
|
|
return NONE
|
|
|
|
/obj/machinery/plumbing/buffer/proc/on_reagent_change()
|
|
SIGNAL_HANDLER
|
|
if(!buffer_net)
|
|
return
|
|
if(reagents.total_volume + CHEMICAL_QUANTISATION_LEVEL >= activation_volume && mode == UNREADY)
|
|
mode = IDLE
|
|
buffer_net.check_active()
|
|
|
|
else if(reagents.total_volume + CHEMICAL_QUANTISATION_LEVEL < activation_volume && mode != UNREADY)
|
|
mode = UNREADY
|
|
buffer_net.check_active()
|
|
|
|
/obj/machinery/plumbing/buffer/update_icon()
|
|
. = ..()
|
|
icon_state = initial(icon_state)
|
|
if(buffer_net)
|
|
switch(mode)
|
|
if(UNREADY)
|
|
icon_state += "_red"
|
|
if(IDLE)
|
|
icon_state += "_yellow"
|
|
if(READY)
|
|
icon_state += "_green"
|
|
|
|
/obj/machinery/plumbing/buffer/proc/attempt_connect()
|
|
|
|
for(var/direction in GLOB.cardinals)
|
|
var/turf/T = get_step(src, direction)
|
|
for(var/atom/movable/movable in T)
|
|
if(istype(movable, /obj/machinery/plumbing/buffer))
|
|
var/obj/machinery/plumbing/buffer/neighbour = movable
|
|
if(neighbour.buffer_net != buffer_net)
|
|
neighbour.buffer_net?.destruct()
|
|
//we could put this on a proc, but its so simple I dont think its worth the overhead
|
|
buffer_net.buffer_list += neighbour
|
|
neighbour.buffer_net = buffer_net
|
|
neighbour.attempt_connect() //technically this would runtime if you made about 200~ buffers
|
|
|
|
add_overlay(icon_state + "_alert")
|
|
addtimer(CALLBACK(src, /atom/.proc/cut_overlay, icon_state + "_alert"), 20)
|
|
|
|
/obj/machinery/plumbing/buffer/attack_hand_secondary(mob/user, modifiers)
|
|
. = ..()
|
|
if(. == SECONDARY_ATTACK_CANCEL_ATTACK_CHAIN)
|
|
return
|
|
|
|
. = SECONDARY_ATTACK_CANCEL_ATTACK_CHAIN
|
|
|
|
var/new_volume = input(user, "Enter new activation threshold", "Beepityboop", activation_volume) as num|null
|
|
if(!new_volume)
|
|
return
|
|
|
|
activation_volume = round(clamp(new_volume, 0, buffer))
|
|
to_chat(user, span_notice("New activation threshold is now [activation_volume]."))
|
|
return
|
|
|
|
/obj/machinery/plumbing/buffer/attackby(obj/item/item, mob/user, params)
|
|
if(item.tool_behaviour == TOOL_SCREWDRIVER)
|
|
to_chat(user, span_notice("You reset the automatic buffer."))
|
|
|
|
//reset the net
|
|
buffer_net?.destruct()
|
|
buffer_net = new()
|
|
LAZYADD(buffer_net.buffer_list, src)
|
|
|
|
attempt_connect()
|
|
else
|
|
return . = ..()
|
|
|
|
/obj/machinery/plumbing/buffer/doMove(destination)
|
|
. = ..()
|
|
buffer_net?.destruct()
|
|
|
|
/datum/buffer_net
|
|
var/list/obj/machinery/plumbing/buffer/buffer_list
|
|
|
|
/datum/buffer_net/proc/destruct()
|
|
for(var/obj/machinery/plumbing/buffer/buffer in buffer_list)
|
|
buffer.buffer_net = null
|
|
buffer_list.Cut()
|
|
qdel(src)
|
|
|
|
/datum/buffer_net/proc/check_active()
|
|
var/ready = TRUE
|
|
for(var/obj/machinery/plumbing/buffer/buffer in buffer_list)
|
|
if(buffer.mode == UNREADY)
|
|
ready = FALSE
|
|
break
|
|
for(var/obj/machinery/plumbing/buffer/buffer in buffer_list)
|
|
if(buffer.mode == READY && !ready)
|
|
buffer.mode = IDLE
|
|
else if(buffer.mode == IDLE && ready)
|
|
buffer.mode = READY
|
|
buffer.update_icon()
|
|
|
|
#undef UNREADY
|
|
#undef IDLE
|
|
#undef READY
|