mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-17 12:35:26 +00:00
8e3f635b98
## About The Pull Request Rewrites how alt click works. Based heavily on #82625. What a cool concept, it flows nicely with #82533. Fixes #81242 (tm bugs fixed) Fixes #82668 <details><summary>More info for devs</summary> Handy regex used for alt click s&r: `AltClick\((.*).*\)(\n\t.*\.\.\(\))?` `click_alt($1)` (yes I am aware this only copies the first arg. there are no other args!) ### Obj reskins No reason for obj reskin to check on every single alt click for every object. It applies to only a few items. - Moved to obj/item - Made into signal - Added screentips ### Ventcrawling Every single atmospherics machine checked for ventcrawling capability on alt click despite only 3 objects needing that functionality. This has been moved down to those individual items. </details> ## Why It's Good For The Game For players: - Alt clicking should work more logically, not causing double actions like eject disk and open item window - Added context menus for reskinnable items - Removed adjacency restriction on loot panel For devs: - Makes alt click interactions easier to work with, no more click chain nonsense and redundant guard clauses. - OOP hell reduced - Pascal Case reduced - Glorious snake case ## Changelog 🆑 add: The lootpanel now works at range. add: Screentips for reskinnable items. fix: Alt click interactions have been refactored, which may lead to unintentional changes to gameplay. Report any issues, please. /🆑
80 lines
2.3 KiB
Plaintext
80 lines
2.3 KiB
Plaintext
/mob/dead/observer/DblClickOn(atom/A, params)
|
|
if(check_click_intercept(params, A))
|
|
return
|
|
|
|
// Things you might plausibly want to follow
|
|
if(ismovable(A))
|
|
ManualFollow(A)
|
|
|
|
// Otherwise jump
|
|
else if(A.loc)
|
|
abstract_move(get_turf(A))
|
|
|
|
/mob/dead/observer/ClickOn(atom/A, params)
|
|
if(check_click_intercept(params,A))
|
|
return
|
|
|
|
var/list/modifiers = params2list(params)
|
|
if(LAZYACCESS(modifiers, SHIFT_CLICK))
|
|
if(LAZYACCESS(modifiers, MIDDLE_CLICK))
|
|
ShiftMiddleClickOn(A)
|
|
return
|
|
if(LAZYACCESS(modifiers, CTRL_CLICK))
|
|
CtrlShiftClickOn(A)
|
|
return
|
|
ShiftClickOn(A)
|
|
return
|
|
if(LAZYACCESS(modifiers, MIDDLE_CLICK))
|
|
if(LAZYACCESS(modifiers, CTRL_CLICK))
|
|
CtrlMiddleClickOn(A)
|
|
else
|
|
MiddleClickOn(A, params)
|
|
return
|
|
if(LAZYACCESS(modifiers, ALT_CLICK))
|
|
base_click_alt(A)
|
|
return
|
|
if(LAZYACCESS(modifiers, CTRL_CLICK))
|
|
CtrlClickOn(A)
|
|
return
|
|
|
|
if(world.time <= next_move)
|
|
return
|
|
// You are responsible for checking config.ghost_interaction when you override this function
|
|
// Not all of them require checking, see below
|
|
A.attack_ghost(src)
|
|
|
|
// Oh by the way this didn't work with old click code which is why clicking shit didn't spam you
|
|
/atom/proc/attack_ghost(mob/dead/observer/user)
|
|
if(SEND_SIGNAL(src, COMSIG_ATOM_ATTACK_GHOST, user) & COMPONENT_CANCEL_ATTACK_CHAIN)
|
|
return TRUE
|
|
if(user.client)
|
|
if(user.gas_scan && atmos_scan(user=user, target=src, silent=TRUE))
|
|
return TRUE
|
|
else if(isAdminGhostAI(user))
|
|
attack_ai(user)
|
|
else if(user.client.prefs.read_preference(/datum/preference/toggle/inquisitive_ghost))
|
|
user.examinate(src)
|
|
return FALSE
|
|
|
|
/mob/living/attack_ghost(mob/dead/observer/user)
|
|
if(user.client && user.health_scan)
|
|
healthscan(user, src, 1, TRUE)
|
|
if(user.client && user.chem_scan)
|
|
chemscan(user, src)
|
|
return ..()
|
|
|
|
// ---------------------------------------
|
|
// And here are some good things for free:
|
|
// Now you can click through portals, wormholes, gateways, and teleporters while observing. -Sayu
|
|
|
|
/obj/machinery/teleport/hub/attack_ghost(mob/user)
|
|
if(!power_station?.engaged || !power_station.teleporter_console || !power_station.teleporter_console.target_ref)
|
|
return ..()
|
|
|
|
var/atom/target = power_station.teleporter_console.target_ref.resolve()
|
|
if(!target)
|
|
power_station.teleporter_console.target_ref = null
|
|
return ..()
|
|
|
|
user.abstract_move(get_turf(target))
|