mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-08-30 16:47:13 +01:00
SmArtKarandGitHub
c74f104c89
## About The Pull Request Instead of being snowflake interactions on objects themselves, rigging things with plasma or welding fuel is now handled on reagents' side via ``on_spark_act``, allowing each reagent to decide how they want to handle exposure to electric currents or violent heating. - Obviously plasma and welding fuel cause explosions, but former gains additional power from electric current being passed through it (same math as powercells), while latter doesn't explode unless in an enclosed space, or a high enough current/temperature has been reached, and merely creates a hotspot instead. - Napalm and phlogiston create hotspots, or (try to) damage the holder if they're enclosed - Sorium, liquid dark matter, TATP, nitroglycerin and flash/smoke/sonic powders trigger their usual detonation effects, albeit slightly weaker. - Teslium creates a ZAP, with additional power for a BIG ZAP if it has been triggered by electric current. - RDX becomes spicier with temperature and current, similarly to how it becomes more dangerous when mixed with LE or teslium. - Gunpowder produces a delayed explosion effect (unless its hot or the current is high enough, in which case its instant) and causes sparks as the message claims it does (normal gunpowder explosions also do that) Plasma and gunpowder rigged items can now be controlled using stabilizing agent - in its presence, plasma will not explode unless the used charge is higher than 0.2% of a standard cell's per unit of agent, while gunpowder will instead spend 0.1 + (charge / 10% of a standard cell's charge) units of agent to delay its detonation. Smoke (powder) now produces a visible message and slightly damages lungs of whoever it reacted inside of, if the container was a mob. The numbers on plasma/welding fuel rigs should be ***roughly*** the same. Also lighters can now be rigged in a fashion similar to welding tools. Also it turns out we broke light rigging at some point, so now it works again. ## Why It's Good For The Game This makes the system much more flexible and allows players to make more creative IEDs, expanding upon the sandbox aspect of the game. Also I have an upcoming project bringing IEDs (kind of, in a new form) back, which is why I wrote this in the first place (but decided to atomize the PRs). As for smoke damage, it feels weird to not have any tells when someone suddenly starts hacking up volumetric amounts of smoke, it makes sense that they'd struggle a bit after coughing a few dozen cubic meters of thick vape clouds. ## Changelog 🆑 add: Multiple new reagents such as napalm, sorium, TATP, smoke/sonic/flash powders and other explosives can now be used to rig cells or tools. add: Plasma and gunpowder rigged items can now have controlled current requirement/delay by adding some stabilizing agent alongside the main reagent. balance: Creating chemical smoke inside of a mob now makes them violently cough it up, damaging their lungs a bit. fix: Chemically-rigged lightbulbs now once again explode. refactor: Refactored how power cells, welding tools, lightbulbs, cigarettes (and now, lighters) handle being rigged with chemicals. /🆑
114 lines
3.5 KiB
Plaintext
114 lines
3.5 KiB
Plaintext
|
|
/////////////////////////////////////////////
|
|
//////// Attach a trail to any object, that spawns when it moves (like for the jetpack)
|
|
/// just pass in the object to attach it to in set_up
|
|
/// Then do start() to start it and stop() to stop it, obviously
|
|
/// and don't call start() in a loop that will be repeated otherwise it'll get spammed!
|
|
/////////////////////////////////////////////
|
|
|
|
/datum/effect_system/trail_follow
|
|
var/turf/oldposition
|
|
var/active = FALSE
|
|
var/allow_overlap = FALSE
|
|
var/auto_process = TRUE
|
|
var/qdel_in_time = 10
|
|
var/fadetype = "ion_fade"
|
|
var/fade = TRUE
|
|
var/nograv_required = FALSE
|
|
|
|
/datum/effect_system/trail_follow/set_up(atom/atom)
|
|
attach(atom)
|
|
oldposition = get_turf(atom)
|
|
|
|
/datum/effect_system/trail_follow/Destroy()
|
|
oldposition = null
|
|
stop()
|
|
return ..()
|
|
|
|
/datum/effect_system/trail_follow/proc/stop()
|
|
oldposition = null
|
|
STOP_PROCESSING(SSfastprocess, src)
|
|
active = FALSE
|
|
return TRUE
|
|
|
|
/datum/effect_system/trail_follow/start()
|
|
oldposition = get_turf(holder)
|
|
if(!check_conditions())
|
|
return FALSE
|
|
if(auto_process)
|
|
START_PROCESSING(SSfastprocess, src)
|
|
active = TRUE
|
|
return TRUE
|
|
|
|
/datum/effect_system/trail_follow/process()
|
|
generate_effect()
|
|
|
|
/datum/effect_system/trail_follow/generate_effect()
|
|
if(!check_conditions())
|
|
return stop()
|
|
if(oldposition && !(oldposition == get_turf(holder)))
|
|
if(!oldposition.has_gravity() || !nograv_required)
|
|
var/obj/effect/E = new effect_type(oldposition)
|
|
set_dir(E)
|
|
if(fade)
|
|
flick(fadetype, E)
|
|
E.icon_state = ""
|
|
if(qdel_in_time)
|
|
QDEL_IN(E, qdel_in_time)
|
|
oldposition = get_turf(holder)
|
|
|
|
/datum/effect_system/trail_follow/proc/check_conditions()
|
|
if(!get_turf(holder))
|
|
return FALSE
|
|
return TRUE
|
|
|
|
/datum/effect_system/trail_follow/steam
|
|
effect_type = /obj/effect/particle_effect/steam
|
|
|
|
/obj/effect/particle_effect/ion_trails
|
|
name = "ion trails"
|
|
icon_state = "ion_trails"
|
|
anchored = TRUE
|
|
|
|
/obj/effect/particle_effect/ion_trails/flight
|
|
icon_state = "ion_trails_flight"
|
|
|
|
/datum/effect_system/trail_follow/ion
|
|
effect_type = /obj/effect/particle_effect/ion_trails
|
|
nograv_required = TRUE
|
|
qdel_in_time = 20
|
|
|
|
/datum/effect_system/trail_follow/proc/set_dir(obj/effect/particle_effect/ion_trails/I)
|
|
I.setDir(holder.dir)
|
|
|
|
/datum/effect_system/trail_follow/ion/grav_allowed
|
|
nograv_required = FALSE
|
|
|
|
//Reagent-based explosion effect
|
|
|
|
/datum/effect_system/reagents_explosion
|
|
var/amount // TNT equivalent
|
|
var/flashing_factor = null // factor of how powerful the flash effect relatively to the explosion
|
|
var/flaming_factor = null // factor of how powerful the flame effect is relatively to explosion
|
|
var/explosion_message = 1 //whether we show a message to mobs.
|
|
|
|
/datum/effect_system/reagents_explosion/set_up(amt, loca, flash_fact = null, flame_fact = null, message = TRUE)
|
|
amount = amt
|
|
explosion_message = message
|
|
if(isturf(loca))
|
|
location = loca
|
|
else
|
|
location = get_turf(loca)
|
|
flashing_factor = flash_fact
|
|
flaming_factor = flame_fact
|
|
|
|
/// Starts the explosion. The explosion_source is as part of logging and identifying the source of the explosion for logs.
|
|
/datum/effect_system/reagents_explosion/start(atom/explosion_source = null)
|
|
if(!explosion_source)
|
|
stack_trace("Reagent explosion triggered without a source atom. This explosion may have incomplete logging.")
|
|
|
|
if(explosion_message)
|
|
location.visible_message(span_danger("The solution violently explodes!"), span_hear("You hear an explosion!"))
|
|
|
|
dyn_explosion(location, amount, flash_range = flashing_factor, flame_range = flaming_factor, explosion_cause = explosion_source)
|