mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-15 20:22:07 +00:00
c529b754fb
* Fixes a bunch of callbacks that were being qdeleted, and code cleanup (#77904) ## About The Pull Request  Continuing the work of https://github.com/tgstation/tgstation/pull/77850. it started with finding one that was being missed and causing a runtime...then I noticed a whole lot more. While I was doing this I found callbacks that weren't being nulled in `Destroy()`, so I added that wherever I found these spots as well as some general code cleanup. There were a lot more of these than I initially hoped to encounter so I'm labeling it as a refactor. ## Why It's Good For The Game Fixes lots of runtimes, improves code resiliency. ## Changelog 🆑 refactor: fixed a bunch of instances of callbacks being qdeleted and cleaned up related code /🆑 * Fixes a bunch of callbacks that were being qdeleted, and code cleanup --------- Co-authored-by: Bloop <13398309+vinylspiders@users.noreply.github.com>
82 lines
3.0 KiB
Plaintext
82 lines
3.0 KiB
Plaintext
/**
|
|
* ## On Hit Effect Component!
|
|
*
|
|
* Component for other elements/components to rely on for on-hit effects without duplicating the on-hit code.
|
|
* See Lifesteal, or bane for examples.
|
|
*
|
|
* THIS COULD EASILY SUPPORT COMPONENT_DUPE_ALLOWED but the getcomponent makes it throw errors. if you can figure that out feel free to readd the dupe types
|
|
*/
|
|
/datum/component/on_hit_effect
|
|
///callback used by other components to apply effects
|
|
var/datum/callback/on_hit_callback
|
|
///callback optionally used for more checks
|
|
var/datum/callback/extra_check_callback
|
|
|
|
/datum/component/on_hit_effect/Initialize(on_hit_callback, extra_check_callback)
|
|
src.on_hit_callback = on_hit_callback
|
|
src.extra_check_callback = extra_check_callback
|
|
if(!(ismachinery(parent) || isstructure(parent) || isgun(parent) || isprojectilespell(parent) || isitem(parent) || isanimal_or_basicmob(parent) || isprojectile(parent)))
|
|
return ELEMENT_INCOMPATIBLE
|
|
|
|
/datum/component/on_hit_effect/Destroy(force, silent)
|
|
on_hit_callback = null
|
|
extra_check_callback = null
|
|
return ..()
|
|
|
|
/datum/component/on_hit_effect/RegisterWithParent()
|
|
if(ismachinery(parent) || isstructure(parent) || isgun(parent) || isprojectilespell(parent))
|
|
RegisterSignal(parent, COMSIG_PROJECTILE_ON_HIT, PROC_REF(on_projectile_hit))
|
|
else if(isitem(parent))
|
|
RegisterSignal(parent, COMSIG_ITEM_AFTERATTACK, PROC_REF(item_afterattack))
|
|
else if(isanimal_or_basicmob(parent))
|
|
RegisterSignal(parent, COMSIG_HOSTILE_POST_ATTACKINGTARGET, PROC_REF(hostile_attackingtarget))
|
|
else if(isprojectile(parent))
|
|
RegisterSignal(parent, COMSIG_PROJECTILE_SELF_ON_HIT, PROC_REF(on_projectile_self_hit))
|
|
|
|
/datum/component/on_hit_effect/UnregisterFromParent()
|
|
UnregisterSignal(parent, list(
|
|
COMSIG_PROJECTILE_ON_HIT,
|
|
COMSIG_ITEM_AFTERATTACK,
|
|
COMSIG_HOSTILE_POST_ATTACKINGTARGET,
|
|
COMSIG_PROJECTILE_SELF_ON_HIT,
|
|
))
|
|
|
|
/datum/component/on_hit_effect/proc/item_afterattack(obj/item/source, atom/target, mob/user, proximity_flag, click_parameters)
|
|
SIGNAL_HANDLER
|
|
|
|
if(!proximity_flag)
|
|
return
|
|
|
|
if(extra_check_callback)
|
|
if(!extra_check_callback.Invoke(user, target, source))
|
|
return
|
|
on_hit_callback.Invoke(source, user, target, user.zone_selected)
|
|
return COMPONENT_AFTERATTACK_PROCESSED_ITEM
|
|
|
|
/datum/component/on_hit_effect/proc/hostile_attackingtarget(mob/living/attacker, atom/target, success)
|
|
SIGNAL_HANDLER
|
|
|
|
if(!success)
|
|
return
|
|
|
|
if(extra_check_callback)
|
|
if(!extra_check_callback.Invoke(attacker, target))
|
|
return
|
|
on_hit_callback.Invoke(attacker, attacker, target, attacker.zone_selected)
|
|
|
|
/datum/component/on_hit_effect/proc/on_projectile_hit(datum/fired_from, atom/movable/firer, atom/target, angle, body_zone)
|
|
SIGNAL_HANDLER
|
|
|
|
if(extra_check_callback)
|
|
if(!extra_check_callback.Invoke(firer, target))
|
|
return
|
|
on_hit_callback.Invoke(fired_from, firer, target, body_zone)
|
|
|
|
/datum/component/on_hit_effect/proc/on_projectile_self_hit(datum/source, mob/firer, atom/target, angle, body_zone)
|
|
SIGNAL_HANDLER
|
|
|
|
if(extra_check_callback)
|
|
if(!extra_check_callback.Invoke(firer, target))
|
|
return
|
|
on_hit_callback.Invoke(source, firer, target, body_zone)
|