mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-17 04:27:39 +00:00
ff6b41aa07
## About The Pull Request - Afterattack is a very simple proc now: All it does is this, and all it's used for is for having a convenient place to put effects an item does after a successful attack (IE, the attack was not blocked)  - An overwhelming majority of afterattack implementations have been moved to `interact_with_atom` or the new `ranged_interact_with_atom` I have manually tested many of the refactored procs but there was 200+ so it's kinda hard ## Why It's Good For The Game Afterattack is one of the worst parts of the attack chain, as it simultaneously serves as a way of doing random interactions NOT AT ALL related to attacks (despite the name) while ALSO serving as the defacto way to do a ranged interaction with an item This means careless coders (most of them) may throw stuff in afterattack without realizing how wide reaching it is, which causes bugs. By making two well defined, separate procs for handing adjacent vs ranged interactions, it becomes WAY WAY WAY more easy to develop for. If you want to do something when you click on something else and you're adjacent, use `interact_with_atom` If you want to do something when you click on something else and you're not adjacent, use 'ranged_interact_with_atom` This does result in some instances of boilerplate as shown here:  But I think it's acceptable, feel free to oppose if you don't I'm sure we can think of another solution ~~Additionally it makes it easier to implement swing combat. That's a bonus I guess~~ ## Changelog 🆑 Melbert refactor: Over 200 item interactions have been refactored to use a newer, easier-to-use system. Report any oddities with using items on other objects you may see (such as surgery, reagent containers like cups and spray bottles, or construction devices), especially using something at range (such as guns or chisels) refactor: Item-On-Modsuit interactions have changed slightly. While on combat mode, you will attempt to "use" the item on the suit instead of inserting it into the suit's storage. This means being on combat mode while the suit's panel is open will block you from inserting items entirely via click (but other methods such as hotkey, clicking on the storage boxes, and mousedrop will still work). refactor: The detective's scanner will now be inserted into storage items if clicked normally, and will scan the storage item if on combat mode /🆑
115 lines
4.6 KiB
Plaintext
115 lines
4.6 KiB
Plaintext
#define ENGINE_COOLDOWN (5 SECONDS)
|
|
#define DASH_COOLDOWN (2.5 SECONDS)
|
|
#define HOUSE_EDGE_ICONS_MAX 3
|
|
#define HOUSE_EDGE_ICONS_MIN 0
|
|
|
|
/obj/item/v8_engine
|
|
name = "ancient engine"
|
|
desc = "An extremely well perserved, massive V8 engine from the early 2000s. It seems to be missing the rest of the vehicle. There's a tiny label on the side."
|
|
icon = 'icons/obj/weapons/sword.dmi'
|
|
icon_state = "v8_engine"
|
|
w_class = WEIGHT_CLASS_HUGE
|
|
force = 5
|
|
throwforce = 15
|
|
throw_range = 1
|
|
throw_speed = 1
|
|
COOLDOWN_DECLARE(engine_sound_cooldown)
|
|
|
|
/obj/item/v8_engine/Initialize(mapload)
|
|
. = ..()
|
|
AddComponent(/datum/component/two_handed, require_twohands=TRUE, force_unwielded=5, force_wielded=5)
|
|
|
|
/obj/item/v8_engine/attack_self(mob/user, modifiers)
|
|
. = ..()
|
|
if (!COOLDOWN_FINISHED(src, engine_sound_cooldown))
|
|
return
|
|
playsound(src, 'sound/items/car_engine_start.ogg', vol = 75, vary = FALSE, extrarange = 3)
|
|
Shake(duration = ENGINE_COOLDOWN)
|
|
to_chat(user, span_notice("Darn thing... it's too old to keep on without retrofitting it! Without modifications, it works like it's junk."))
|
|
COOLDOWN_START(src, engine_sound_cooldown, ENGINE_COOLDOWN)
|
|
|
|
/obj/item/v8_engine/examine_more(mob/user)
|
|
. = ..()
|
|
INVOKE_ASYNC(src, PROC_REF(start_learning_recipe), user)
|
|
|
|
/obj/item/v8_engine/proc/start_learning_recipe(mob/user)
|
|
if(!user.mind)
|
|
return
|
|
if(user.mind.has_crafting_recipe(user = user, potential_recipe = /datum/crafting_recipe/house_edge))
|
|
return
|
|
to_chat(user, span_notice("You peer at the label on the side, reading about some unique modifications that could be made to the engine..."))
|
|
if(do_after(user, 15 SECONDS, src))
|
|
user.mind.teach_crafting_recipe(/datum/crafting_recipe/house_edge)
|
|
to_chat(user, span_notice("You learned how to make the House Edge."))
|
|
|
|
/obj/item/house_edge
|
|
name = "House Edge"
|
|
desc = "Dangerous. Loud. Sleek. It has a built in roulette wheel. This thing could easily rip your arm off if you're not careful."
|
|
icon = 'icons/obj/weapons/sword.dmi'
|
|
icon_state = "house_edge0"
|
|
inhand_icon_state = "house_edge0"
|
|
lefthand_file = 'icons/mob/inhands/weapons/swords_lefthand.dmi'
|
|
righthand_file = 'icons/mob/inhands/weapons/swords_righthand.dmi'
|
|
w_class = WEIGHT_CLASS_HUGE
|
|
sharpness = SHARP_EDGED
|
|
force = 12
|
|
throwforce = 10
|
|
throw_range = 5
|
|
throw_speed = 1
|
|
hitsound = 'sound/items/car_engine_start.ogg'
|
|
/// The number of charges the house edge has accrued through 2-handed hits, to charge a more powerful charge attack.
|
|
var/fire_charges = 0
|
|
///Sound played when wielded.
|
|
var/active_hitsound = 'sound/items/house_edge_hit.ogg'
|
|
///Datum that tracks weapon dashing for the fire_charge system
|
|
var/datum/action/innate/dash/charge
|
|
COOLDOWN_DECLARE(fire_charge_cooldown)
|
|
|
|
/obj/item/house_edge/Initialize(mapload)
|
|
. = ..()
|
|
AddComponent(/datum/component/two_handed, force_unwielded = 12, force_wielded = 22, attacksound = active_hitsound)
|
|
RegisterSignals(src, list(COMSIG_ITEM_DROPPED, COMSIG_MOVABLE_PRE_THROW, COMSIG_ITEM_ATTACK_SELF), PROC_REF(reset_charges))
|
|
|
|
/obj/item/house_edge/afterattack(atom/target, mob/user, click_parameters)
|
|
if(!ismob(target))
|
|
return
|
|
if(HAS_TRAIT(src, TRAIT_WIELDED))
|
|
//Add a fire charge to a max of 3, updates icon_state.
|
|
fire_charges = clamp((fire_charges + 1), HOUSE_EDGE_ICONS_MIN, HOUSE_EDGE_ICONS_MAX)
|
|
COOLDOWN_RESET(src, fire_charge_cooldown)
|
|
else
|
|
//Lose a fire charge to a min of 0, updates icon_state.
|
|
fire_charges = clamp((fire_charges - 1), HOUSE_EDGE_ICONS_MIN, HOUSE_EDGE_ICONS_MAX)
|
|
do_sparks(number = 0, cardinal_only = TRUE, source = src)
|
|
update_appearance(UPDATE_ICON_STATE)
|
|
|
|
/obj/item/house_edge/ranged_interact_with_atom_secondary(atom/interacting_with, mob/living/user, list/modifiers)
|
|
if(!COOLDOWN_FINISHED(src, fire_charge_cooldown))
|
|
return ITEM_INTERACT_BLOCKING
|
|
if(fire_charges <= 0)
|
|
balloon_alert(user, "no fire charges!")
|
|
return ITEM_INTERACT_BLOCKING
|
|
user.throw_at(target = get_turf(interacting_with), range = 2 * fire_charges, speed = 5, thrower = user, spin = FALSE, gentle = FALSE, quickstart = TRUE)
|
|
COOLDOWN_START(src, fire_charge_cooldown, DASH_COOLDOWN)
|
|
reset_charges(on_dash = TRUE)
|
|
return ITEM_INTERACT_SUCCESS
|
|
|
|
/obj/item/house_edge/update_icon_state()
|
|
inhand_icon_state = HAS_TRAIT(src, TRAIT_WIELDED) ? "house_edge1" : "house_edge0"
|
|
icon_state = "house_edge[fire_charges]"
|
|
return ..()
|
|
|
|
/obj/item/house_edge/proc/reset_charges(on_dash = FALSE)
|
|
if(!COOLDOWN_FINISHED(src, fire_charge_cooldown) && !on_dash)
|
|
return
|
|
if(fire_charges)
|
|
balloon_alert_to_viewers("charges lost!")
|
|
fire_charges = 0
|
|
icon_state = "house_edge[fire_charges]"
|
|
update_icon()
|
|
|
|
#undef ENGINE_COOLDOWN
|
|
#undef DASH_COOLDOWN
|
|
#undef HOUSE_EDGE_ICONS_MAX
|
|
#undef HOUSE_EDGE_ICONS_MIN
|