mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-01 20:42:08 +00:00
375a20e49b
Converts most spans into span procs. Mostly used regex for this and sorted out any compile time errors afterwards so there could be some bugs. Was initially going to do defines, but ninja said to make it into a proc, and if there's any overhead, they can easily be changed to defines. Makes it easier to control the formatting and prevents typos when creating spans as it'll runtime if you misspell instead of silently failing. Reduces the code you need to write when writing spans, as you don't need to close the span as that's automatically handled by the proc. (Note from Lemon: This should be converted to defines once we update the minimum version to 514. Didn't do it now because byond pain and such)
40 lines
1.2 KiB
Plaintext
40 lines
1.2 KiB
Plaintext
/datum/component/tether
|
|
dupe_mode = COMPONENT_DUPE_UNIQUE_PASSARGS
|
|
var/atom/tether_target
|
|
var/max_dist
|
|
var/tether_name
|
|
|
|
/datum/component/tether/Initialize(atom/tether_target, max_dist = 4, tether_name)
|
|
if(!isliving(parent) || !istype(tether_target) || !tether_target.loc)
|
|
return COMPONENT_INCOMPATIBLE
|
|
src.tether_target = tether_target
|
|
src.max_dist = max_dist
|
|
if (ispath(tether_name, /atom))
|
|
var/atom/tmp = tether_name
|
|
src.tether_name = initial(tmp.name)
|
|
else
|
|
src.tether_name = tether_name
|
|
RegisterSignal(parent, list(COMSIG_MOVABLE_PRE_MOVE), .proc/checkTether)
|
|
|
|
/datum/component/tether/proc/checkTether(mob/mover, newloc)
|
|
SIGNAL_HANDLER
|
|
|
|
if (get_dist(mover,newloc) > max_dist)
|
|
to_chat(mover, span_userdanger("The [tether_name] runs out of slack and prevents you from moving!"))
|
|
return COMPONENT_MOVABLE_BLOCK_PRE_MOVE
|
|
|
|
var/atom/blocker
|
|
out:
|
|
for(var/turf/T in getline(tether_target,newloc))
|
|
if (T.density)
|
|
blocker = T
|
|
break out
|
|
for(var/a in T)
|
|
var/atom/A = a
|
|
if(A.density && A != mover && A != tether_target)
|
|
blocker = A
|
|
break out
|
|
if (blocker)
|
|
to_chat(mover, span_userdanger("The [tether_name] catches on [blocker] and prevents you from moving!"))
|
|
return COMPONENT_MOVABLE_BLOCK_PRE_MOVE
|