mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-21 22:47:19 +00:00
ee404b2170
* Cleanup world/New * Moves some things from OnReboot SS Shutdowns * Move mode handling procs to ticker * Moves delayed reboot to ticker Cleans up round end sound setting Splits round end animation between SStitle and SSticker * Moves PR announcement to where it can use the define * Clean this bit up * Move out datacore Initialization * Fix some stuff * Fix this for * Different PR * Gives admins reboot options * Make it smaller
73 lines
2.5 KiB
Plaintext
73 lines
2.5 KiB
Plaintext
/client/proc/play_sound(S as sound)
|
|
set category = "Fun"
|
|
set name = "Play Global Sound"
|
|
if(!check_rights(R_SOUNDS))
|
|
return
|
|
|
|
var/freq = 1
|
|
if(SSevents.holidays && SSevents.holidays[APRIL_FOOLS])
|
|
freq = pick(0.5, 0.7, 0.8, 0.85, 0.9, 0.95, 1.1, 1.2, 1.4, 1.6, 2.0, 2.5)
|
|
to_chat(src, "You feel the Honkmother messing with your song...")
|
|
|
|
var/sound/admin_sound = new()
|
|
admin_sound.file = S
|
|
admin_sound.priority = 250
|
|
admin_sound.channel = CHANNEL_ADMIN
|
|
admin_sound.frequency = freq
|
|
admin_sound.wait = 1
|
|
admin_sound.repeat = 0
|
|
admin_sound.status = SOUND_STREAM
|
|
|
|
var/res = alert(usr, "Show the title of this song to the players?",, "No", "Yes", "Cancel")
|
|
switch(res)
|
|
if("Yes")
|
|
to_chat(world, "<span class='boldannounce'>An admin played: [S]</span>")
|
|
if("Cancel")
|
|
return
|
|
|
|
log_admin("[key_name(src)] played sound [S]")
|
|
message_admins("[key_name_admin(src)] played sound [S]")
|
|
|
|
for(var/mob/M in GLOB.player_list)
|
|
if(M.client.prefs.toggles & SOUND_MIDI)
|
|
M << admin_sound
|
|
|
|
SSblackbox.add_details("admin_verb","Play Global Sound") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
|
|
|
|
|
|
/client/proc/play_local_sound(S as sound)
|
|
set category = "Fun"
|
|
set name = "Play Local Sound"
|
|
if(!check_rights(R_SOUNDS))
|
|
return
|
|
|
|
log_admin("[key_name(src)] played a local sound [S]")
|
|
message_admins("[key_name_admin(src)] played a local sound [S]")
|
|
playsound(get_turf(src.mob), S, 50, 0, 0)
|
|
SSblackbox.add_details("admin_verb","Play Local Sound") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
|
|
|
|
/client/proc/set_round_end_sound(S as sound)
|
|
set category = "Fun"
|
|
set name = "Set Round End Sound"
|
|
if(!check_rights(R_SOUNDS))
|
|
return
|
|
|
|
SSticker.SetRoundEndSound(S)
|
|
|
|
log_admin("[key_name(src)] set the round end sound to [S]")
|
|
message_admins("[key_name_admin(src)] set the round end sound to [S]")
|
|
SSblackbox.add_details("admin_verb","Set Round End Sound") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
|
|
|
|
/client/proc/stop_sounds()
|
|
set category = "Debug"
|
|
set name = "Stop All Playing Sounds"
|
|
if(!src.holder)
|
|
return
|
|
|
|
log_admin("[key_name(src)] stopped all currently playing sounds.")
|
|
message_admins("[key_name_admin(src)] stopped all currently playing sounds.")
|
|
for(var/mob/M in GLOB.player_list)
|
|
if(M.client)
|
|
M << sound(null)
|
|
SSblackbox.add_details("admin_verb","Stop All Playing Sounds") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
|