mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-06-01 12:07:02 +01:00
SkyratBot
45a1502809
* Automatic changelog for PR #23141 [ci skip] * Replaces Big Mob Tiny Sprites With Togglable Clientside Transparency For Big Mobs * Replaces Big Mob Tiny Sprites With Togglable Clientside Transparency For Big Mobs (#77361) ## About The Pull Request This PR replaces the tiny mob sprite abilities for our large mobs with a Toggle Seethrough ability. What this does when enabled is make yourself transparent on your own client and makes you unable to click yourself. With this, any sort of overlays that get added look correct while in your tiny mob form and you can still appreciate your large size without giving up the ability to click on targets that would be hiding underneath your sprite.   In total, this ability is granted to all the mobs who had tiny sprites: - Xenomorph Queen - Space Dragon - Megafauna (not that players ever get access to these normally, but it might be nice for admins) Along with all this, I've also gone and expanded the mobs who get access to the Seethrough ability to mobs that are large but didn't have a mini-sprite. This includes: - Jungle giants (leaper and mega arachnid) - Tree mob - Festivus pole mob - Lavaland elites - Xenomorph Praetorian - Wumborian Fugu On top of all this, any simple/basic mob given a fugu gland also automatically gains this ability. This solution also fixes all the overlays bugs that tiny mob sprites introduced to the game, most notably the xenomorph queen overlays being screwy when in small form and space dragon's overlays being completely disabled for everyone if he was in small form. The only issue with this currently is that clicking on any overlays from your mob will let you still click on yourself, though this issue is pretty negligible. ## Why It's Good For The Game Tiny mob sprite abilities clashed very hard with our overlay system, leading to a lot of buggy and unintended behavior. This replacement works a lot more smoothly with overlays and also requires much less setup to give it to a mob than tiny sprites did. I would also imagine it helps keep the fantasy of being a big monster alive by letting you still see yourself being a big monster without it getting in your way when trying to attack things. ## Changelog 🆑 del: Removed tiny mob sprite abilities for large mobs add: Add a Self Seethrough ability, given to most large mobs and all mobs affected by a fugu gland fix: Space Dragon's overlay will no longer vanish at times --------- Co-authored-by: MrMelbert <51863163+MrMelbert@users.noreply.github.com> Co-authored-by: Ghom <42542238+Ghommie@users.noreply.github.com> * Delete AutoChangeLog-pr-23141.yml This is really weird * Modular adjustments --------- Co-authored-by: IndieanaJones <47086570+IndieanaJones@users.noreply.github.com> Co-authored-by: MrMelbert <51863163+MrMelbert@users.noreply.github.com> Co-authored-by: Ghom <42542238+Ghommie@users.noreply.github.com> Co-authored-by: Bloop <13398309+vinylspiders@users.noreply.github.com>
119 lines
3.6 KiB
Plaintext
119 lines
3.6 KiB
Plaintext
/mob/living/basic/tree
|
|
name = "pine tree"
|
|
desc = "A pissed off tree-like alien. It seems annoyed with the festivities..."
|
|
icon = 'icons/obj/fluff/flora/pinetrees.dmi'
|
|
icon_state = "pine_1"
|
|
icon_living = "pine_1"
|
|
icon_dead = "pine_1"
|
|
icon_gib = "pine_1"
|
|
health_doll_icon = "pine_1"
|
|
mob_biotypes = MOB_ORGANIC | MOB_PLANT
|
|
gender = NEUTER
|
|
gold_core_spawnable = HOSTILE_SPAWN
|
|
basic_mob_flags = DEL_ON_DEATH
|
|
|
|
response_help_continuous = "brushes"
|
|
response_help_simple = "brush"
|
|
response_disarm_continuous = "pushes"
|
|
response_disarm_simple = "push"
|
|
|
|
mob_size = MOB_SIZE_LARGE
|
|
pixel_x = -16
|
|
base_pixel_x = -16
|
|
|
|
speed = 1
|
|
maxHealth = 250
|
|
health = 250
|
|
melee_damage_lower = 8
|
|
melee_damage_upper = 12
|
|
attack_verb_continuous = "bites"
|
|
attack_verb_simple = "bite"
|
|
attack_sound = 'sound/weapons/bite.ogg'
|
|
attack_vis_effect = ATTACK_EFFECT_BITE
|
|
|
|
faction = list(FACTION_HOSTILE)
|
|
speak_emote = list("pines")
|
|
|
|
habitable_atmos = list("min_oxy" = 2, "max_oxy" = 0, "min_plas" = 0, "max_plas" = 0, "min_co2" = 0, "max_co2" = 0, "min_n2" = 0, "max_n2" = 0)
|
|
unsuitable_atmos_damage = 2.5
|
|
minimum_survivable_temperature = 0
|
|
maximum_survivable_temperature = 1200
|
|
|
|
death_message = "is hacked into pieces!"
|
|
|
|
ai_controller = /datum/ai_controller/basic_controller/tree
|
|
|
|
///items that make us angry
|
|
var/list/infuriating_objects = list(/obj/item/chainsaw, /obj/item/hatchet, /obj/item/stack/sheet/mineral/wood)
|
|
///chance of target getting paralyzed
|
|
var/paralyze_prob = 15
|
|
///for how the target is paralyzed
|
|
var/paralyze_value = 5 SECONDS
|
|
///Additional paralyze chance
|
|
var/anger_boost = 50
|
|
|
|
/mob/living/basic/tree/Initialize(mapload)
|
|
. = ..()
|
|
AddComponent(/datum/component/seethrough_mob)
|
|
AddElement(/datum/element/swabable, CELL_LINE_TABLE_PINE, CELL_VIRUS_TABLE_GENERIC_MOB, 1, 5)
|
|
var/static/list/death_loot = list(/obj/item/stack/sheet/mineral/wood)
|
|
AddElement(/datum/element/death_drops, death_loot)
|
|
AddComponent(/datum/component/aggro_emote, emote_list = string_list(list("growls")), emote_chance = 20)
|
|
|
|
/mob/living/basic/tree/Life(seconds_per_tick = SSMOBS_DT, times_fired)
|
|
..()
|
|
if(!isopenturf(loc))
|
|
return
|
|
var/turf/open/our_turf = src.loc
|
|
if(!our_turf.air || !our_turf.air.gases[/datum/gas/carbon_dioxide])
|
|
return
|
|
|
|
var/co2 = our_turf.air.gases[/datum/gas/carbon_dioxide][MOLES]
|
|
if(co2 > 0 && SPT_PROB(13, seconds_per_tick))
|
|
var/amt = min(co2, 9)
|
|
our_turf.air.gases[/datum/gas/carbon_dioxide][MOLES] -= amt
|
|
our_turf.atmos_spawn_air("[GAS_O2]=[amt]")
|
|
|
|
/mob/living/basic/tree/melee_attack(atom/target, list/modifiers)
|
|
. = ..()
|
|
|
|
if(!.)
|
|
return
|
|
|
|
if(!isliving(target))
|
|
return
|
|
|
|
var/mob/living/victim = target
|
|
var/boost = 0
|
|
if(iscarbon(victim))
|
|
for(var/item_path in infuriating_objects)
|
|
if(locate(item_path) in victim.held_items)
|
|
boost = anger_boost
|
|
break
|
|
|
|
if(prob(paralyze_prob + boost))
|
|
victim.Paralyze(paralyze_value + boost)
|
|
victim.visible_message(
|
|
span_danger("[src] knocks down [victim]!"),
|
|
span_userdanger("[src] knocks you down!"),
|
|
)
|
|
|
|
/datum/ai_controller/basic_controller/tree
|
|
blackboard = list(
|
|
BB_TARGETTING_DATUM = new /datum/targetting_datum/basic(),
|
|
)
|
|
|
|
ai_movement = /datum/ai_movement/basic_avoidance
|
|
idle_behavior = /datum/idle_behavior/idle_random_walk/less_walking
|
|
planning_subtrees = list(
|
|
/datum/ai_planning_subtree/simple_find_target,
|
|
/datum/ai_planning_subtree/basic_melee_attack_subtree/tree,
|
|
/datum/ai_planning_subtree/random_speech/tree,
|
|
)
|
|
|
|
/datum/ai_planning_subtree/basic_melee_attack_subtree/tree
|
|
melee_attack_behavior = /datum/ai_behavior/basic_melee_attack/tree
|
|
|
|
/datum/ai_behavior/basic_melee_attack/tree
|
|
action_cooldown = 2 SECONDS
|