mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-25 08:34:23 +00:00
3ceee2aab4
- Removes unnecessary real global vars. - Adds comments pointing to the init order defined in /code/game/world.dm. - Prevent people using `GLOBAL_REAL_VAR` and `GLOBAL_REAL` to circumvent init order. - Properly type `PROFILE_STORE` real global. - Refactored `make_datum_references_lists()` and moved the call to it into `GLOB` init with duct tape. - Renamed `GLOB.admin_log` to `GLOB.admin_activities` as it wasn't actually a log file. - Whitelist loading happens in config. - Renamed `SSdbcore`'s `SetRoundID()` to `InitializeRound()`. Now handles calling `CheckSchemaVersion()`. - Created macro for setting up log `GLOB`s. - Removed log line for `GLOB` count. - Moved call to `make_datum_reference_lists()` to `/datum/controller/global_vars/Initialize()`. I slimmed it down where possible too. - Updated comments about world init order. - Move `load_admins()` call to after log setup. - Removes unused function `gib_stack_trace()`. - Removes a bunch of unused log `GLOB`s. - Unlocks the secrets of the universe by finally making the first executed line of code deterministic. No functional changes. Closes #74792 Testmerge thoroughly. --------- Co-authored-by: Mothblocks <35135081+Mothblocks@users.noreply.github.com>
68 lines
2.2 KiB
Plaintext
68 lines
2.2 KiB
Plaintext
#define PROFILER_FILENAME "profiler.json"
|
|
#define SENDMAPS_FILENAME "sendmaps.json"
|
|
|
|
SUBSYSTEM_DEF(profiler)
|
|
name = "Profiler"
|
|
init_order = INIT_ORDER_PROFILER
|
|
runlevels = RUNLEVELS_DEFAULT | RUNLEVEL_LOBBY
|
|
wait = 3000
|
|
var/fetch_cost = 0
|
|
var/write_cost = 0
|
|
|
|
/datum/controller/subsystem/profiler/stat_entry(msg)
|
|
msg += "F:[round(fetch_cost,1)]ms"
|
|
msg += "|W:[round(write_cost,1)]ms"
|
|
return msg
|
|
|
|
/datum/controller/subsystem/profiler/Initialize()
|
|
if(CONFIG_GET(flag/auto_profile))
|
|
StartProfiling()
|
|
else
|
|
StopProfiling() //Stop the early start profiler
|
|
return SS_INIT_SUCCESS
|
|
|
|
/datum/controller/subsystem/profiler/fire()
|
|
if(CONFIG_GET(flag/auto_profile))
|
|
DumpFile()
|
|
|
|
/datum/controller/subsystem/profiler/Shutdown()
|
|
if(CONFIG_GET(flag/auto_profile))
|
|
DumpFile()
|
|
world.Profile(PROFILE_CLEAR, type = "sendmaps")
|
|
return ..()
|
|
|
|
/datum/controller/subsystem/profiler/proc/StartProfiling()
|
|
world.Profile(PROFILE_START)
|
|
world.Profile(PROFILE_START, type = "sendmaps")
|
|
|
|
/datum/controller/subsystem/profiler/proc/StopProfiling()
|
|
world.Profile(PROFILE_STOP)
|
|
world.Profile(PROFILE_STOP, type = "sendmaps")
|
|
|
|
|
|
/datum/controller/subsystem/profiler/proc/DumpFile()
|
|
var/timer = TICK_USAGE_REAL
|
|
var/current_profile_data = world.Profile(PROFILE_REFRESH, format = "json")
|
|
var/current_sendmaps_data = world.Profile(PROFILE_REFRESH, type = "sendmaps", format="json")
|
|
fetch_cost = MC_AVERAGE(fetch_cost, TICK_DELTA_TO_MS(TICK_USAGE_REAL - timer))
|
|
CHECK_TICK
|
|
|
|
if(!length(current_profile_data)) //Would be nice to have explicit proc to check this
|
|
stack_trace("Warning, profiling stopped manually before dump.")
|
|
var/prof_file = file("[GLOB.log_directory]/[PROFILER_FILENAME]")
|
|
if(fexists(prof_file))
|
|
fdel(prof_file)
|
|
if(!length(current_sendmaps_data)) //Would be nice to have explicit proc to check this
|
|
stack_trace("Warning, sendmaps profiling stopped manually before dump.")
|
|
var/sendmaps_file = file("[GLOB.log_directory]/[SENDMAPS_FILENAME]")
|
|
if(fexists(sendmaps_file))
|
|
fdel(sendmaps_file)
|
|
|
|
timer = TICK_USAGE_REAL
|
|
WRITE_FILE(prof_file, current_profile_data)
|
|
WRITE_FILE(sendmaps_file, current_sendmaps_data)
|
|
write_cost = MC_AVERAGE(write_cost, TICK_DELTA_TO_MS(TICK_USAGE_REAL - timer))
|
|
|
|
#undef PROFILER_FILENAME
|
|
#undef SENDMAPS_FILENAME
|