mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-16 12:07:48 +00:00
375a20e49b
Converts most spans into span procs. Mostly used regex for this and sorted out any compile time errors afterwards so there could be some bugs. Was initially going to do defines, but ninja said to make it into a proc, and if there's any overhead, they can easily be changed to defines. Makes it easier to control the formatting and prevents typos when creating spans as it'll runtime if you misspell instead of silently failing. Reduces the code you need to write when writing spans, as you don't need to close the span as that's automatically handled by the proc. (Note from Lemon: This should be converted to defines once we update the minimum version to 514. Didn't do it now because byond pain and such)
79 lines
3.2 KiB
Plaintext
79 lines
3.2 KiB
Plaintext
/mob/verb/pray(msg as text)
|
|
set category = "IC"
|
|
set name = "Pray"
|
|
|
|
if(GLOB.say_disabled) //This is here to try to identify lag problems
|
|
to_chat(usr, span_danger("Speech is currently admin-disabled."), confidential = TRUE)
|
|
return
|
|
|
|
msg = copytext_char(sanitize(msg), 1, MAX_MESSAGE_LEN)
|
|
if(!msg)
|
|
return
|
|
log_prayer("[src.key]/([src.name]): [msg]")
|
|
if(usr.client)
|
|
if(usr.client.prefs.muted & MUTE_PRAY)
|
|
to_chat(usr, span_danger("You cannot pray (muted)."), confidential = TRUE)
|
|
return
|
|
if(src.client.handle_spam_prevention(msg,MUTE_PRAY))
|
|
return
|
|
|
|
var/mutable_appearance/cross = mutable_appearance('icons/obj/storage.dmi', "bible")
|
|
var/font_color = "purple"
|
|
var/prayer_type = "PRAYER"
|
|
var/deity
|
|
if(usr.job == "Chaplain")
|
|
cross.icon_state = "kingyellow"
|
|
font_color = "blue"
|
|
prayer_type = "CHAPLAIN PRAYER"
|
|
if(GLOB.deity)
|
|
deity = GLOB.deity
|
|
else if(IS_CULTIST(usr))
|
|
cross.icon_state = "tome"
|
|
font_color = "red"
|
|
prayer_type = "CULTIST PRAYER"
|
|
deity = "Nar'Sie"
|
|
else if(isliving(usr))
|
|
var/mob/living/L = usr
|
|
if(HAS_TRAIT(L, TRAIT_SPIRITUAL))
|
|
cross.icon_state = "holylight"
|
|
font_color = "blue"
|
|
prayer_type = "SPIRITUAL PRAYER"
|
|
|
|
var/msg_tmp = msg
|
|
msg = span_adminnotice("[icon2html(cross, GLOB.admins)]<b><font color=[font_color]>[prayer_type][deity ? " (to [deity])" : ""]: </font>[ADMIN_FULLMONTY(src)] [ADMIN_SC(src)]:</b> <span class='linkify'>[msg]</span>")
|
|
|
|
for(var/client/C in GLOB.admins)
|
|
if(C.prefs.chat_toggles & CHAT_PRAYER)
|
|
to_chat(C, msg, confidential = TRUE)
|
|
if(C.prefs.toggles & SOUND_PRAYERS)
|
|
if(usr.job == "Chaplain")
|
|
SEND_SOUND(C, sound('sound/effects/pray.ogg'))
|
|
to_chat(usr, span_info("You pray to the gods: \"[msg_tmp]\""), confidential = TRUE)
|
|
|
|
SSblackbox.record_feedback("tally", "admin_verb", 1, "Prayer") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
|
|
//log_admin("HELP: [key_name(src)]: [msg]")
|
|
|
|
/// Used by communications consoles to message CentCom
|
|
/proc/message_centcom(text, mob/sender)
|
|
var/msg = copytext_char(sanitize(text), 1, MAX_MESSAGE_LEN)
|
|
msg = span_adminnotice("<b><font color=orange>CENTCOM:</font>[ADMIN_FULLMONTY(sender)] [ADMIN_CENTCOM_REPLY(sender)]:</b> [msg]")
|
|
to_chat(GLOB.admins, msg, confidential = TRUE)
|
|
for(var/obj/machinery/computer/communications/console in GLOB.machines)
|
|
console.override_cooldown()
|
|
|
|
/// Used by communications consoles to message the Syndicate
|
|
/proc/message_syndicate(text, mob/sender)
|
|
var/msg = copytext_char(sanitize(text), 1, MAX_MESSAGE_LEN)
|
|
msg = span_adminnotice("<b><font color=crimson>SYNDICATE:</font>[ADMIN_FULLMONTY(sender)] [ADMIN_SYNDICATE_REPLY(sender)]:</b> [msg]")
|
|
to_chat(GLOB.admins, msg, confidential = TRUE)
|
|
for(var/obj/machinery/computer/communications/console in GLOB.machines)
|
|
console.override_cooldown()
|
|
|
|
/// Used by communications consoles to request the nuclear launch codes
|
|
/proc/nuke_request(text, mob/sender)
|
|
var/msg = copytext_char(sanitize(text), 1, MAX_MESSAGE_LEN)
|
|
msg = span_adminnotice("<b><font color=orange>NUKE CODE REQUEST:</font>[ADMIN_FULLMONTY(sender)] [ADMIN_CENTCOM_REPLY(sender)] [ADMIN_SET_SD_CODE]:</b> [msg]")
|
|
to_chat(GLOB.admins, msg, confidential = TRUE)
|
|
for(var/obj/machinery/computer/communications/console in GLOB.machines)
|
|
console.override_cooldown()
|