mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-19 14:12:55 +00:00
58501dce77
## About The Pull Request <details> - renamed ai folder to announcer -- announcer -- - moved vox_fem to announcer - moved approachingTG to announcer - separated the ambience folder into ambience and instrumental -- ambience -- - created holy folder moved all related sounds there - created engineering folder and moved all related sounds there - created security folder and moved ambidet there - created general folder and moved ambigen there - created icemoon folder and moved all icebox-related ambience there - created medical folder and moved all medbay-related ambi there - created ruin folder and moves all ruins ambi there - created beach folder and moved seag and shore there - created lavaland folder and moved related ambi there - created aurora_caelus folder and placed its ambi there - created misc folder and moved the rest of the files that don't have a specific category into it -- instrumental -- - moved traitor folder here - created lobby_music folder and placed our songs there (title0 not used anywhere? - server-side modification?) -- items -- - moved secdeath to hailer - moved surgery to handling -- effects -- - moved chemistry into effects - moved hallucinations into effects - moved health into effects - moved magic into effects -- vehicles -- - moved mecha into vehicles created mobs folder -- mobs -- - moved creatures folder into mobs - moved voice into mobs renamed creatures to non-humanoids renamed voice to humanoids -- non-humanoids-- created cyborg folder created hiss folder moved harmalarm.ogg to cyborg -- humanoids -- -- misc -- moved ghostwhisper to misc moved insane_low_laugh to misc I give up trying to document this. </details> - [X] ambience - [x] announcer - [x] effects - [X] instrumental - [x] items - [x] machines - [x] misc - [X] mobs - [X] runtime - [X] vehicles - [ ] attributions ## Why It's Good For The Game This folder is so disorganized that it's vomit inducing, will make it easier to find and add new sounds, providng a minor structure to the sound folder. ## Changelog 🆑 grungussuss refactor: the sound folder in the source code has been reorganized, please report any oddities with sounds playing or not playing server: lobby music has been repathed to sound/music/lobby_music /🆑
59 lines
1.9 KiB
Plaintext
59 lines
1.9 KiB
Plaintext
#define MULTIPLY_PIXELSPEED 0.8
|
|
|
|
/obj/projectile/energy/photon
|
|
name = "photon bolt"
|
|
icon_state = "solarflare"
|
|
damage_type = STAMINA
|
|
armor_flag = ENERGY
|
|
impact_effect_type = /obj/effect/temp_visual/impact_effect/blue_laser
|
|
damage = 5 //It's literally a weaker tesla bolt, which is already weak. Don't worry, we'll fix that.
|
|
range = 20
|
|
speed = 1
|
|
pixel_speed_multiplier = 1
|
|
projectile_piercing = PASSMOB
|
|
light_color = LIGHT_COLOR_DEFAULT
|
|
light_system = OVERLAY_LIGHT
|
|
light_power = 5
|
|
light_range = 6
|
|
|
|
|
|
/obj/projectile/energy/photon/Initialize(mapload)
|
|
. = ..()
|
|
RegisterSignals(src, list(COMSIG_MOVABLE_CROSS, COMSIG_MOVABLE_CROSS_OVER), PROC_REF(blast_touched))
|
|
RegisterSignal(src, COMSIG_ATOM_ENTERED, PROC_REF(scorch_earth))
|
|
set_light_on(TRUE)
|
|
|
|
/**
|
|
* Handle side effects for the phonon bolt.
|
|
* behaves like a higher power direct flash if hit, and sparks silicons like they're getting microwaved.
|
|
*/
|
|
/obj/projectile/energy/photon/proc/blast_touched(datum/source, atom/flashed)
|
|
SIGNAL_HANDLER
|
|
if(isliving(flashed))
|
|
var/mob/living/flashed_creature = flashed
|
|
flashed_creature.flash_act(intensity = 3, affect_silicon = TRUE, length = 6)
|
|
flashed_creature.adjust_confusion(1.5 SECONDS)
|
|
if(issilicon(flashed))
|
|
do_sparks(rand(1, 4), FALSE, src)
|
|
|
|
/**
|
|
* When traveling to a new turf, throws a probability to generate a hotspot across its path.
|
|
*/
|
|
/obj/projectile/energy/photon/proc/scorch_earth(turf/open/floor/source, atom/movable/arrived, atom/old_loc, list/atom/old_locs)
|
|
SIGNAL_HANDLER
|
|
if(prob(40))
|
|
new /obj/effect/hotspot(arrived)
|
|
|
|
/obj/projectile/energy/photon/Range()
|
|
. = ..()
|
|
pixel_speed_multiplier *= MULTIPLY_PIXELSPEED
|
|
|
|
/obj/projectile/energy/photon/on_range()
|
|
do_sparks(rand(4, 9), FALSE, src)
|
|
playsound(loc, 'sound/items/weapons/solarflare.ogg', 100, FALSE, 8, 0.9)
|
|
for(var/mob/living/flashed_mob in viewers(5, loc))
|
|
flashed_mob.flash_act()
|
|
return ..()
|
|
|
|
#undef MULTIPLY_PIXELSPEED
|