mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-10 09:42:29 +00:00
049b19bb18
* Moves "catch this var/flag" code from obj/init and datum/new into the types that use it * Update atoms_movable.dm * Update airlock.dm * SRCC Co-authored-by: LemonInTheDark <58055496+LemonInTheDark@users.noreply.github.com> Co-authored-by: Zonespace <41448081+Zonespace27@users.noreply.github.com> Co-authored-by: John Doe <gamingskeleton3@gmail.com>
74 lines
2.7 KiB
Plaintext
74 lines
2.7 KiB
Plaintext
#define ARMORID "armor-[melee]-[bullet]-[laser]-[energy]-[bomb]-[bio]-[fire]-[acid]-[wound]-[consume]"
|
|
|
|
/proc/getArmor(melee = 0, bullet = 0, laser = 0, energy = 0, bomb = 0, bio = 0, fire = 0, acid = 0, wound = 0, consume = 0)
|
|
. = locate(ARMORID)
|
|
if (!.)
|
|
. = new /datum/armor(melee, bullet, laser, energy, bomb, bio, fire, acid, wound, consume)
|
|
|
|
/datum/armor
|
|
var/melee
|
|
var/bullet
|
|
var/laser
|
|
var/energy
|
|
var/bomb
|
|
var/bio
|
|
var/fire
|
|
var/acid
|
|
var/wound
|
|
var/consume
|
|
|
|
/datum/armor/New(melee = 0, bullet = 0, laser = 0, energy = 0, bomb = 0, bio = 0, fire = 0, acid = 0, wound = 0, consume = 0)
|
|
src.melee = melee
|
|
src.bullet = bullet
|
|
src.laser = laser
|
|
src.energy = energy
|
|
src.bomb = bomb
|
|
src.bio = bio
|
|
src.fire = fire
|
|
src.acid = acid
|
|
src.wound = wound
|
|
src.consume = consume
|
|
GenerateTag()
|
|
|
|
/datum/armor/proc/modifyRating(melee = 0, bullet = 0, laser = 0, energy = 0, bomb = 0, bio = 0, fire = 0, acid = 0, wound = 0, consume = 0)
|
|
return getArmor(src.melee+melee, src.bullet+bullet, src.laser+laser, src.energy+energy, src.bomb+bomb, src.bio+bio, src.fire+fire, src.acid+acid, src.wound+wound, src.consume+consume)
|
|
|
|
/datum/armor/proc/modifyAllRatings(modifier = 0)
|
|
return getArmor(melee+modifier, bullet+modifier, laser+modifier, energy+modifier, bomb+modifier, bio+modifier, fire+modifier, acid+modifier, wound+modifier, consume+modifier)
|
|
|
|
/datum/armor/proc/setRating(melee, bullet, laser, energy, bomb, bio, fire, acid, wound, consume)
|
|
return getArmor((isnull(melee) ? src.melee : melee),\
|
|
(isnull(bullet) ? src.bullet : bullet),\
|
|
(isnull(laser) ? src.laser : laser),\
|
|
(isnull(energy) ? src.energy : energy),\
|
|
(isnull(bomb) ? src.bomb : bomb),\
|
|
(isnull(bio) ? src.bio : bio),\
|
|
(isnull(fire) ? src.fire : fire),\
|
|
(isnull(acid) ? src.acid : acid),\
|
|
(isnull(wound) ? src.wound : wound),\
|
|
(isnull(consume) ? src.consume : consume))
|
|
|
|
/datum/armor/proc/getRating(rating)
|
|
return vars[rating]
|
|
|
|
/datum/armor/proc/getList()
|
|
return list(MELEE = melee, BULLET = bullet, LASER = laser, ENERGY = energy, BOMB = bomb, BIO = bio, FIRE = fire, ACID = acid, WOUND = wound, CONSUME = consume)
|
|
|
|
/datum/armor/proc/attachArmor(datum/armor/AA)
|
|
return getArmor(melee+AA.melee, bullet+AA.bullet, laser+AA.laser, energy+AA.energy, bomb+AA.bomb, bio+AA.bio, fire+AA.fire, acid+AA.acid, wound+AA.wound, consume+AA.consume)
|
|
|
|
/datum/armor/proc/detachArmor(datum/armor/AA)
|
|
return getArmor(melee-AA.melee, bullet-AA.bullet, laser-AA.laser, energy-AA.energy, bomb-AA.bomb, bio-AA.bio, fire-AA.fire, acid-AA.acid, wound-AA.wound, consume-AA.consume)
|
|
|
|
/datum/armor/GenerateTag()
|
|
. = ..()
|
|
tag = ARMORID
|
|
|
|
/datum/armor/vv_edit_var(var_name, var_value)
|
|
if (var_name == NAMEOF(src, tag))
|
|
return FALSE
|
|
. = ..()
|
|
GenerateTag()
|
|
|
|
#undef ARMORID
|